[gentoo-commits] gentoo-x86 commit in net-libs/libsrtp: ChangeLog libsrtp-1.4.4_p20121108-r1.ebuild

[gentoo-commits] gentoo-x86 commit in net-libs/libsrtp: ChangeLog libsrtp-1.4.4_p20121108-r1.ebuild

[PaweA Hajdan (phajdan.jr)]

phajdan.jr    13/10/13 19:58:24

  Modified:             ChangeLog
  Added:                libsrtp-1.4.4_p20121108-r1.ebuild
  Log:
  Version bump for security bug #472302 .
  
  (Portage version: 2.2.1/cvs/Linux i686, signed Manifest commit with key 30427902)

Revision  Changes    Path
1.30                 net-libs/libsrtp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsrtp/ChangeLog?rev=1.30&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsrtp/ChangeLog?rev=1.30&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsrtp/ChangeLog?r1=1.29&r2=1.30

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/libsrtp/ChangeLog,v
retrieving revision 1.29
retrieving revision 1.30
diff -u -r1.29 -r1.30
--- ChangeLog	1 Oct 2013 15:30:04 -0000	1.29
+++ ChangeLog	13 Oct 2013 19:58:24 -0000	1.30
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/libsrtp
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libsrtp/ChangeLog,v 1.29 2013/10/01 15:30:04 chithanh Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libsrtp/ChangeLog,v 1.30 2013/10/13 19:58:24 phajdan.jr Exp $
+
+*libsrtp-1.4.4_p20121108-r1 (13 Oct 2013)
+
+  13 Oct 2013; Pawel Hajdan jr <phajdan.jr@gentoo.org>
+  +libsrtp-1.4.4_p20121108-r1.ebuild, +files/libsrtp-CVE-2013-2139.diff:
+  Version bump for security bug #472302 .
 
   01 Oct 2013; Chí-Thanh Christopher Nguyễn <chithanh@gentoo.org> metadata.xml:
   Add chainsaw to maintainers.



1.1                  net-libs/libsrtp/libsrtp-1.4.4_p20121108-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsrtp/libsrtp-1.4.4_p20121108-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsrtp/libsrtp-1.4.4_p20121108-r1.ebuild?rev=1.1&content-type=text/plain

Index: libsrtp-1.4.4_p20121108-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libsrtp/libsrtp-1.4.4_p20121108-r1.ebuild,v 1.1 2013/10/13 19:58:24 phajdan.jr Exp $

EAPI="4"

inherit base multilib

MY_PN="srtp"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="Open-source implementation of the Secure Real-time Transport Protocol (SRTP)"
HOMEPAGE="http://srtp.sourceforge.net/srtp.html"
SRC_URI="http://dev.gentoo.org/~phajdan.jr/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 -sparc ~x86 ~x86-fbsd ~ppc-macos ~x64-macos ~x86-macos"
IUSE="aesicm console debug doc static-libs syslog"
PATCHES=(
	"${FILESDIR}/${P}-shared.patch"
	"${FILESDIR}/${PN}-CVE-2013-2139.diff"
	)

S=${WORKDIR}/${MY_PN}

src_configure() {
	# stdout: default error output for messages in debug
	# kernel-linux: breaks the build
	# gdoi: disabled by upstream and breaks the build
	econf \
		--enable-stdout \
		--disable-kernel-linux \
		--disable-gdoi \
		$(use_enable aesicm generic-aesicm) \
		$(use_enable console) \
		$(use_enable debug) \
		$(use_enable syslog)
}

src_compile() {
	if use static-libs; then
		emake ${PN}.a || die "Failed to build static library"
	fi
	emake ${PN}$(get_libname) || die "Failed to build dynamic library"
}

src_test() {
	# getopt returns an int, not a char
	sed -i -e "s/char q/int q/" \
		test/rdbx_driver.c test/srtp_driver.c test/dtls_srtp_driver.c \
		|| die "fixing getopt errors failed"

	# test/rtpw_test.sh is assuming . is in $PATH
	sed -i -e "s:\$RTPW :./\$RTPW :" test/rtpw_test.sh \
		|| die "patching test/rtpw_test.sh failed"

	# test/rtpw.c is using /usr/share/dict/words assuming it exists
	# using test/rtpw.c guaratees the file exists in any case
	sed -i -e "s:/usr/share/dict/words:rtpw.c:" test/rtpw.c \
		|| die "patching test/rtpw.c failed"

	emake test || die "building test failed"
	emake -j1 runtest || die "tests failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc CHANGES README TODO || die "dodoc failed"

	if use doc; then
		# libsrtp.pdf can also be generated with doxygen
		# but it would be a waste of time as an up-to-date version is built
		dodoc doc/*.txt doc/${PN}.pdf || die "dodoc failed"
	fi
}