[gentoo-commits] gentoo-x86 commit in sys-auth/nss-pam-ldapd: nss-pam-ldapd-0.9.1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in sys-auth/nss-pam-ldapd: nss-pam-ldapd-0.9.1.ebuild ChangeLog

[Matt Thode (prometheanfire)]

prometheanfire    13/09/11 03:19:01

  Modified:             ChangeLog
  Added:                nss-pam-ldapd-0.9.1.ebuild
  Log:
  just a bump of nslcd to 0.9.1
  
  (Portage version: 2.1.12.2/cvs/Linux x86_64, signed Manifest commit with key 0x2471eb3e40ac5ac3)

Revision  Changes    Path
1.11                 sys-auth/nss-pam-ldapd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/nss-pam-ldapd/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/nss-pam-ldapd/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/nss-pam-ldapd/ChangeLog?r1=1.10&r2=1.11

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-auth/nss-pam-ldapd/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog	6 May 2013 15:04:35 -0000	1.10
+++ ChangeLog	11 Sep 2013 03:19:01 -0000	1.11
@@ -1,6 +1,12 @@
 # ChangeLog for sys-auth/nss-pam-ldapd
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/nss-pam-ldapd/ChangeLog,v 1.10 2013/05/06 15:04:35 prometheanfire Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/nss-pam-ldapd/ChangeLog,v 1.11 2013/09/11 03:19:01 prometheanfire Exp $
+
+*nss-pam-ldapd-0.9.1 (11 Sep 2013)
+
+  11 Sep 2013; Matthew Thode <prometheanfire@gentoo.org>
+  +nss-pam-ldapd-0.9.1.ebuild:
+  just a bump of nslcd to 0.9.1
 
 *nss-pam-ldapd-0.8.13 (06 May 2013)
 



1.1                  sys-auth/nss-pam-ldapd/nss-pam-ldapd-0.9.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/nss-pam-ldapd/nss-pam-ldapd-0.9.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/nss-pam-ldapd/nss-pam-ldapd-0.9.1.ebuild?rev=1.1&content-type=text/plain

Index: nss-pam-ldapd-0.9.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-auth/nss-pam-ldapd/nss-pam-ldapd-0.9.1.ebuild,v 1.1 2013/09/11 03:19:01 prometheanfire Exp $

EAPI=4

inherit eutils multilib user

DESCRIPTION="NSS module for name lookups using LDAP"
HOMEPAGE="http://arthurdejong.org/nss-pam-ldapd/"
SRC_URI="http://arthurdejong.org/nss-pam-ldapd/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS=""
IUSE="debug kerberos sasl +pam"

DEPEND="net-nds/openldap
		sasl? ( dev-libs/cyrus-sasl )
		kerberos? ( virtual/krb5 )
		pam? ( virtual/pam )
		!sys-auth/nss_ldap
		!sys-auth/pam_ldap"
RDEPEND="${DEPEND}"

pkg_setup() {
	enewgroup nslcd
	enewuser nslcd -1 -1 -1 nslcd
}

src_prepare() {
	# support user patches
	epatch_user
}

src_configure() {
	# nss libraries always go in /lib on Gentoo
	myconf="--enable-warnings
	--with-ldap-lib=openldap
	--with-ldap-conf-file=/etc/nslcd.conf
	--with-nslcd-pidfile=/var/run/nslcd/nslcd.pid
	--with-nslcd-socket=/var/run/nslcd/socket
	--with-pam-seclib-dir=/$(get_libdir)/security
	--libdir=/$(get_libdir)
	$(use_enable debug)
	$(use_enable kerberos)
	$(use_enable pam)
	$(use_enable sasl)"

	if use x86-fbsd; then
		myconf+=" --with-nss-flavour=freebsd"
	else
		myconf+=" --with-nss-flavour=glibc"
	fi

	econf ${myconf}
}

src_install() {
	emake DESTDIR="${D}" install

	dodoc NEWS ChangeLog AUTHORS README

	# for socket and pid file (not needed bug 452992)
	#keepdir /var/run/nslcd

	# init script
	newinitd "${FILESDIR}"/nslcd-init nslcd

	# make an example copy
	insinto /usr/share/nss-pam-ldapd
	doins nslcd.conf

	fperms o-r /etc/nslcd.conf
}

pkg_postinst() {
	elog
	elog "For this to work you must configure /etc/nslcd.conf"
	elog "This configuration is similar to pam_ldap's /etc/ldap.conf"
	elog
	elog "In order to use nss-pam-ldapd, nslcd needs to be running. You can"
	elog "start it like this:"
	elog "  # /etc/init.d/nslcd start"
	elog
	elog "You can add it to the default runlevel like so:"
	elog " # rc-update add nslcd default"
	elog
	elog "If you are upgrading, keep in mind that /etc/nss-ldapd.conf"
	elog " is now named /etc/nslcd.conf"
	elog
}