[gentoo-commits] gentoo-x86 commit in dev-python/pycrypto: pycrypto-2.6.1.ebuild ChangeLog

["Dirkjan Ochtman (djc)" <djc@gentoo.org>]

djc         13/10/20 08:54:05

  Modified:             ChangeLog
  Added:                pycrypto-2.6.1.ebuild
  Log:
  Version bump pycrypto for bug 488630.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 30380381)

Revision  Changes    Path
1.145                dev-python/pycrypto/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pycrypto/ChangeLog?rev=1.145&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pycrypto/ChangeLog?rev=1.145&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pycrypto/ChangeLog?r1=1.144&r2=1.145

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/pycrypto/ChangeLog,v
retrieving revision 1.144
retrieving revision 1.145
diff -u -r1.144 -r1.145
--- ChangeLog	20 Oct 2013 08:47:25 -0000	1.144
+++ ChangeLog	20 Oct 2013 08:54:05 -0000	1.145
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/pycrypto
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pycrypto/ChangeLog,v 1.144 2013/10/20 08:47:25 djc Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pycrypto/ChangeLog,v 1.145 2013/10/20 08:54:05 djc Exp $
+
+*pycrypto-2.6.1 (20 Oct 2013)
+
+  20 Oct 2013; Dirkjan Ochtman <djc@gentoo.org> +pycrypto-2.6.1.ebuild:
+  Version bump pycrypto for bug 488630.
 
   20 Oct 2013; Dirkjan Ochtman <djc@gentoo.org> -pycrypto-2.3.ebuild,
   -pycrypto-2.4.1.ebuild, -pycrypto-2.5.ebuild, -pycrypto-2.6-r1.ebuild,



1.1                  dev-python/pycrypto/pycrypto-2.6.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pycrypto/pycrypto-2.6.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pycrypto/pycrypto-2.6.1.ebuild?rev=1.1&content-type=text/plain

Index: pycrypto-2.6.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pycrypto/pycrypto-2.6.1.ebuild,v 1.1 2013/10/20 08:54:05 djc Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )

inherit distutils-r1

DESCRIPTION="Python Cryptography Toolkit"
HOMEPAGE="http://www.dlitz.net/software/pycrypto/ http://pypi.python.org/pypi/pycrypto"
SRC_URI="http://ftp.dlitz.net/pub/dlitz/crypto/pycrypto/${P}.tar.gz"

LICENSE="PSF-2 public-domain"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE="doc +gmp"

RDEPEND="gmp? ( dev-libs/gmp )"
DEPEND="${RDEPEND}
	doc? ( dev-python/docutils
		>=dev-python/epydoc-3 )"

python_configure_all() {
	# the configure does not interact with python in any way,
	# it just sets up the C header file.
	econf \
		$(use_with gmp) \
		--without-mpir
}

python_compile_all() {
	if use doc; then
		rst2html.py Doc/pycrypt.rst > Doc/index.html
		epydoc --config=Doc/epydoc-config --exclude-introspect="^Crypto\.(Random\.OSRNG\.nt|Util\.winrandom)$" || die
	fi
}

python_compile() {
	python_is_python3 || local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
	distutils-r1_python_compile
}

python_test() {
	esetup.py test
}

python_install_all() {
	local DOCS=( ACKS ChangeLog README TODO )
	use doc && local HTML_DOCS=( Doc/apidoc/. Doc/index.html )

	distutils-r1_python_install_all
}