[gentoo-commits] gentoo-x86 commit in mail-client/geary: geary-0.4.0.ebuild ChangeLog geary-0.4.0_pre2.ebuild

[gentoo-commits] gentoo-x86 commit in mail-client/geary: geary-0.4.0.ebuild ChangeLog geary-0.4.0_pre2.ebuild

[Julian Ospald (hasufell)]

hasufell    13/10/06 16:41:42

  Modified:             ChangeLog
  Added:                geary-0.4.0.ebuild
  Removed:              geary-0.4.0_pre2.ebuild
  Log:
  version bump wrt #487054
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.6                  mail-client/geary/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/geary/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/geary/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/geary/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-client/geary/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	22 Sep 2013 13:06:15 -0000	1.5
+++ ChangeLog	6 Oct 2013 16:41:41 -0000	1.6
@@ -1,6 +1,14 @@
 # ChangeLog for mail-client/geary
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/geary/ChangeLog,v 1.5 2013/09/22 13:06:15 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/geary/ChangeLog,v 1.6 2013/10/06 16:41:41 hasufell Exp $
+
+*geary-0.4.0 (06 Oct 2013)
+
+  06 Oct 2013; Julian Ospald <hasufell@gentoo.org>
+  +files/geary-0.4.0-cflags.patch, +files/geary-0.4.0-unity.patch,
+  +geary-0.4.0.ebuild, -files/geary-0.4.0_pre2-cflags.patch,
+  -files/geary-0.4.0_pre2-unity.patch, -geary-0.4.0_pre2.ebuild:
+  version bump wrt #487054
 
 *geary-0.4.0_pre2 (22 Sep 2013)
 



1.1                  mail-client/geary/geary-0.4.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/geary/geary-0.4.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/geary/geary-0.4.0.ebuild?rev=1.1&content-type=text/plain

Index: geary-0.4.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-client/geary/geary-0.4.0.ebuild,v 1.1 2013/10/06 16:41:41 hasufell Exp $

EAPI=5

VALA_MIN_API_VERSION=0.20

inherit eutils fdo-mime gnome2-utils vala cmake-utils

MY_P=${P/_pre/pr}
DESCRIPTION="A lightweight, easy-to-use, feature-rich email client"
HOMEPAGE="http://www.yorba.org/projects/geary/"
SRC_URI="http://yorba.org/download/geary/${PV:0:3}/${MY_P}.tar.xz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="nls"

DEPEND="
	app-crypt/libsecret
	dev-db/sqlite:3
	dev-libs/glib:2
	>=dev-libs/libgee-0.8.5:0.8
	dev-libs/libunique:3
	dev-libs/libxml2:2
	dev-libs/gmime:2.6
	media-libs/libcanberra
	>=net-libs/webkit-gtk-1.10.0:3[introspection]
	<net-libs/webkit-gtk-2.0.4:3[introspection]
	>=x11-libs/gtk+-3.6.0:3[introspection]
	x11-libs/libnotify"
RDEPEND="${DEPEND}
	gnome-base/gsettings-desktop-schemas
	nls? ( virtual/libintl )"
DEPEND="${DEPEND}
	nls? ( sys-devel/gettext )
	$(vala_depend)
	virtual/pkgconfig"

DOCS=( AUTHORS MAINTAINERS README NEWS THANKS )

S=${WORKDIR}/${MY_P}

src_prepare() {
	epatch "${FILESDIR}"/${P}-{unity,cflags}.patch

	local i
	if use nls ; then
		if [[ -n "${LINGUAS+x}" ]] ; then
			for i in $(cd po ; echo *.po) ; do
				if ! has ${i%.po} ${LINGUAS} ; then
					sed -i -e "s/\s${i%.po}$//" po/CMakeLists.txt || die
					rm po/${i} || die
				fi
			done
		fi
	else
		sed -i -e 's#add_subdirectory(po)##' CMakeLists.txt || die
	fi

	cmake-utils_src_prepare
	vala_src_prepare
}

src_configure() {
	local mycmakeargs=(
		-DDESKTOP_UPDATE=OFF
		-DGSETTINGS_COMPILE=OFF
		-DICON_UPDATE=OFF
		-DVALA_EXECUTABLE="${VALAC}"
		-DWITH_UNITY=OFF
		-DDESKTOP_VALIDATE=OFF
	)

	cmake-utils_src_configure
}

pkg_preinst() {
	gnome2_icon_savelist
	gnome2_schemas_savelist
}

pkg_postinst() {
	elog "For libnotify sounds you will need"
	elog "\"alsa\" or \"pulseaudio\" useflag of media-libs/libcanberra"
	elog "enabled."

	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
	gnome2_schemas_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
	gnome2_schemas_update
}