[gentoo-commits] gentoo-x86 commit in net-im/prosody: prosody-0.9.1-r1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-im/prosody: prosody-0.9.1-r1.ebuild ChangeLog

[Tobias Klausmann (klausman)]

klausman    13/09/16 21:54:02

  Modified:             ChangeLog
  Added:                prosody-0.9.1-r1.ebuild
  Log:
  Fix multilib-strict failure of 0.9.1, thanks to mrueg@ for the patch
  
  (Portage version: 2.2.3/cvs/Linux x86_64, signed Manifest commit with key CE5D54E8)

Revision  Changes    Path
1.29                 net-im/prosody/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/prosody/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/prosody/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/prosody/ChangeLog?r1=1.28&r2=1.29

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/prosody/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog	16 Sep 2013 16:41:37 -0000	1.28
+++ ChangeLog	16 Sep 2013 21:54:02 -0000	1.29
@@ -1,6 +1,11 @@
 # ChangeLog for net-im/prosody
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/prosody/ChangeLog,v 1.28 2013/09/16 16:41:37 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/prosody/ChangeLog,v 1.29 2013/09/16 21:54:02 klausman Exp $
+
+*prosody-0.9.1-r1 (16 Sep 2013)
+
+  16 Sep 2013; Tobias Klausmann <klausman@gentoo.org> +prosody-0.9.1-r1.ebuild:
+  Fix multilib-strict failure of 0.9.1, thanks to mrueg@ for the patch
 
   16 Sep 2013; Tobias Klausmann <klausman@gentoo.org> prosody-0.9.1.ebuild:
   Rekeyword prosody-0.9.1 and make luasocket dep USE-conditional



1.1                  net-im/prosody/prosody-0.9.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/prosody/prosody-0.9.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/prosody/prosody-0.9.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: prosody-0.9.1-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/prosody/prosody-0.9.1-r1.ebuild,v 1.1 2013/09/16 21:54:02 klausman Exp $

EAPI=5

inherit flag-o-matic multilib versionator

MY_PV=$(replace_version_separator 3 '')
MY_P="${PN}-${MY_PV}"
DESCRIPTION="Prosody is a flexible communications server for Jabber/XMPP written in Lua."
HOMEPAGE="http://prosody.im/"
SRC_URI="http://prosody.im/tmp/${MY_PV}/${MY_P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="ipv6 libevent mysql postgres sqlite ssl zlib"

DEPEND="net-im/jabber-base
		>=dev-lang/lua-5.1
		>=net-dns/libidn-1.1
		>=dev-libs/openssl-0.9.8"
RDEPEND="${DEPEND}
		dev-lua/luaexpat
		dev-lua/luafilesystem
		ipv6? ( >=dev-lua/luasocket-3 )
		!ipv6? ( dev-lua/luasocket )
		libevent? ( >=dev-lua/luaevent-0.4.3 )
		mysql? ( dev-lua/luadbi[mysql] )
		postgres? ( dev-lua/luadbi[postgres] )
		sqlite? ( dev-lua/luadbi[sqlite] )
		ssl? ( dev-lua/luasec )
		zlib? ( dev-lua/lua-zlib )"

S=${WORKDIR}/${MY_P}

JABBER_ETC="/etc/jabber"
JABBER_SPOOL="/var/spool/jabber"

src_prepare() {
	sed -i -e "s!MODULES = \$(DESTDIR)\$(PREFIX)/lib/!MODULES = \$(DESTDIR)\$(PREFIX)/$(get_libdir)/!"\
		-e "s!SOURCE = \$(DESTDIR)\$(PREFIX)/lib/!SOURCE = \$(DESTDIR)\$(PREFIX)/$(get_libdir)/!"\
		-e "s!INSTALLEDSOURCE = \$(PREFIX)/lib/!INSTALLEDSOURCE = \$(PREFIX)/$(get_libdir)/!"\
		-e "s!INSTALLEDMODULES = \$(PREFIX)/lib/!INSTALLEDMODULES = \$(PREFIX)/$(get_libdir)/!"\
		 Makefile || die
}

src_configure() {
	# the configure script is handcrafted (and yells at unknown options)
	# hence do not use 'econf'
	append-cflags -D_GNU_SOURCE
	./configure \
		--ostype=linux \
		--prefix="/usr" \
		--sysconfdir="${JABBER_ETC}" \
		--datadir="${JABBER_SPOOL}" \
		--with-lua-include=/usr/include \
		--with-lua-lib=/usr/$(get_libdir)/lua \
		--cflags="${CFLAGS} -Wall -fPIC" \
		--ldflags="${LDFLAGS} -shared" \
		--c-compiler="$(tc-getCC)" \
		--linker="$(tc-getCC)" \
		--require-config || die "configure failed"
}

src_install() {
	emake DESTDIR="${D}" install
	newinitd "${FILESDIR}/${PN}".initd ${PN}
}

src_test() {
	cd tests || die
	./run_tests.sh || die
}