[gentoo-commits] gentoo-x86 commit in mail-filter/postgrey: postgrey-1.34-r2.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in mail-filter/postgrey: postgrey-1.34-r2.ebuild ChangeLog

[Alexander Vershilov (qnikst)]

qnikst      13/09/09 14:25:57

  Modified:             ChangeLog
  Added:                postgrey-1.34-r2.ebuild
  Log:
  remove -T from postrey shebang (due to bug #479400)
  
  (Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key 0xEAD50D64D8D3571A!)

Revision  Changes    Path
1.82                 mail-filter/postgrey/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/postgrey/ChangeLog?rev=1.82&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/postgrey/ChangeLog?rev=1.82&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/postgrey/ChangeLog?r1=1.81&r2=1.82

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-filter/postgrey/ChangeLog,v
retrieving revision 1.81
retrieving revision 1.82
diff -u -r1.81 -r1.82
--- ChangeLog	17 Mar 2013 15:03:34 -0000	1.81
+++ ChangeLog	9 Sep 2013 14:25:57 -0000	1.82
@@ -1,6 +1,11 @@
 # ChangeLog for mail-filter/postgrey
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-filter/postgrey/ChangeLog,v 1.81 2013/03/17 15:03:34 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-filter/postgrey/ChangeLog,v 1.82 2013/09/09 14:25:57 qnikst Exp $
+
+*postgrey-1.34-r2 (09 Sep 2013)
+
+  09 Sep 2013; Alexander Vershilov <qnikst@gentoo.org> +postgrey-1.34-r2.ebuild:
+  remove -T from postrey shebang (due to bug #479400)
 
   17 Mar 2013; Markos Chandras <hwoarang@gentoo.org> metadata.xml:
   Add proxy-maintainers to metadata.xml



1.1                  mail-filter/postgrey/postgrey-1.34-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/postgrey/postgrey-1.34-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/postgrey/postgrey-1.34-r2.ebuild?rev=1.1&content-type=text/plain

Index: postgrey-1.34-r2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-filter/postgrey/postgrey-1.34-r2.ebuild,v 1.1 2013/09/09 14:25:57 qnikst Exp $

EAPI=4

inherit eutils user

DESCRIPTION="Postgrey is a Postfix policy server implementing greylisting"
HOMEPAGE="http://postgrey.schweikert.ch/"
SRC_URI="http://postgrey.schweikert.ch/pub/${P}.tar.gz
	http://postgrey.schweikert.ch/pub/old/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86"
IUSE="targrey"

DEPEND=""
RDEPEND=">=dev-lang/perl-5.6.0
	dev-perl/net-server
	dev-perl/IO-Multiplex
	dev-perl/BerkeleyDB
	dev-perl/Net-DNS
	dev-perl/Parse-Syslog
	dev-perl/Net-RBLClient
	>=sys-libs/db-4.1"

pkg_setup() {
	enewgroup ${PN}
	enewuser ${PN} -1 -1 /dev/null ${PN}
}

src_prepare() {
	if use targrey ; then
		epatch "${FILESDIR}"/targrey-0.31-postgrey-1.34.patch
	fi
	sed -i 's@#!/usr/bin/perl -T -w@#!/usr/bin/perl -w@' postgrey || die "sed failed"
}

src_install() {
	# postgrey data/DB in /var
	diropts -m0770 -o ${PN} -g ${PN}
	dodir /var/spool/postfix/${PN}
	keepdir /var/spool/postfix/${PN}
	fowners postgrey:postgrey /var/spool/postfix/${PN}
	fperms 0770 /var/spool/postfix/${PN}

	# postgrey binary
	dosbin ${PN}
	dosbin contrib/postgreyreport

	# policy-test script
	dosbin policy-test

	# postgrey data in /etc/postfix
	insinto /etc/postfix
	insopts -o root -g ${PN} -m 0640
	doins postgrey_whitelist_clients postgrey_whitelist_recipients

	# documentation
	dodoc Changes README

	# init.d + conf.d files
	insopts -o root -g root -m 755
	newinitd "${FILESDIR}"/${PN}.rc.new ${PN}
	insopts -o root -g root -m 640
	newconfd "${FILESDIR}"/${PN}.conf.new ${PN}
}