[gentoo-commits] gentoo-x86 commit in app-office/calligra-l10n: calligra-l10n-2.7.2.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in app-office/calligra-l10n: calligra-l10n-2.7.2.ebuild ChangeLog

[Johannes Huber (johu)]

johu        13/09/14 13:52:24

  Modified:             ChangeLog
  Added:                calligra-l10n-2.7.2.ebuild
  Log:
  Version bump wrt bug #479530.
  
  (Portage version: 2.2.4/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

Revision  Changes    Path
1.40                 app-office/calligra-l10n/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/calligra-l10n/ChangeLog?rev=1.40&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/calligra-l10n/ChangeLog?rev=1.40&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/calligra-l10n/ChangeLog?r1=1.39&r2=1.40

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/calligra-l10n/ChangeLog,v
retrieving revision 1.39
retrieving revision 1.40
diff -u -r1.39 -r1.40
--- ChangeLog	13 Jul 2013 16:27:12 -0000	1.39
+++ ChangeLog	14 Sep 2013 13:52:24 -0000	1.40
@@ -1,6 +1,11 @@
 # ChangeLog for app-office/calligra-l10n
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/calligra-l10n/ChangeLog,v 1.39 2013/07/13 16:27:12 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/calligra-l10n/ChangeLog,v 1.40 2013/09/14 13:52:24 johu Exp $
+
+*calligra-l10n-2.7.2 (14 Sep 2013)
+
+  14 Sep 2013; Johannes Huber <johu@gentoo.org> +calligra-l10n-2.7.2.ebuild:
+  Version bump wrt bug #479530.
 
   13 Jul 2013; Johannes Huber <johu@gentoo.org> -calligra-l10n-2.6.3.ebuild:
   Remove old.



1.1                  app-office/calligra-l10n/calligra-l10n-2.7.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/calligra-l10n/calligra-l10n-2.7.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/calligra-l10n/calligra-l10n-2.7.2.ebuild?rev=1.1&content-type=text/plain

Index: calligra-l10n-2.7.2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/calligra-l10n/calligra-l10n-2.7.2.ebuild,v 1.1 2013/09/14 13:52:24 johu Exp $

EAPI=5

inherit kde4-base

DESCRIPTION="Calligra localization package"
HOMEPAGE="http://www.kde.org/"
LICENSE="GPL-2"

DEPEND="sys-devel/gettext"
RDEPEND="!app-office/koffice-l10n"

KEYWORDS="~amd64 ~arm ~x86"
IUSE="doc"

MY_LANGS="bs ca cs da de el es et fi fr gl hu it kk nb nds nl pl pt pt_BR ru sk
sl sv tr uk zh_CN zh_TW"

case ${PV} in
	2.[456789].[789]?)
		# beta or rc releases
		URI_BASE="mirror://kde/unstable/${PN/-l10n/}-${PV}/${PN}/" ;;
	2.[456789].?)
		# stable releases
		URI_BASE="mirror://kde/stable/${PN/-l10n/}-${PV}/${PN}/" ;;
	*)
		SRC_URI="" ;;
esac

SRC_URI=""
SLOT="4"

for MY_LANG in ${MY_LANGS} ; do
	IUSE="${IUSE} linguas_${MY_LANG}"
	SRC_URI="${SRC_URI} linguas_${MY_LANG}? ( ${URI_BASE}/${PN}-${MY_LANG}-${PV}.tar.xz )"
done
unset MY_LANG

S="${WORKDIR}"

src_unpack() {
	local lng dir
	if [[ -z ${A} ]]; then
		elog
		elog "You either have the LINGUAS variable unset, or it only"
		elog "contains languages not supported by ${P}."
		elog "You won't have any additional language support."
		elog
		elog "${P} supports these language codes:"
		elog "${MY_LANGS}"
		elog
	fi

	[[ -n ${A} ]] && unpack ${A}
	cd "${S}"

	# add all linguas to cmake
	if [[ -n ${A} ]]; then
		for lng in ${MY_LANGS}; do
			dir="${PN}-${lng}-${PV}"
			if [[ -d "${dir}" ]] ; then
				echo "add_subdirectory( ${dir} )" >> "${S}"/CMakeLists.txt
			fi
		done
	fi
}

src_configure() {
	local mycmakeargs=(
		-DBUILD_MESSAGES=ON -DBUILD_DATA=ON
		$(cmake-utils_use_build doc)
	)
	[[ -e "${S}"/CMakeLists.txt ]] && kde4-base_src_configure
}

src_compile() {
	[[ -e "${S}"/CMakeLists.txt ]] && kde4-base_src_compile
}

src_test() {
	[[ -e "${S}"/CMakeLists.txt ]] && kde4-base_src_test
}

src_install() {
	[[ -e "${S}"/CMakeLists.txt ]] && kde4-base_src_install
}