[gentoo-commits] gentoo-x86 commit in x11-libs/qscintilla: qscintilla-2.8.ebuild ChangeLog qscintilla-2.7.1.ebuild

[gentoo-commits] gentoo-x86 commit in x11-libs/qscintilla: qscintilla-2.8.ebuild ChangeLog qscintilla-2.7.1.ebuild

[Davide Pesavento (pesa)]

pesa        13/11/14 01:33:31

  Modified:             ChangeLog
  Added:                qscintilla-2.8.ebuild
  Removed:              qscintilla-2.7.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 17A85C72)

Revision  Changes    Path
1.95                 x11-libs/qscintilla/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/ChangeLog?rev=1.95&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/ChangeLog?rev=1.95&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/ChangeLog?r1=1.94&r2=1.95

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/ChangeLog,v
retrieving revision 1.94
retrieving revision 1.95
diff -u -r1.94 -r1.95
--- ChangeLog	5 Sep 2013 19:25:00 -0000	1.94
+++ ChangeLog	14 Nov 2013 01:33:31 -0000	1.95
@@ -1,6 +1,12 @@
 # ChangeLog for x11-libs/qscintilla
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/ChangeLog,v 1.94 2013/09/05 19:25:00 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/ChangeLog,v 1.95 2013/11/14 01:33:31 pesa Exp $
+
+*qscintilla-2.8 (14 Nov 2013)
+
+  14 Nov 2013; Davide Pesavento <pesa@gentoo.org> +qscintilla-2.8.ebuild,
+  -qscintilla-2.7.1.ebuild:
+  Version bump.
 
   05 Sep 2013; Agostino Sarubbo <ago@gentoo.org> qscintilla-2.7.2.ebuild:
   Stable for x86, wrt bug #483112



1.1                  x11-libs/qscintilla/qscintilla-2.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/qscintilla-2.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/qscintilla-2.8.ebuild?rev=1.1&content-type=text/plain

Index: qscintilla-2.8.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/qscintilla-2.8.ebuild,v 1.1 2013/11/14 01:33:31 pesa Exp $

EAPI=5

inherit qt4-r2

MY_P=QScintilla-gpl-${PV}

DESCRIPTION="A Qt port of Neil Hodgson's Scintilla C++ editor class"
HOMEPAGE="http://www.riverbankcomputing.co.uk/software/qscintilla/intro"
SRC_URI="mirror://sourceforge/pyqt/${MY_P}.tar.gz"

LICENSE="|| ( GPL-2 GPL-3 )"
SLOT="0/11"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="doc python"

DEPEND="
	>=dev-qt/designer-4.8.5:4
	>=dev-qt/qtcore-4.8.5:4
	>=dev-qt/qtgui-4.8.5:4
"
RDEPEND="${DEPEND}"
PDEPEND="python? ( ~dev-python/qscintilla-python-${PV} )"

S=${WORKDIR}/${MY_P}

PATCHES=(
	"${FILESDIR}/${PN}-2.7.1-designer.patch"
)

src_unpack() {
	qt4-r2_src_unpack

	# Sub-slot sanity check
	local subslot=${SLOT#*/}
	local version=$(sed -nre 's:.*VERSION\s*=\s*([0-9\.]+):\1:p' "${S}"/Qt4Qt5/qscintilla.pro)
	local major=${version%%.*}
	if [[ ${subslot} != ${major} ]]; then
		eerror
		eerror "Ebuild sub-slot (${subslot}) does not match QScintilla major version (${major})"
		eerror "Please update SLOT variable as follows:"
		eerror "    SLOT=\"${SLOT%%/*}/${major}\""
		eerror
		die "sub-slot sanity check failed"
	fi
}

src_configure() {
	pushd Qt4Qt5 > /dev/null
	einfo "Configuration of qscintilla"
	eqmake4 qscintilla.pro
	popd > /dev/null

	pushd designer-Qt4Qt5 > /dev/null
	einfo "Configuration of designer plugin"
	eqmake4 designer.pro
	popd > /dev/null
}

src_compile() {
	pushd Qt4Qt5 > /dev/null
	einfo "Building of qscintilla"
	emake
	popd > /dev/null

	pushd designer-Qt4Qt5 > /dev/null
	einfo "Building of designer plugin"
	emake
	popd > /dev/null
}

src_install() {
	pushd Qt4Qt5 > /dev/null
	einfo "Installation of qscintilla"
	emake INSTALL_ROOT="${D}" install
	popd > /dev/null

	pushd designer-Qt4Qt5 > /dev/null
	einfo "Installation of designer plugin"
	emake INSTALL_ROOT="${D}" install
	popd > /dev/null

	dodoc NEWS

	if use doc; then
		dohtml doc/html-Qt4Qt5/*
		insinto /usr/share/doc/${PF}
		doins -r doc/Scintilla
	fi
}