* [gentoo-commits] gentoo-x86 commit in net-print/hplip: ChangeLog hplip-3.13.9.ebuild
@ 2013-09-28 10:16 Daniel Pielmeier (billie)
0 siblings, 0 replies; 2+ messages in thread
From: Daniel Pielmeier (billie) @ 2013-09-28 10:16 UTC (permalink / raw
To: gentoo-commits
billie 13/09/28 10:16:55
Modified: ChangeLog
Added: hplip-3.13.9.ebuild
Log:
Version bump. Includes Red Hat's patch to fix CVE-2013-4325.
(Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key 215AD14D)
Revision Changes Path
1.280 net-print/hplip/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/ChangeLog?rev=1.280&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/ChangeLog?rev=1.280&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/ChangeLog?r1=1.279&r2=1.280
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v
retrieving revision 1.279
retrieving revision 1.280
diff -u -r1.279 -r1.280
--- ChangeLog 6 Sep 2013 15:51:32 -0000 1.279
+++ ChangeLog 28 Sep 2013 10:16:55 -0000 1.280
@@ -1,6 +1,11 @@
# ChangeLog for net-print/hplip
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v 1.279 2013/09/06 15:51:32 billie Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v 1.280 2013/09/28 10:16:55 billie Exp $
+
+*hplip-3.13.9 (28 Sep 2013)
+
+ 28 Sep 2013; Daniel Pielmeier <billie@gentoo.org> +hplip-3.13.9.ebuild:
+ Version bump. Includes Red Hat's patch to fix CVE-2013-4325.
06 Sep 2013; Daniel Pielmeier <billie@gentoo.org> -hplip-3.13.6.ebuild:
Remove old.
1.1 net-print/hplip/hplip-3.13.9.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/hplip-3.13.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/hplip-3.13.9.ebuild?rev=1.1&content-type=text/plain
Index: hplip-3.13.9.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/hplip-3.13.9.ebuild,v 1.1 2013/09/28 10:16:55 billie Exp $
EAPI=5
PYTHON_COMPAT=( python{2_6,2_7} )
PYTHON_REQ_USE="threads,xml"
inherit eutils fdo-mime linux-info python-single-r1 udev autotools toolchain-funcs
DESCRIPTION="HP Linux Imaging and Printing. Includes printer, scanner, fax drivers and service tools."
HOMEPAGE="http://hplipopensource.com/hplip-web/index.html"
SRC_URI="mirror://sourceforge/hplip/${P}.tar.gz
http://dev.gentoo.org/~billie/distfiles/${PN}-3.13.9-patches-1.tar.xz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
# zeroconf does not work properly with >=cups-1.4.
# Thus support for it is also disabled in hplip.
IUSE="doc fax +hpcups hpijs kde libnotify -libusb0 minimal parport policykit qt4 scanner snmp static-ppds X"
# TODO: check if net-print/cups, net-analyzer/net-snmp
# are migrated to python-r1
COMMON_DEPEND="
virtual/jpeg
hpijs? ( >=net-print/foomatic-filters-3.0.20080507[cups] )
!minimal? (
${PYTHON_DEPS}
>=net-print/cups-1.4.0
!libusb0? ( virtual/libusb:1 )
libusb0? ( virtual/libusb:0 )
scanner? ( >=media-gfx/sane-backends-1.0.19-r1 )
fax? ( >=sys-apps/dbus-1.6.8-r1 )
snmp? (
net-analyzer/net-snmp
dev-libs/openssl:0
)
)"
DEPEND="${COMMON_DEPEND}
virtual/pkgconfig"
RDEPEND="${COMMON_DEPEND}
>=app-text/ghostscript-gpl-8.71-r3
>=dev-python/dbus-python-1.1.1-r1[${PYTHON_USEDEP}]
policykit? (
sys-auth/polkit
)
!minimal? (
>=dev-python/pygobject-2.28.6-r53:2[${PYTHON_USEDEP}]
kernel_linux? ( virtual/udev !<sys-fs/udev-114 )
scanner? (
>=dev-python/reportlab-2.6[${PYTHON_USEDEP}]
>=virtual/python-imaging-1[${PYTHON_USEDEP}]
X? ( || (
kde? ( kde-misc/skanlite )
media-gfx/xsane
media-gfx/sane-frontends
) )
)
fax? (
>=dev-python/reportlab-2.6[${PYTHON_USEDEP}]
>=dev-python/dbus-python-1.1.1-r1[${PYTHON_USEDEP}]
)
qt4? (
>=dev-python/PyQt4-4.9.6-r2[dbus,X,${PYTHON_USEDEP}]
libnotify? (
>=dev-python/notify-python-0.1.1-r3[${PYTHON_USEDEP}]
)
)
)"
REQUIRED_USE="!minimal? ( ${PYTHON_REQUIRED_USE} )"
CONFIG_CHECK="~PARPORT ~PPDEV"
ERROR_PARPORT="Please make sure kernel parallel port support is enabled (PARPORT and PPDEV)."
pkg_setup() {
use !minimal && python-single-r1_pkg_setup
! use qt4 && ewarn "You need USE=qt4 for the hplip GUI."
use scanner && ! use X && ewarn "You need USE=X for the scanner GUI."
if ! use hpcups && ! use hpijs ; then
ewarn "Installing neither hpcups (USE=-hpcups) nor hpijs (USE=-hpijs) driver,"
ewarn "which is probably not what you want."
ewarn "You will almost certainly not be able to print."
fi
if use minimal ; then
ewarn "Installing driver portions only, make sure you know what you are doing."
ewarn "Depending on the USE flags set for hpcups or hpijs the appropiate driver"
ewarn "is installed. If both USE flags are set hpijs overrides hpcups."
else
use parport && linux-info_pkg_setup
fi
}
src_prepare() {
if use !minimal ; then
python_export EPYTHON PYTHON
python_fix_shebang .
fi
EPATCH_SUFFIX="patch" \
EPATCH_FORCE="yes" \
epatch "${WORKDIR}"
# Make desktop files follow the specification
# Gentoo bug: https://bugs.gentoo.org/show_bug.cgi?id=443680
# Upstream bug: https://bugs.launchpad.net/hplip/+bug/1080324
sed -i -e '/^Categories=/s/Application;//' \
-e '/^Encoding=.*/d' hplip.desktop.in || die
sed -i -e '/^Categories=/s/Application;//' \
-e '/^Version=.*/d' \
-e '/^Comment=.*/d' hplip-systray.desktop.in || die
# Fix for Gentoo bug https://bugs.gentoo.org/show_bug.cgi?id=345725
# Upstream bug: https://bugs.launchpad.net/hplip/+bug/880847,
# https://bugs.launchpad.net/hplip/+bug/500086
local udevdir=$(udev_get_udevdir)
sed -i -e "s|/etc/udev|${udevdir}|g" \
$(find . -type f -exec grep -l /etc/udev {} +) || die
# Force recognition of Gentoo distro by hp-check
sed -i \
-e "s:file('/etc/issue', 'r').read():'Gentoo':" \
installer/core_install.py || die
# Use system foomatic-rip for hpijs driver instead of foomatic-rip-hplip
# The hpcups driver does not use foomatic-rip
local i
for i in ppd/hpijs/*.ppd.gz ; do
rm -f ${i}.temp || die
gunzip -c ${i} | sed 's/foomatic-rip-hplip/foomatic-rip/g' | \
gzip > ${i}.temp || die
mv ${i}.temp ${i} || die
done
eautoreconf
}
src_configure() {
local myconf drv_build minimal_build
if use fax || use qt4 ; then
myconf="${myconf} --enable-dbus-build"
else
myconf="${myconf} --disable-dbus-build"
fi
if use libusb0 ; then
myconf="${myconf} --enable-libusb01_build"
else
myconf="${myconf} --disable-libusb01_build"
fi
if use hpcups ; then
drv_build="$(use_enable hpcups hpcups-install)"
if use static-ppds ; then
drv_build="${drv_build} --enable-cups-ppd-install"
drv_build="${drv_build} --disable-cups-drv-install"
else
drv_build="${drv_build} --enable-cups-drv-install"
drv_build="${drv_build} --disable-cups-ppd-install"
fi
else
drv_build="--disable-hpcups-install"
drv_build="${drv_build} --disable-cups-drv-install"
drv_build="${drv_build} --disable-cups-ppd-install"
fi
if use hpijs ; then
drv_build="${drv_build} $(use_enable hpijs hpijs-install)"
if use static-ppds ; then
drv_build="${drv_build} --enable-foomatic-ppd-install"
drv_build="${drv_build} --disable-foomatic-drv-install"
else
drv_build="${drv_build} --enable-foomatic-drv-install"
drv_build="${drv_build} --disable-foomatic-ppd-install"
fi
else
drv_build="${drv_build} --disable-hpijs-install"
drv_build="${drv_build} --disable-foomatic-drv-install"
drv_build="${drv_build} --disable-foomatic-ppd-install"
fi
if use minimal ; then
if use hpijs ; then
minimal_build="--enable-hpijs-only-build"
else
minimal_build="--disable-hpijs-only-build"
fi
if use hpcups ; then
minimal_build="${minimal_build} --enable-hpcups-only-build"
else
minimal_build="${minimal_build} --disable-hpcups-only-build"
fi
fi
econf \
--disable-cups11-build \
--disable-lite-build \
--disable-foomatic-rip-hplip-install \
--disable-shadow-build \
--disable-qt3 \
--disable-udev_sysfs_rules \
--disable-udev-acl-rules \
--with-cupsbackenddir=$(cups-config --serverbin)/backend \
--with-cupsfilterdir=$(cups-config --serverbin)/filter \
--with-docdir=/usr/share/doc/${PF} \
--with-htmldir=/usr/share/doc/${PF}/html \
${myconf} \
${drv_build} \
${minimal_build} \
$(use_enable doc doc-build) \
$(use_enable fax fax-build) \
$(use_enable parport pp-build) \
$(use_enable scanner scan-build) \
$(use_enable snmp network-build) \
$(use_enable qt4 gui-build) \
$(use_enable qt4) \
$(use_enable policykit)
}
src_install() {
default
# Installed by sane-backends
# Gentoo Bug: https://bugs.gentoo.org/show_bug.cgi?id=201023
rm -f "${D}"/etc/sane.d/dll.conf || die
rm -f "${D}"/usr/share/doc/${PF}/{copyright,README_LIBJPG,COPYING} || die
rmdir --ignore-fail-on-non-empty "${D}"/usr/share/doc/${PF}/ || die
# Remove hal fdi files
rm -rf "${D}"/usr/share/hal || die
find "${D}" -name '*.la' -exec rm -rf {} + || die
if use !minimal ; then
python_export EPYTHON PYTHON
python_optimize "${D}"/usr/share/hplip
fi
}
pkg_preinst() {
# remove temporary directory so it is recreated with correct permissions
# this ensures correct permissions when upgrading from vulnerable versions
# remove this after some time
# Gentoo bug: https://bugs.gentoo.org/show_bug.cgi?id=452586
# Upstream bug: https://bugs.launchpad.net/hplip/+bug/1016507
if [[ $(stat -c '%A' /var/lib/hp/) =~ w.$ ]] ; then
rm -rf "${ROOT%/}/var/log/hp"
fi
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
elog "For more information on setting up your printer please take"
elog "a look at the hplip section of the gentoo printing guide:"
elog "http://www.gentoo.org/doc/en/printing-howto.xml"
elog
elog "Any user who wants to print must be in the lp group."
fi
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-print/hplip: ChangeLog hplip-3.13.9.ebuild
@ 2013-10-14 18:16 Tony Vroon (chainsaw)
0 siblings, 0 replies; 2+ messages in thread
From: Tony Vroon (chainsaw) @ 2013-10-14 18:16 UTC (permalink / raw
To: gentoo-commits
chainsaw 13/10/14 18:16:48
Modified: ChangeLog hplip-3.13.9.ebuild
Log:
Marked stable on AMD64 based on arch tester report by Elijah "Armageddon" El Lazkani in bug #484474.
(Portage version: 2.2.0/cvs/Linux x86_64, signed Manifest commit with key 0xB5058F9A)
Revision Changes Path
1.282 net-print/hplip/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/ChangeLog?rev=1.282&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/ChangeLog?rev=1.282&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/ChangeLog?r1=1.281&r2=1.282
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v
retrieving revision 1.281
retrieving revision 1.282
diff -u -r1.281 -r1.282
--- ChangeLog 28 Sep 2013 10:45:34 -0000 1.281
+++ ChangeLog 14 Oct 2013 18:16:47 -0000 1.282
@@ -1,6 +1,10 @@
# ChangeLog for net-print/hplip
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v 1.281 2013/09/28 10:45:34 billie Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/ChangeLog,v 1.282 2013/10/14 18:16:47 chainsaw Exp $
+
+ 14 Oct 2013; Tony Vroon <chainsaw@gentoo.org> hplip-3.13.9.ebuild:
+ Marked stable on AMD64 based on arch tester report by Elijah "Armageddon" El
+ Lazkani in bug #484474.
28 Sep 2013; Daniel Pielmeier <billie@gentoo.org> -hplip-3.13.7.ebuild,
-hplip-3.13.8.ebuild:
1.2 net-print/hplip/hplip-3.13.9.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/hplip-3.13.9.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/hplip-3.13.9.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/hplip/hplip-3.13.9.ebuild?r1=1.1&r2=1.2
Index: hplip-3.13.9.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/hplip/hplip-3.13.9.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- hplip-3.13.9.ebuild 28 Sep 2013 10:16:55 -0000 1.1
+++ hplip-3.13.9.ebuild 14 Oct 2013 18:16:47 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/hplip-3.13.9.ebuild,v 1.1 2013/09/28 10:16:55 billie Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/hplip/hplip-3.13.9.ebuild,v 1.2 2013/10/14 18:16:47 chainsaw Exp $
EAPI=5
@@ -16,7 +16,7 @@
LICENSE="GPL-2"
SLOT="0"
-KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+KEYWORDS="amd64 ~arm ~ppc ~ppc64 ~x86"
# zeroconf does not work properly with >=cups-1.4.
# Thus support for it is also disabled in hplip.
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2013-10-14 18:16 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-10-14 18:16 [gentoo-commits] gentoo-x86 commit in net-print/hplip: ChangeLog hplip-3.13.9.ebuild Tony Vroon (chainsaw)
-- strict thread matches above, loose matches on Subject: below --
2013-09-28 10:16 Daniel Pielmeier (billie)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox