* [gentoo-commits] gentoo-x86 commit in x11-misc/lightdm: ChangeLog lightdm-1.7.16.ebuild
@ 2013-09-20 21:30 Patrick McLean (chutzpah)
0 siblings, 0 replies; only message in thread
From: Patrick McLean (chutzpah) @ 2013-09-20 21:30 UTC (permalink / raw
To: gentoo-commits
chutzpah 13/09/20 21:30:39
Modified: ChangeLog
Added: lightdm-1.7.16.ebuild
Log:
Version bump, fixes bug #479660.
(Portage version: 2.2.4/cvs/Linux x86_64, signed Manifest commit with key 0xE3F69979BB4B8928DA78E3D17CBF44EF)
Revision Changes Path
1.72 x11-misc/lightdm/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/ChangeLog?rev=1.72&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/ChangeLog?rev=1.72&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/ChangeLog?r1=1.71&r2=1.72
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/lightdm/ChangeLog,v
retrieving revision 1.71
retrieving revision 1.72
diff -u -r1.71 -r1.72
--- ChangeLog 11 Sep 2013 19:48:10 -0000 1.71
+++ ChangeLog 20 Sep 2013 21:30:39 -0000 1.72
@@ -1,6 +1,11 @@
# ChangeLog for x11-misc/lightdm
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/ChangeLog,v 1.71 2013/09/11 19:48:10 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/ChangeLog,v 1.72 2013/09/20 21:30:39 chutzpah Exp $
+
+*lightdm-1.7.16 (20 Sep 2013)
+
+ 20 Sep 2013; Patrick McLean <chutzpah@gentoo.org> +lightdm-1.7.16.ebuild:
+ Version bump, fixes bug #479660.
*lightdm-1.7.15 (11 Sep 2013)
*lightdm-1.4.3 (11 Sep 2013)
1.1 x11-misc/lightdm/lightdm-1.7.16.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/lightdm-1.7.16.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/lightdm-1.7.16.ebuild?rev=1.1&content-type=text/plain
Index: lightdm-1.7.16.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/lightdm-1.7.16.ebuild,v 1.1 2013/09/20 21:30:39 chutzpah Exp $
EAPI=5
inherit autotools eutils pam readme.gentoo systemd
TRUNK_VERSION="1.7"
DESCRIPTION="A lightweight display manager"
HOMEPAGE="http://www.freedesktop.org/wiki/Software/LightDM"
SRC_URI="http://launchpad.net/${PN}/${TRUNK_VERSION}/${PV}/+download/${P}.tar.xz
mirror://gentoo/introspection-20110205.m4.tar.bz2"
LICENSE="GPL-3 LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~x86"
IUSE="+gtk +introspection kde qt4 razor"
REQUIRED_USE="|| ( gtk kde razor )"
COMMON_DEPEND=">=dev-libs/glib-2.32.3:2
dev-libs/libxml2
sys-apps/accountsservice
virtual/pam
x11-libs/libX11
>=x11-libs/libxklavier-5
introspection? ( >=dev-libs/gobject-introspection-1 )
qt4? (
dev-qt/qtcore:4
dev-qt/qtdbus:4
dev-qt/qtgui:4
)"
RDEPEND="${COMMON_DEPEND}
>=sys-auth/pambase-20101024-r2"
DEPEND="${COMMON_DEPEND}
dev-util/gtk-doc-am
dev-util/intltool
gnome-base/gnome-common
sys-devel/gettext
virtual/pkgconfig"
PDEPEND="gtk? ( x11-misc/lightdm-gtk-greeter )
kde? ( x11-misc/lightdm-kde )
razor? ( razorqt-base/razorqt-lightdm-greeter )"
DOCS=( NEWS )
src_prepare() {
sed -i -e 's:getgroups:lightdm_&:' tests/src/libsystem.c || die #412369
sed -i -e '/minimum-uid/s:500:1000:' data/users.conf || die
epatch "${FILESDIR}"/${PN}-1.7.7-session-wrapper.patch
epatch_user
# Remove bogus Makefile statement. This needs to go upstream
sed -i /"@YELP_HELP_RULES@"/d help/Makefile.am || die
if has_version dev-libs/gobject-introspection; then
eautoreconf
else
AT_M4DIR=${WORKDIR} eautoreconf
fi
}
src_configure() {
# Set default values if global vars unset
local _greeter _session _user
_greeter=${LIGHTDM_GREETER:=lightdm-gtk-greeter}
_session=${LIGHTDM_SESSION:=gnome}
_user=${LIGHTDM_USER:=root}
# Let user know how lightdm is configured
einfo "Gentoo configuration"
einfo "Default greeter: ${_greeter}"
einfo "Default session: ${_session}"
einfo "Greeter user: ${_user}"
econf \
--localstatedir=/var \
--disable-static \
$(use_enable introspection) \
$(use_enable qt4 liblightdm-qt) \
--with-user-session=${_session} \
--with-greeter-session=${_greeter} \
--with-greeter-user=${_user} \
--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
}
src_install() {
default
insinto /etc/${PN}
doins data/{${PN},keys}.conf
doins "${FILESDIR}"/Xsession
fperms +x /etc/${PN}/Xsession
prune_libtool_files --all
rm -rf "${ED}"/etc/init
pamd_mimic system-local-login ${PN} auth account session #372229
dopamd "${FILESDIR}"/${PN}-autologin #390863, #423163
readme.gentoo_create_doc
systemd_dounit "${FILESDIR}/${PN}.service"
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-09-20 21:30 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-09-20 21:30 [gentoo-commits] gentoo-x86 commit in x11-misc/lightdm: ChangeLog lightdm-1.7.16.ebuild Patrick McLean (chutzpah)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox