[gentoo-commits] gentoo-x86 commit in net-wireless/wifi-radar: wifi-radar-2.0.8-r2.ebuild ChangeLog

["Pacho Ramos (pacho)" <pacho@gentoo.org>]

pacho       13/10/13 17:16:00

  Modified:             ChangeLog
  Added:                wifi-radar-2.0.8-r2.ebuild
  Log:
  Use new eclasses, fix ifconfig path (#484380) and add missing dep on sudo (#484378)
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.33                 net-wireless/wifi-radar/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/wifi-radar/ChangeLog?rev=1.33&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/wifi-radar/ChangeLog?rev=1.33&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/wifi-radar/ChangeLog?r1=1.32&r2=1.33

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/wifi-radar/ChangeLog,v
retrieving revision 1.32
retrieving revision 1.33
diff -u -r1.32 -r1.33
--- ChangeLog	2 Feb 2013 12:09:43 -0000	1.32
+++ ChangeLog	13 Oct 2013 17:16:00 -0000	1.33
@@ -1,6 +1,12 @@
 # ChangeLog for net-wireless/wifi-radar
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/wifi-radar/ChangeLog,v 1.32 2013/02/02 12:09:43 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/wifi-radar/ChangeLog,v 1.33 2013/10/13 17:16:00 pacho Exp $
+
+*wifi-radar-2.0.8-r2 (13 Oct 2013)
+
+  13 Oct 2013; Pacho Ramos <pacho@gentoo.org> +wifi-radar-2.0.8-r2.ebuild:
+  Use new eclasses, fix ifconfig path (#484380) and add missing dep on sudo
+  (#484378)
 
   02 Feb 2013; Pacho Ramos <pacho@gentoo.org> -wifi-radar-1.9.8-r1.ebuild,
   -wifi-radar-1.9.9.ebuild, -wifi-radar-2.0.8.ebuild, metadata.xml:



1.1                  net-wireless/wifi-radar/wifi-radar-2.0.8-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/wifi-radar/wifi-radar-2.0.8-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/wifi-radar/wifi-radar-2.0.8-r2.ebuild?rev=1.1&content-type=text/plain

Index: wifi-radar-2.0.8-r2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/wifi-radar/wifi-radar-2.0.8-r2.ebuild,v 1.1 2013/10/13 17:16:00 pacho Exp $

EAPI=5
PYTHON_COMPAT=( python{2_6,2_7} )

inherit eutils versionator python-single-r1 readme.gentoo

MY_PV="$(get_version_component_range 1-2)"
MY_PL="$(get_version_component_range 3)"
MY_PL="s0${MY_PL}"
MY_PV="${MY_PV}.${MY_PL}"

DESCRIPTION="WiFi Radar is a Python/PyGTK2 utility for managing WiFi profiles."
HOMEPAGE="http://wifi-radar.berlios.de/"
SRC_URI="mirror://berlios/${PN}/${PN}-${MY_PV}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

RDEPEND="
	app-admin/sudo
	>=dev-python/pygtk-2.16.0-r1
	>=net-wireless/wireless-tools-29
	|| ( net-misc/dhcpcd net-misc/dhcp net-misc/pump )
"
DEPEND=""

S="${WORKDIR}/${PN}-${MY_PV}"

DISABLE_AUTOFORMATTING="yes"
DOC_CONTENTS="
Remember to edit configuration file /etc/${PN}.conf to suit your needs.
To use ${PN} with a normal user (with sudo) add:
%users   ALL = /usr/sbin/${PN}
in your /etc/sudoers. Also, find the line saying:
Defaults      env_reset
and modify it as follows:
Defaults      env_keep=DISPLAY

Then launch ${PN}.sh
"

src_prepare() {
	sed -i "s:/etc/wpa_supplicant.conf:/etc/wpa_supplicant/wpa_supplicant.conf:" ${PN} || die
	sed -i -e "s:/sbin/ifconfig:/bin/ifconfig:" ${PN} || die
	python_fix_shebang .
}

src_install() {
	dosbin ${PN}
	dobin ${PN}.sh
	doicon -s scalable pixmaps/${PN}.svg
	doicon -s 32 pixmaps/wifi_radar_32x32.png
	doicon pixmaps/${PN}.png
	make_desktop_entry ${PN}.sh "WiFi Radar" ${PN} Network

	doman man/man1/${PN}.1 man/man5/${PN}.conf.5

	cd docs
	dodoc BUGS CREDITS DEVELOPER_GUIDELINES HISTORY README README.WPA-Mini-HOWTO.txt TODO
	keepdir /etc/${PN}

	readme.gentoo_create_doc
}