* [gentoo-commits] gentoo-x86 commit in app-admin/hddtemp: hddtemp-0.3_beta15-r24.ebuild hddtemp-0.3_beta15-r7.ebuild ChangeLog
@ 2013-09-28 8:09 Pacho Ramos (pacho)
0 siblings, 0 replies; only message in thread
From: Pacho Ramos (pacho) @ 2013-09-28 8:09 UTC (permalink / raw
To: gentoo-commits
pacho 13/09/28 08:09:02
Modified: ChangeLog
Added: hddtemp-0.3_beta15-r24.ebuild
hddtemp-0.3_beta15-r7.ebuild
Log:
Fix unit file (#485924 by Tilo Prütz)
(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)
Revision Changes Path
1.138 app-admin/hddtemp/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/hddtemp/ChangeLog?rev=1.138&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/hddtemp/ChangeLog?rev=1.138&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/hddtemp/ChangeLog?r1=1.137&r2=1.138
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/hddtemp/ChangeLog,v
retrieving revision 1.137
retrieving revision 1.138
diff -u -r1.137 -r1.138
--- ChangeLog 6 Sep 2013 18:33:17 -0000 1.137
+++ ChangeLog 28 Sep 2013 08:09:02 -0000 1.138
@@ -1,6 +1,14 @@
# ChangeLog for app-admin/hddtemp
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/hddtemp/ChangeLog,v 1.137 2013/09/06 18:33:17 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/hddtemp/ChangeLog,v 1.138 2013/09/28 08:09:02 pacho Exp $
+
+*hddtemp-0.3_beta15-r24 (28 Sep 2013)
+*hddtemp-0.3_beta15-r7 (28 Sep 2013)
+
+ 28 Sep 2013; Pacho Ramos <pacho@gentoo.org> +files/hddtemp.service-r1,
+ +files/hddtemp.service.conf, +hddtemp-0.3_beta15-r24.ebuild,
+ +hddtemp-0.3_beta15-r7.ebuild:
+ Fix unit file (#485924 by Tilo Prütz)
06 Sep 2013; Agostino Sarubbo <ago@gentoo.org> hddtemp-0.3_beta15-r6.ebuild:
Stable for sparc, wrt bug #480036
1.1 app-admin/hddtemp/hddtemp-0.3_beta15-r24.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/hddtemp/hddtemp-0.3_beta15-r24.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/hddtemp/hddtemp-0.3_beta15-r24.ebuild?rev=1.1&content-type=text/plain
Index: hddtemp-0.3_beta15-r24.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/hddtemp/hddtemp-0.3_beta15-r24.ebuild,v 1.1 2013/09/28 08:09:02 pacho Exp $
EAPI=4
inherit eutils autotools systemd
MY_P=${P/_beta/-beta}
DBV=20080531
DESCRIPTION="A simple utility to read the temperature of SMART capable hard drives"
HOMEPAGE="http://savannah.nongnu.org/projects/hddtemp/"
SRC_URI="http://download.savannah.gnu.org/releases/hddtemp/${MY_P}.tar.bz2 mirror://gentoo/hddtemp-${DBV}.db.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~sparc ~x86"
IUSE="network-cron nls"
DEPEND=""
RDEPEND="${DEPEND}"
S="${WORKDIR}/${MY_P}"
DOCS=(README TODO ChangeLog)
src_prepare() {
epatch "${FILESDIR}"/${P}-satacmds.patch
epatch "${FILESDIR}"/${P}-byteswap.patch
epatch "${FILESDIR}"/${P}-execinfo.patch
epatch "${FILESDIR}"/${P}-nls.patch
epatch "${FILESDIR}"/${P}-iconv.patch
epatch "${FILESDIR}"/${P}-dontwake.patch
AT_M4DIR="m4" eautoreconf
}
src_configure() {
local myconf
myconf="--with-db-path=/usr/share/hddtemp/hddtemp.db"
# disabling nls breaks compiling
use nls || myconf="--disable-nls ${myconf}"
econf ${myconf}
}
src_install() {
default
insinto /usr/share/hddtemp
newins "${WORKDIR}/hddtemp-${DBV}.db" hddtemp.db
doins "${FILESDIR}"/hddgentoo.db
update_db "${D}/usr/share/hddtemp/hddgentoo.db" "${D}/usr/share/hddtemp/hddtemp.db"
newconfd "${FILESDIR}"/hddtemp-conf.d hddtemp
newinitd "${FILESDIR}"/hddtemp-init hddtemp
systemd_newunit "${FILESDIR}"/hddtemp.service-r1 "${PN}.service"
systemd_install_serviced "${FILESDIR}"/hddtemp.service.conf
dosbin "${FILESDIR}"/update-hddtemp.db
if use network-cron ; then
exeinto /etc/cron.monthly
echo -e "#!/bin/sh\n/usr/sbin/update-hddtemp.db" > "${T}"/hddtemp.cron
newexe "${T}"/hddtemp.cron update-hddtemp.db
fi
}
pkg_postinst() {
elog "In order to update your hddtemp database, run:"
elog " update-hddtemp.db"
elog ""
elog "If your hard drive is not recognized by hddtemp, please consider"
elog "submitting your HDD info for inclusion into the Gentoo hddtemp"
elog "database by filing a bug at https://bugs.gentoo.org/"
echo
ewarn "If hddtemp complains but finds your HDD temperature sensor, use the"
ewarn "--quiet option to suppress the warning."
}
update_db() {
local src=$1
local dst=$2
while read line ; do
if [[ -z $(echo "${line}" | sed -re 's/(^#.*|^\w*$)//') ]]; then
echo "${line}" >> "${dst}"
fi
id=$(echo "${line}" | grep -o '"[^"]*"')
grep "${id}" "${dst}" 2>&1 >/dev/null || echo "${line}" >> "${dst}"
done < "${src}"
}
1.1 app-admin/hddtemp/hddtemp-0.3_beta15-r7.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/hddtemp/hddtemp-0.3_beta15-r7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/hddtemp/hddtemp-0.3_beta15-r7.ebuild?rev=1.1&content-type=text/plain
Index: hddtemp-0.3_beta15-r7.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/hddtemp/hddtemp-0.3_beta15-r7.ebuild,v 1.1 2013/09/28 08:09:02 pacho Exp $
inherit eutils autotools systemd
MY_P=${P/_beta/-beta}
DBV=20080531
DESCRIPTION="A simple utility to read the temperature of SMART capable hard drives"
HOMEPAGE="http://savannah.nongnu.org/projects/hddtemp/"
SRC_URI="http://download.savannah.gnu.org/releases/hddtemp/${MY_P}.tar.bz2 mirror://gentoo/hddtemp-${DBV}.db.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~sparc ~x86"
IUSE="nls"
DEPEND=""
RDEPEND="${DEPEND}"
S="${WORKDIR}/${MY_P}"
src_unpack() {
unpack ${A}
cd "${S}"
epatch "${FILESDIR}"/${P}-satacmds.patch
epatch "${FILESDIR}"/${P}-byteswap.patch
epatch "${FILESDIR}"/${P}-execinfo.patch
epatch "${FILESDIR}"/${P}-nls.patch
epatch "${FILESDIR}"/${P}-iconv.patch
epatch "${FILESDIR}"/${P}-dontwake.patch
AT_M4DIR="m4" eautoreconf
}
src_compile() {
local myconf
myconf="--with-db-path=/usr/share/hddtemp/hddtemp.db"
# disabling nls breaks compiling
use nls || myconf="--disable-nls ${myconf}"
econf ${myconf} || die
emake || die
}
src_install() {
make DESTDIR="${D}" install || die
dodoc README TODO ChangeLog
insinto /usr/share/hddtemp
newins "${WORKDIR}/hddtemp-${DBV}.db" hddtemp.db
doins "${FILESDIR}"/hddgentoo.db
update_db "${D}/usr/share/hddtemp/hddgentoo.db" "${D}/usr/share/hddtemp/hddtemp.db"
newconfd "${FILESDIR}"/hddtemp-conf.d hddtemp
newinitd "${FILESDIR}"/hddtemp-init hddtemp
systemd_newunit "${FILESDIR}"/hddtemp.service-r1 "${PN}.service"
systemd_install_serviced "${FILESDIR}"/hddtemp.service.conf
}
pkg_postinst() {
elog "In order to update your hddtemp database, run:"
elog " emerge --config =${CATEGORY}/${PF}"
elog ""
elog "If your hard drive is not recognized by hddtemp, please consider"
elog "submitting your HDD info for inclusion into the Gentoo hddtemp"
elog "database by filing a bug at https://bugs.gentoo.org/"
echo
ewarn "If hddtemp complains but finds your HDD temperature sensor, use the"
ewarn "--quiet option to suppress the warning."
}
update_db() {
local src=$1
local dst=$2
while read line ; do
if [[ -z $(echo "${line}" | sed -re 's/(^#.*|^\w*$)//') ]]; then
echo "${line}" >> "${dst}"
fi
id=$(echo "${line}" | grep -o '"[^"]*"')
grep "${id}" "${dst}" 2>&1 >/dev/null || echo "${line}" >> "${dst}"
done < "${src}"
}
pkg_config() {
cd "${ROOT}"/usr/share/hddtemp
einfo "Trying to download the latest hddtemp.db file"
wget http://www.guzu.net/linux/hddtemp.db -O hddtemp.db \
|| die "failed to download hddtemp.db"
update_db "hddgentoo.db" "hddtemp.db"
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-09-28 8:09 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-09-28 8:09 [gentoo-commits] gentoo-x86 commit in app-admin/hddtemp: hddtemp-0.3_beta15-r24.ebuild hddtemp-0.3_beta15-r7.ebuild ChangeLog Pacho Ramos (pacho)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox