[gentoo-commits] gentoo-x86 commit in x11-wm/enlightenment: enlightenment-0.17.5.ebuild ChangeLog enlightenment-0.17.4.ebuild enlightenment-0.17.5_pre2.ebuild

[gentoo-commits] gentoo-x86 commit in x11-wm/enlightenment: enlightenment-0.17.5.ebuild ChangeLog enlightenment-0.17.4.ebuild enlightenment-0.17.5_pre2.ebuild

[Thomas Sachau (tommy)]

tommy       13/11/13 22:29:07

  Modified:             ChangeLog
  Added:                enlightenment-0.17.5.ebuild
  Removed:              enlightenment-0.17.4.ebuild
                        enlightenment-0.17.5_pre2.ebuild
  Log:
  Version bump for enlightenment-0.17.5, drop 0.17.4 and pre-release
  
  (Portage version: 2.2.6-r1/cvs/Linux x86_64, signed Manifest commit with key 0x35899067)

Revision  Changes    Path
1.190                x11-wm/enlightenment/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/enlightenment/ChangeLog?rev=1.190&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/enlightenment/ChangeLog?rev=1.190&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/enlightenment/ChangeLog?r1=1.189&r2=1.190

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/enlightenment/ChangeLog,v
retrieving revision 1.189
retrieving revision 1.190
diff -u -r1.189 -r1.190
--- ChangeLog	4 Oct 2013 10:40:51 -0000	1.189
+++ ChangeLog	13 Nov 2013 22:29:07 -0000	1.190
@@ -1,6 +1,13 @@
 # ChangeLog for x11-wm/enlightenment
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/enlightenment/ChangeLog,v 1.189 2013/10/04 10:40:51 tommy Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/enlightenment/ChangeLog,v 1.190 2013/11/13 22:29:07 tommy Exp $
+
+*enlightenment-0.17.5 (13 Nov 2013)
+
+  13 Nov 2013; Thomas Sachau (Tommy[D]) <tommy@gentoo.org>
+  +enlightenment-0.17.5.ebuild, -enlightenment-0.17.4.ebuild,
+  -enlightenment-0.17.5_pre2.ebuild:
+  Version bump for enlightenment-0.17.5, drop 0.17.4 and pre-release
 
 *enlightenment-0.17.5_pre2 (04 Oct 2013)
 



1.1                  x11-wm/enlightenment/enlightenment-0.17.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/enlightenment/enlightenment-0.17.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/enlightenment/enlightenment-0.17.5.ebuild?rev=1.1&content-type=text/plain

Index: enlightenment-0.17.5.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/enlightenment/enlightenment-0.17.5.ebuild,v 1.1 2013/11/13 22:29:07 tommy Exp $

EAPI=5

inherit enlightenment

DESCRIPTION="Enlightenment DR17 window manager"
SRC_URI="http://download.enlightenment.org/releases/${P}.tar.bz2"

LICENSE="BSD-2"
KEYWORDS="~amd64 ~arm ~x86"
SLOT="0.17/${PV/_pre2}"

# The @ is just an anchor to expand from
__EVRY_MODS=""
__CONF_MODS="
	+@applications +@dialogs +@display +@edgebindings
	+@interaction +@intl +@keybindings +@menus
	+@paths +@performance +@randr +@shelves +@theme
	+@window-manipulation +@window-remembers"
__NORM_MODS="
	@access +@backlight +@battery +@clock +@comp +@connman +@cpufreq +@dropshadow
	+@everything +@fileman +@fileman-opinfo +@gadman +@ibar +@ibox +@illume2
	+@mixer	+@msgbus +@notification +@pager +@quickaccess @shot +@start
	+@syscon +@systray +@tasks +@temperature +@tiling +@winlist +@wizard +@xkbswitch"
IUSE_E_MODULES="
	${__CONF_MODS//@/enlightenment_modules_conf-}
	${__NORM_MODS//@/enlightenment_modules_}"

IUSE="emotion pam spell static-libs +udev ukit ${IUSE_E_MODULES}"

RDEPEND="
	pam? ( sys-libs/pam )
	>=dev-libs/eet-1.7.9
	>=dev-libs/efreet-1.7.9
	>=dev-libs/eio-1.7.9
	>=dev-libs/eina-1.7.9[mempool-chained-pool]
	|| ( >=dev-libs/ecore-1.7.9[X,evas,inotify] >=dev-libs/ecore-1.7.9[xcb,evas,inotify] )
	>=media-libs/edje-1.7.9
	>=dev-libs/e_dbus-1.7.9[libnotify,udev?]
	ukit? ( >=dev-libs/e_dbus-1.7.9[udev] )
	enlightenment_modules_connman? ( >=dev-libs/e_dbus-1.7.9[connman] )
	enlightenment_modules_shot? ( >=dev-libs/ecore-1.7.9[curl] )
	|| ( >=media-libs/evas-1.7.9[eet,X,jpeg,png] >=media-libs/evas-1.7.9[eet,xcb,jpeg,png] )
	>=dev-libs/eeze-1.7.9
	emotion? ( >=media-libs/emotion-1.7.9 )
	x11-libs/xcb-util-keysyms"
DEPEND="${RDEPEND}"

src_prepare() {
	epatch "${FILESDIR}"/quickstart.diff
	enlightenment_src_prepare
}

src_configure() {
	E_ECONF+=(
		--disable-install-sysactions
		--disable-elementary
		$(use_enable doc)
		--disable-device-hal
		$(use_enable emotion)
		--disable-mount-hal
		$(use_enable nls)
		$(use_enable pam)
		--enable-device-udev
		$(use_enable udev mount-eeze)
		$(use_enable ukit mount-udisks)
		--disable-physics
	)
	local u c
	for u in ${IUSE_E_MODULES} ; do
		u=${u#+}
		c=${u#enlightenment_modules_}
		E_ECONF+=( $(use_enable ${u} ${c}) )
	done
	enlightenment_src_configure
}

src_install() {
	enlightenment_src_install
	insinto /etc/enlightenment
	newins "${FILESDIR}"/gentoo-sysactions.conf sysactions.conf
}