* [gentoo-commits] gentoo-x86 commit in net-firewall/pglinux: pglinux-2.2.2-r1.ebuild ChangeLog
@ 2013-09-23 23:55 Julian Ospald (hasufell)
0 siblings, 0 replies; only message in thread
From: Julian Ospald (hasufell) @ 2013-09-23 23:55 UTC (permalink / raw
To: gentoo-commits
hasufell 13/09/23 23:55:18
Modified: ChangeLog
Added: pglinux-2.2.2-r1.ebuild
Log:
add systemd support wrt #485674
(Portage version: 2.2.6/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)
Revision Changes Path
1.15 net-firewall/pglinux/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/pglinux/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/pglinux/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/pglinux/ChangeLog?r1=1.14&r2=1.15
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-firewall/pglinux/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog 3 May 2013 16:43:51 -0000 1.14
+++ ChangeLog 23 Sep 2013 23:55:18 -0000 1.15
@@ -1,6 +1,18 @@
# ChangeLog for net-firewall/pglinux
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-firewall/pglinux/ChangeLog,v 1.14 2013/05/03 16:43:51 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-firewall/pglinux/ChangeLog,v 1.15 2013/09/23 23:55:18 hasufell Exp $
+
+*pglinux-2.2.2-r1 (23 Sep 2013)
+
+ 23 Sep 2013; Julian Ospald <hasufell@gentoo.org> +pglinux-2.2.2-r1.ebuild,
+ +files/0-pglinux-2.2.2-gentoo-init.patch,
+ +files/1-pglinux-2.2.2-gentoo-init.patch,
+ +files/pglinux-2.2.2-path-variables.patch,
+ +files/0-pglinux-2.2.2-systemd.patch, +files/1-pglinux-2.2.2-systemd.patch,
+ +files/2-pglinux-2.2.2-systemd.patch, +files/3-pglinux-2.2.2-systemd.patch,
+ +files/4-pglinux-2.2.2-systemd.patch, +files/5-pglinux-2.2.2-systemd.patch,
+ +files/6-pglinux-2.2.2-systemd.patch:
+ add systemd support wrt #485674
03 May 2013; Julian Ospald <hasufell@gentoo.org> pglinux-2.2.2.ebuild:
ensure that empty pgl specific dirs are not removed by PM
1.1 net-firewall/pglinux/pglinux-2.2.2-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/pglinux/pglinux-2.2.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/pglinux/pglinux-2.2.2-r1.ebuild?rev=1.1&content-type=text/plain
Index: pglinux-2.2.2-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/pglinux/pglinux-2.2.2-r1.ebuild,v 1.1 2013/09/23 23:55:18 hasufell Exp $
EAPI=5
inherit autotools eutils gnome2-utils linux-info systemd
MY_P="pgl-${PV}"
DESCRIPTION="Privacy oriented firewall application"
HOMEPAGE="https://sourceforge.net/projects/peerguardian/"
SRC_URI="mirror://sourceforge/peerguardian/${MY_P}.tar.gz"
LICENSE="GPL-3"
KEYWORDS="~amd64 ~x86"
SLOT="0"
IUSE="cron dbus logrotate networkmanager qt4 zlib"
COMMON_DEPEND="
net-libs/libnetfilter_queue
net-libs/libnfnetlink
dbus? ( sys-apps/dbus )
zlib? ( sys-libs/zlib )
qt4? ( sys-auth/polkit-qt
dev-qt/qtcore:4
dev-qt/qtdbus:4
dev-qt/qtgui:4
|| ( kde-base/kdesu x11-libs/gksu x11-misc/ktsuss )
)"
DEPEND="${COMMON_DEPEND}
virtual/pkgconfig
sys-devel/libtool:2"
RDEPEND="${COMMON_DEPEND}
net-firewall/iptables
sys-apps/sysvinit
cron? ( virtual/cron )
logrotate? ( app-admin/logrotate )
networkmanager? ( net-misc/networkmanager )"
REQUIRED_USE="qt4? ( dbus )"
CONFIG_CHECK="~NETFILTER_NETLINK
~NETFILTER_NETLINK_QUEUE
~NETFILTER_XTABLES
~NETFILTER_XT_TARGET_NFQUEUE
~NETFILTER_XT_MATCH_IPRANGE
~NETFILTER_XT_MARK
~NETFILTER_XT_MATCH_MULTIPORT
~NETFILTER_XT_MATCH_STATE
~NF_CONNTRACK
~NF_CONNTRACK_IPV4
~NF_DEFRAG_IPV4
~IP_NF_FILTER
~IP_NF_IPTABLES
~IP_NF_TARGET_REJECT"
S=${WORKDIR}/${MY_P}
src_prepare() {
epatch -p2 "${FILESDIR}"/${P}-path-variables.patch \
"${FILESDIR}"/{0,1}-${P}-gentoo-init.patch \
"${FILESDIR}"/{0..6}-${P}-systemd.patch
eautoreconf
}
src_configure() {
econf \
--localstatedir=/var \
--docdir=/usr/share/doc/${PF} \
$(use_enable logrotate) \
$(use_enable cron) \
$(use_enable networkmanager) \
$(use_enable zlib) \
$(use_enable dbus) \
--disable-lowmem \
--with-iconsdir=/usr/share/icons/hicolor/128x128/apps \
--with-gentoo-init \
$(use_with qt4) \
--with-systemd="$(systemd_get_unitdir)"
}
src_install() {
default
keepdir /var/{lib,log,spool}/pgl
rm -rf "${ED}"/tmp
}
pkg_preinst() {
gnome2_icon_savelist
}
pkg_postinst() {
elog "optional dependencies:"
elog " app-arch/p7zip (needed for blocklists packed as .7z)"
elog " app-arch/unzip (needed for blocklists packed as .zip)"
elog " virtual/mta (needed to send informational (blocklist updates) and"
elog " warning mails (if pglcmd.wd detects a problem.))"
gnome2_icon_cache_update
}
pkg_postrm() {
gnome2_icon_cache_update
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-09-23 23:55 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-09-23 23:55 [gentoo-commits] gentoo-x86 commit in net-firewall/pglinux: pglinux-2.2.2-r1.ebuild ChangeLog Julian Ospald (hasufell)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox