[gentoo-commits] gentoo-x86 commit in x11-misc/menulibre: menulibre-13.04.17.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in x11-misc/menulibre: menulibre-13.04.17.ebuild ChangeLog

[Julian Ospald (hasufell)]

hasufell    13/10/21 17:46:32

  Modified:             ChangeLog
  Added:                menulibre-13.04.17.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.6                  x11-misc/menulibre/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/menulibre/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/menulibre/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/menulibre/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/menulibre/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	21 Oct 2013 17:40:09 -0000	1.5
+++ ChangeLog	21 Oct 2013 17:46:32 -0000	1.6
@@ -1,6 +1,11 @@
 # ChangeLog for x11-misc/menulibre
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/menulibre/ChangeLog,v 1.5 2013/10/21 17:40:09 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/menulibre/ChangeLog,v 1.6 2013/10/21 17:46:32 hasufell Exp $
+
+*menulibre-13.04.17 (21 Oct 2013)
+
+  21 Oct 2013; Julian Ospald <hasufell@gentoo.org> +menulibre-13.04.17.ebuild:
+  version bump
 
 *menulibre-13.01.4-r1 (21 Oct 2013)
 



1.1                  x11-misc/menulibre/menulibre-13.04.17.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/menulibre/menulibre-13.04.17.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/menulibre/menulibre-13.04.17.ebuild?rev=1.1&content-type=text/plain

Index: menulibre-13.04.17.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/menulibre/menulibre-13.04.17.ebuild,v 1.1 2013/10/21 17:46:32 hasufell Exp $

EAPI=5

PYTHON_COMPAT=( python2_6 python2_7 )
PYTHON_REQ_USE="xml"
DISTUTILS_IN_SOURCE_BUILD=1
inherit eutils gnome2-utils distutils-r1

DESCRIPTION="An advanced menu editor that provides modern features in a clean, easy-to-use interface"
HOMEPAGE="http://www.smdavis.us/projects/menulibre/"
SRC_URI="http://launchpad.net/${PN}/trunk/${PV}/+download/${PN}_${PV}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="dev-python/python-distutils-extra[${PYTHON_USEDEP}]"
RDEPEND="dev-libs/gobject-introspection
	dev-python/pygobject:3[${PYTHON_USEDEP}]
	dev-python/pyxdg[${PYTHON_USEDEP}]
	x11-libs/gdk-pixbuf[X,introspection]
	x11-libs/gtk+:3[X,introspection]
	x11-libs/gtksourceview:3.0[introspection]
	x11-themes/hicolor-icon-theme"

S=${WORKDIR}/trunk

python_prepare_all() {
	# too many categories
	sed -i \
		-e 's/X-GNOME-Settings-Panel;X-GNOME-PersonalSettings;DesktopSettings;X-XFCE;//' \
		menulibre.desktop.in || die 'sed on menulibre.desktop.in failed'

	local i
	# fix incorrect behavior when LINGUAS is set to an empty string
	# https://bugs.launchpad.net/python-distutils-extra/+bug/1133594
	if [[ -n "${LINGUAS+x}" ]] ; then # if LINGUAS is set
		for i in $(cd "${S}"/po ; for p in *.po ; do echo ${p%.po} ; done) ; do # for every supported language
			if ! has ${i} ${LINGUAS} ; then # if language is disabled
				rm po/${i}.po || die
			fi
		done
	fi

	distutils-r1_python_prepare_all
}

python_install_all() {
	distutils-r1_python_install_all
	newicon -s 32 help/C/figures/icon.png menu-editor.png
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
	elog "optional dependencies:"
	elog "  gnome-extra/yelp (view help contents)"
}

pkg_postrm() {
	gnome2_icon_cache_update
}