[gentoo-commits] gentoo-x86 commit in app-editors/mg: ChangeLog mg-20130922-r1.ebuild mg-20130922.ebuild

[gentoo-commits] gentoo-x86 commit in app-editors/mg: ChangeLog mg-20130922-r1.ebuild mg-20130922.ebuild

[Ulrich Mueller (ulm)]

ulm         13/10/13 07:12:46

  Modified:             ChangeLog
  Added:                mg-20130922-r1.ebuild
  Removed:              mg-20130922.ebuild
  Log:
  Fix dirname(3) call in writeout function, bug 487758.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 9433907D693FB5B8!)

Revision  Changes    Path
1.61                 app-editors/mg/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/mg/ChangeLog?rev=1.61&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/mg/ChangeLog?rev=1.61&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/mg/ChangeLog?r1=1.60&r2=1.61

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/mg/ChangeLog,v
retrieving revision 1.60
retrieving revision 1.61
diff -u -r1.60 -r1.61
--- ChangeLog	9 Oct 2013 10:06:19 -0000	1.60
+++ ChangeLog	13 Oct 2013 07:12:45 -0000	1.61
@@ -1,6 +1,13 @@
 # ChangeLog for app-editors/mg
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/mg/ChangeLog,v 1.60 2013/10/09 10:06:19 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/mg/ChangeLog,v 1.61 2013/10/13 07:12:45 ulm Exp $
+
+*mg-20130922-r1 (13 Oct 2013)
+
+  13 Oct 2013; Ulrich Müller <ulm@gentoo.org> -mg-20130922.ebuild,
+  +mg-20130922-r1.ebuild, +files/mg-20130922-dirname.patch:
+  Fix dirname(3) call in writeout function, bug 487758. Thanks to Marien Zwart
+  <marienz@gentoo.org>.
 
   09 Oct 2013; Ulrich Müller <ulm@gentoo.org> mg-20130922.ebuild:
   Specify CPPFLAGS not CFLAGS for preprocessor options. Add missing EPREFIX.



1.1                  app-editors/mg/mg-20130922-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/mg/mg-20130922-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/mg/mg-20130922-r1.ebuild?rev=1.1&content-type=text/plain

Index: mg-20130922-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/mg/mg-20130922-r1.ebuild,v 1.1 2013/10/13 07:12:46 ulm Exp $

EAPI=5

inherit eutils toolchain-funcs

DESCRIPTION="MicroGnuEmacs, a port from the BSDs"
HOMEPAGE="http://homepage.boetes.org/software/mg/"
SRC_URI="http://homepage.boetes.org/software/mg/${P}.tar.gz"

LICENSE="public-domain"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~x86"
IUSE="livecd"

RDEPEND="sys-libs/ncurses"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	dev-libs/clens"

src_prepare() {
	epatch "${FILESDIR}"/${P}-dirname.patch
	epatch_user

	# create our own Makefile to avoid BSD make
	echo -e 'SRCS =' *.c '\n\nmg: $(SRCS:.c=.o)' \
		'\n\t$(CC) $(LDFLAGS) -o $@ $^ $(LDLIBS)' >Makefile || die

	# remove OpenBSD specific easter egg
	sed -i -e 's/theo\.c//' Makefile || die
	sed -i -e '/theo_init/d' main.c || die

	# fix path to tutorial in man page
	sed -i -e "s:doc/mg/:doc/${PF}/:" mg.1 || die
}

src_compile() {
	emake CC="$(tc-getCC)" \
		CPPFLAGS="${CPPFLAGS} -DFKEYS -DREGEX -DXKEYS \
			-I${EPREFIX}/usr/include/clens" \
		LDLIBS="-lclens $("$(tc-getPKG_CONFIG)" --libs ncurses)"
}

src_install()  {
	dobin mg
	doman mg.1
	dodoc README README_PORTING tutorial
	# don't compress the tutorial, otherwise mg cannot open it
	docompress -x /usr/share/doc/${PF}/tutorial
}

pkg_postinst() {
	if use livecd; then
		[[ -e ${EROOT}/usr/bin/emacs ]] || ln -s mg "${EROOT}"/usr/bin/emacs
	fi
}