* [gentoo-commits] gentoo-x86 commit in net-print/cups: ChangeLog cups-1.7.0.ebuild cups-9999.ebuild cups-1.6.3-r2.ebuild cups-1.7_rc1.ebuild
@ 2013-10-30 21:48 Andreas HAttel (dilfridge)
0 siblings, 0 replies; only message in thread
From: Andreas HAttel (dilfridge) @ 2013-10-30 21:48 UTC (permalink / raw
To: gentoo-commits
dilfridge 13/10/30 21:48:47
Modified: ChangeLog cups-9999.ebuild
Added: cups-1.7.0.ebuild
Removed: cups-1.6.3-r2.ebuild cups-1.7_rc1.ebuild
Log:
Version bump; remove old
(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key EBE6A336BE19039C!)
Revision Changes Path
1.567 net-print/cups/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups/ChangeLog?rev=1.567&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups/ChangeLog?rev=1.567&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups/ChangeLog?r1=1.566&r2=1.567
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/cups/ChangeLog,v
retrieving revision 1.566
retrieving revision 1.567
diff -u -r1.566 -r1.567
--- ChangeLog 22 Oct 2013 16:41:12 -0000 1.566
+++ ChangeLog 30 Oct 2013 21:48:47 -0000 1.567
@@ -1,6 +1,12 @@
# ChangeLog for net-print/cups
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/cups/ChangeLog,v 1.566 2013/10/22 16:41:12 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/cups/ChangeLog,v 1.567 2013/10/30 21:48:47 dilfridge Exp $
+
+*cups-1.7.0 (30 Oct 2013)
+
+ 30 Oct 2013; Andreas K. Huettel <dilfridge@gentoo.org> -cups-1.6.3-r2.ebuild,
+ -cups-1.7_rc1.ebuild, +cups-1.7.0.ebuild, cups-9999.ebuild:
+ Version bump; remove old
22 Oct 2013; Andreas K. Huettel <dilfridge@gentoo.org> cups-1.6.2-r5.ebuild:
Drop stable keywords on unstable-only arches
1.45 net-print/cups/cups-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups/cups-9999.ebuild?rev=1.45&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups/cups-9999.ebuild?rev=1.45&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups/cups-9999.ebuild?r1=1.44&r2=1.45
Index: cups-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/cups/cups-9999.ebuild,v
retrieving revision 1.44
retrieving revision 1.45
diff -u -r1.44 -r1.45
--- cups-9999.ebuild 21 Oct 2013 15:21:03 -0000 1.44
+++ cups-9999.ebuild 30 Oct 2013 21:48:47 -0000 1.45
@@ -1,6 +1,6 @@
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/cups/cups-9999.ebuild,v 1.44 2013/10/21 15:21:03 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/cups/cups-9999.ebuild,v 1.45 2013/10/30 21:48:47 dilfridge Exp $
EAPI=5
@@ -34,7 +34,7 @@
IUSE="acl dbus debug +filters gnutls java kerberos lprng-compat pam
python selinux +ssl static-libs +threads usb X xinetd zeroconf"
-LANGS="ca es fr ja ru"
+LANGS="ca es fr it ja ru"
for X in ${LANGS} ; do
IUSE="${IUSE} +linguas_${X}"
done
@@ -91,7 +91,6 @@
"${FILESDIR}/${PN}-1.6.0-fix-install-perms.patch"
"${FILESDIR}/${PN}-1.4.4-nostrip.patch"
"${FILESDIR}/${PN}-1.5.0-systemd-socket-2.patch" # systemd support
- "${FILESDIR}/${PN}-1.6.3-colord-profile.patch"
)
pkg_setup() {
1.1 net-print/cups/cups-1.7.0.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups/cups-1.7.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups/cups-1.7.0.ebuild?rev=1.1&content-type=text/plain
Index: cups-1.7.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-print/cups/cups-1.7.0.ebuild,v 1.1 2013/10/30 21:48:47 dilfridge Exp $
EAPI=5
PYTHON_COMPAT=( python{2_6,2_7} )
inherit autotools base fdo-mime gnome2-utils flag-o-matic linux-info \
multilib pam python-single-r1 user versionator java-pkg-opt-2 systemd
MY_P=${P/_rc/rc}
MY_P=${MY_P/_beta/b}
MY_PV=${PV/_rc/rc}
MY_PV=${MY_PV/_beta/b}
if [[ ${PV} == *9999 ]]; then
inherit git-2
EGIT_REPO_URI="http://www.cups.org/cups.git"
if [[ ${PV} != 9999 ]]; then
EGIT_BRANCH=branch-${PV/.9999}
fi
KEYWORDS=""
else
SRC_URI="http://www.cups.org/software/${MY_PV}/${MY_P}-source.tar.bz2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
fi
DESCRIPTION="The Common Unix Printing System"
HOMEPAGE="http://www.cups.org/"
LICENSE="GPL-2"
SLOT="0"
IUSE="acl dbus debug +filters gnutls java kerberos lprng-compat pam
python selinux +ssl static-libs +threads usb X xinetd zeroconf"
LANGS="ca es fr it ja ru"
for X in ${LANGS} ; do
IUSE="${IUSE} +linguas_${X}"
done
RDEPEND="
app-text/libpaper
acl? (
kernel_linux? (
sys-apps/acl
sys-apps/attr
)
)
dbus? ( sys-apps/dbus )
java? ( >=virtual/jre-1.6 )
kerberos? ( virtual/krb5 )
!lprng-compat? ( !net-print/lprng )
pam? ( virtual/pam )
python? ( ${PYTHON_DEPS} )
selinux? ( sec-policy/selinux-cups )
ssl? (
gnutls? (
dev-libs/libgcrypt
net-libs/gnutls
)
!gnutls? ( >=dev-libs/openssl-0.9.8g )
)
usb? ( virtual/libusb:1 )
X? ( x11-misc/xdg-utils )
xinetd? ( sys-apps/xinetd )
zeroconf? ( net-dns/avahi )
"
DEPEND="${RDEPEND}
virtual/pkgconfig
"
PDEPEND="
app-text/ghostscript-gpl[cups]
app-text/poppler[utils]
>=net-print/cups-filters-1.0.30
filters? ( net-print/foomatic-filters )
"
REQUIRED_USE="gnutls? ( ssl )
python? ( ${PYTHON_REQUIRED_USE} )"
# upstream includes an interactive test which is a nono for gentoo
RESTRICT="test"
S="${WORKDIR}/${MY_P}"
PATCHES=(
"${FILESDIR}/${PN}-1.6.0-dont-compress-manpages.patch"
"${FILESDIR}/${PN}-1.6.0-fix-install-perms.patch"
"${FILESDIR}/${PN}-1.4.4-nostrip.patch"
"${FILESDIR}/${PN}-1.5.0-systemd-socket-2.patch" # systemd support
)
pkg_setup() {
enewgroup lp
enewuser lp -1 -1 -1 lp
enewgroup lpadmin 106
use python && python-single-r1_pkg_setup
if use kernel_linux; then
linux-info_pkg_setup
if ! linux_config_exists; then
ewarn "Can't check the linux kernel configuration."
ewarn "You might have some incompatible options enabled."
else
# recheck that we don't have usblp to collide with libusb
if use usb; then
if linux_chkconfig_present USB_PRINTER; then
eerror "Your usb printers will be managed via libusb. In this case, "
eerror "${P} requires the USB_PRINTER support disabled."
eerror "Please disable it:"
eerror " CONFIG_USB_PRINTER=n"
eerror "in /usr/src/linux/.config or"
eerror " Device Drivers --->"
eerror " USB support --->"
eerror " [ ] USB Printer support"
eerror "Alternatively, just disable the usb useflag for cups (your printer will still work)."
fi
else
#here we should warn user that he should enable it so he can print
if ! linux_chkconfig_present USB_PRINTER; then
ewarn "If you plan to use USB printers you should enable the USB_PRINTER"
ewarn "support in your kernel."
ewarn "Please enable it:"
ewarn " CONFIG_USB_PRINTER=y"
ewarn "in /usr/src/linux/.config or"
ewarn " Device Drivers --->"
ewarn " USB support --->"
ewarn " [*] USB Printer support"
ewarn "Alternatively, enable the usb useflag for cups and use the libusb code."
fi
fi
fi
fi
}
src_prepare() {
base_src_prepare
AT_M4DIR=config-scripts eaclocal
eautoconf
}
src_configure() {
export DSOFLAGS="${LDFLAGS}"
einfo LANGS=\"${LANGS}\"
einfo LINGUAS=\"${LINGUAS}\"
local myconf
if use ssl ; then
myconf+="
$(use_enable gnutls)
$(use_enable !gnutls openssl)
"
else
myconf+="
--disable-gnutls
--disable-openssl
"
fi
econf \
--libdir="${EPREFIX}"/usr/$(get_libdir) \
--localstatedir="${EPREFIX}"/var \
--with-rundir="${EPREFIX}"/run/cups \
--with-cups-user=lp \
--with-cups-group=lp \
--with-docdir="${EPREFIX}"/usr/share/cups/html \
--with-languages="${LINGUAS}" \
--with-system-groups=lpadmin \
$(use_enable acl) \
$(use_enable zeroconf avahi) \
$(use_enable dbus) \
$(use_enable debug) \
$(use_enable debug debug-guards) \
$(use_enable kerberos gssapi) \
$(use_enable pam) \
$(use_enable static-libs static) \
$(use_enable threads) \
$(use_enable usb libusb) \
--disable-dnssd \
$(use_with java) \
--without-perl \
--without-php \
$(use_with python python "${PYTHON}") \
$(use_with xinetd xinetd /etc/xinetd.d) \
--enable-libpaper \
--with-systemdsystemunitdir="$(systemd_get_unitdir)" \
${myconf}
# install in /usr/libexec always, instead of using /usr/lib/cups, as that
# makes more sense when facing multilib support.
sed -i -e "s:SERVERBIN.*:SERVERBIN = \"\$\(BUILDROOT\)${EPREFIX}/usr/libexec/cups\":" Makedefs || die
sed -i -e "s:#define CUPS_SERVERBIN.*:#define CUPS_SERVERBIN \"${EPREFIX}/usr/libexec/cups\":" config.h || die
sed -i -e "s:cups_serverbin=.*:cups_serverbin=\"${EPREFIX}/usr/libexec/cups\":" cups-config || die
}
src_install() {
# Fix install-sh, posix sh does not have 'function'.
sed 's#function gzipcp#gzipcp()#g' -i "${S}/install-sh"
emake BUILDROOT="${D}" install
dodoc {CHANGES,CREDITS,README}.txt
# move the default config file to docs
dodoc "${ED}"/etc/cups/cupsd.conf.default
rm -f "${ED}"/etc/cups/cupsd.conf.default
# clean out cups init scripts
rm -rf "${ED}"/etc/{init.d/cups,rc*,pam.d/cups}
# install our init script
local neededservices
use zeroconf && neededservices+=" avahi-daemon"
use dbus && neededservices+=" dbus"
[[ -n ${neededservices} ]] && neededservices="need${neededservices}"
cp "${FILESDIR}"/cupsd.init.d-r1 "${T}"/cupsd || die
sed -i \
-e "s/@neededservices@/$neededservices/" \
"${T}"/cupsd || die
doinitd "${T}"/cupsd
# install our pam script
pamd_mimic_system cups auth account
if use xinetd ; then
# correct path
sed -i \
-e "s:server = .*:server = /usr/libexec/cups/daemon/cups-lpd:" \
"${ED}"/etc/xinetd.d/cups-lpd || die
# it is safer to disable this by default, bug #137130
grep -w 'disable' "${ED}"/etc/xinetd.d/cups-lpd || \
{ sed -i -e "s:}:\tdisable = yes\n}:" "${ED}"/etc/xinetd.d/cups-lpd || die ; }
# write permission for file owner (root), bug #296221
fperms u+w /etc/xinetd.d/cups-lpd || die "fperms failed"
else
rm -rf "${ED}"/etc/xinetd.d
fi
keepdir /usr/libexec/cups/driver /usr/share/cups/{model,profiles} \
/var/cache/cups /var/cache/cups/rss /var/log/cups \
/var/spool/cups/tmp
keepdir /etc/cups/{interfaces,ppd,ssl}
use X || rm -r "${ED}"/usr/share/applications
# create /etc/cups/client.conf, bug #196967 and #266678
echo "ServerName ${EPREFIX}/run/cups/cups.sock" >> "${ED}"/etc/cups/client.conf
# the following files are now provided by cups-filters:
rm -r "${ED}"/usr/share/cups/banners || die
rm -r "${ED}"/usr/share/cups/data/testprint || die
# for the special case of running lprng and cups together, bug 467226
if use lprng-compat ; then
rm -fv "${ED}"/usr/bin/{lp*,cancel}
rm -fv "${ED}"/usr/sbin/lp*
rm -fv "${ED}"/usr/share/man/man1/{lp*,cancel*}
rm -fv "${ED}"/usr/share/man/man8/lp*
ewarn "Not installing lp... binaries, since the lprng-compat useflag is set."
ewarn "Unless you plan to install an exotic server setup, you most likely"
ewarn "do not want this. Disable the useflag then and all will be fine."
fi
}
pkg_preinst() {
gnome2_icon_savelist
}
pkg_postinst() {
# Update desktop file database and gtk icon cache (bug 370059)
gnome2_icon_cache_update
fdo-mime_desktop_database_update
# not slotted - at most one value
if ! [[ "${REPLACING_VERSIONS}" ]]; then
echo
elog "For information about installing a printer and general cups setup"
elog "take a look at: http://www.gentoo.org/doc/en/printing-howto.xml"
echo
fi
if [[ "${REPLACING_VERSIONS}" ]] && [[ "${REPLACING_VERSIONS}" < "1.6" ]]; then
echo
elog "CUPS-1.6 no longer supports automatic remote printers or implicit classes"
elog "via the CUPS, LDAP, or SLP protocols, i.e. \"network browsing\"."
elog "You will have to find printers using zeroconf/avahi instead, enter"
elog "the location manually, or run cups-browsed from net-print/cups-filters"
elog "which re-adds that functionality as a separate daemon."
echo
fi
if [[ "${REPLACING_VERSIONS}" == "1.6.2-r4" ]]; then
ewarn
ewarn "You are upgrading from the broken version net-print/cups-1.6.2-r4."
ewarn "Please rebuild net-print/cups-filters now to make sure everything is OK."
ewarn
fi
}
pkg_postrm() {
# Update desktop file database and gtk icon cache (bug 370059)
gnome2_icon_cache_update
fdo-mime_desktop_database_update
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-10-30 21:48 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-10-30 21:48 [gentoo-commits] gentoo-x86 commit in net-print/cups: ChangeLog cups-1.7.0.ebuild cups-9999.ebuild cups-1.6.3-r2.ebuild cups-1.7_rc1.ebuild Andreas HAttel (dilfridge)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox