* [gentoo-commits] gentoo-x86 commit in x11-drivers/xf86-video-virtualbox: xf86-video-virtualbox-4.2.18.ebuild ChangeLog xf86-video-virtualbox-4.2.14.ebuild
@ 2013-09-08 12:38 Lars Wendler (polynomial-c)
0 siblings, 0 replies; only message in thread
From: Lars Wendler (polynomial-c) @ 2013-09-08 12:38 UTC (permalink / raw
To: gentoo-commits
polynomial-c 13/09/08 12:38:36
Modified: ChangeLog
Added: xf86-video-virtualbox-4.2.18.ebuild
Removed: xf86-video-virtualbox-4.2.14.ebuild
Log:
Version bump. Removed old
(Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)
Revision Changes Path
1.119 x11-drivers/xf86-video-virtualbox/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-drivers/xf86-video-virtualbox/ChangeLog?rev=1.119&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-drivers/xf86-video-virtualbox/ChangeLog?rev=1.119&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-drivers/xf86-video-virtualbox/ChangeLog?r1=1.118&r2=1.119
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-drivers/xf86-video-virtualbox/ChangeLog,v
retrieving revision 1.118
retrieving revision 1.119
diff -u -r1.118 -r1.119
--- ChangeLog 8 Jul 2013 14:51:45 -0000 1.118
+++ ChangeLog 8 Sep 2013 12:38:36 -0000 1.119
@@ -1,6 +1,12 @@
# ChangeLog for x11-drivers/xf86-video-virtualbox
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-drivers/xf86-video-virtualbox/ChangeLog,v 1.118 2013/07/08 14:51:45 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-drivers/xf86-video-virtualbox/ChangeLog,v 1.119 2013/09/08 12:38:36 polynomial-c Exp $
+
+*xf86-video-virtualbox-4.2.18 (08 Sep 2013)
+
+ 08 Sep 2013; Lars Wendler <polynomial-c@gentoo.org>
+ -xf86-video-virtualbox-4.2.14.ebuild, +xf86-video-virtualbox-4.2.18.ebuild:
+ Version bump. Removed old.
*xf86-video-virtualbox-4.2.16 (08 Jul 2013)
1.1 x11-drivers/xf86-video-virtualbox/xf86-video-virtualbox-4.2.18.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-drivers/xf86-video-virtualbox/xf86-video-virtualbox-4.2.18.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-drivers/xf86-video-virtualbox/xf86-video-virtualbox-4.2.18.ebuild?rev=1.1&content-type=text/plain
Index: xf86-video-virtualbox-4.2.18.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-drivers/xf86-video-virtualbox/xf86-video-virtualbox-4.2.18.ebuild,v 1.1 2013/09/08 12:38:36 polynomial-c Exp $
EAPI=5
PYTHON_COMPAT=( python2_7 )
inherit eutils linux-mod multilib python-single-r1 versionator toolchain-funcs
MY_PV="${PV/beta/BETA}"
MY_PV="${PV/rc/RC}"
MY_P=VirtualBox-${MY_PV}
DESCRIPTION="VirtualBox video driver"
HOMEPAGE="http://www.virtualbox.org/"
SRC_URI="http://download.virtualbox.org/virtualbox/${MY_PV}/${MY_P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="dri"
RDEPEND="<x11-base/xorg-server-1.14.99[-minimal]
x11-libs/libXcomposite"
DEPEND="${RDEPEND}
>=dev-util/kbuild-0.1.9998_pre20120806
${PYTHON_DEPS}
>=dev-lang/yasm-0.6.2
sys-power/iasl
x11-proto/fontsproto
x11-proto/randrproto
x11-proto/renderproto
x11-proto/xextproto
x11-proto/xineramaproto
x11-proto/xproto
x11-libs/libXdmcp
x11-libs/libXau
x11-libs/libX11
x11-libs/libXfixes
x11-libs/libXext
dri? ( x11-proto/xf86driproto
>=x11-libs/libdrm-2.4.5 )"
REQUIRED_USE=( "${PYTHON_REQUIRED_USE}" )
BUILD_TARGETS="all"
BUILD_TARGET_ARCH="${ARCH}"
MODULE_NAMES="vboxvideo(misc:${WORKDIR}/vboxvideo_drm:${WORKDIR}/vboxvideo_drm)"
S="${WORKDIR}/${MY_P}"
QA_TEXTRELS_x86="usr/lib/VBoxOGL.so"
pkg_setup() {
linux-mod_pkg_setup
BUILD_PARAMS="KERN_DIR=${KV_DIR} KERNOUT=${KV_OUT_DIR}"
python-single-r1_pkg_setup
}
src_prepare() {
# Prepare the vboxvideo_drm sources and Makefile in ${WORKDIR}
cp -a "${S}"/src/VBox/Additions/linux/drm "${WORKDIR}/vboxvideo_drm" \
|| die "cannot copy vboxvideo_drm directory"
cp "${FILESDIR}/${PN}-3-vboxvideo_drm.makefile" \
"${WORKDIR}/vboxvideo_drm/Makefile" \
|| die "cannot copy vboxvideo_drm Makefile"
# stupid new header references...
for vboxheader in {product,version}-generated.h ; do
ln -sf "${S}"/out/linux.${ARCH}/release/${vboxheader} \
"${WORKDIR}/vboxvideo_drm/${vboxheader}"
done
# Remove shipped binaries (kBuild,yasm), see bug #232775
rm -rf kBuild/bin tools
# Disable things unused or splitted into separate ebuilds
cp "${FILESDIR}/${PN}-3-localconfig" LocalConfig.kmk
# Ugly hack to build the opengl part of the video driver
epatch "${FILESDIR}/${PN}-2.2.0-enable-opengl.patch"
# unset useless/problematic checks in configure
epatch "${FILESDIR}/${PN}-3.2.8-mesa-check.patch" \
"${FILESDIR}/${PN}-4-makeself-check.patch" \
"${FILESDIR}/${PN}-4-mkisofs-check.patch"
# Patch to link with lazy on hardened #394757
if gcc-specs-now ; then
epatch "${FILESDIR}/${PN}-link-lazy.patch"
fi
}
src_configure() {
# build the user-space tools, warnings are harmless
./configure \
--nofatal \
--disable-xpcom \
--disable-sdl-ttf \
--disable-pulse \
--disable-alsa \
--build-headless || die "configure failed"
source ./env.sh
}
src_compile() {
for each in /src/VBox/{Runtime,Additions/common/VBoxGuestLib} \
/src/VBox/{GuestHost/OpenGL,Additions/x11/x11stubs,Additions/common/crOpenGL} \
/src/VBox/Additions/x11/vboxvideo ; do
cd "${S}"${each}
MAKE="kmk" emake TOOL_YASM_AS=yasm \
KBUILD_PATH="${S}/kBuild"
done
if use dri; then
# Now creating the kernel modules. We must do this _after_
# we compiled the user-space tools as we need two of the
# automatically generated header files. (>=3.2.0)
linux-mod_src_compile
fi
}
src_install() {
if use dri; then
linux-mod_src_install
fi
cd "${S}/out/linux.${ARCH}/release/bin/additions"
insinto /usr/$(get_libdir)/xorg/modules/drivers
# # xorg-server-1.14.x
if has_version ">=x11-base/xorg-server-1.13.99" ; then
newins vboxvideo_drv_114.so vboxvideo_drv.so
# xorg-server-1.13.x
elif has_version ">=x11-base/xorg-server-1.12.99" ; then
newins vboxvideo_drv_113.so vboxvideo_drv.so
# xorg-server-1.12.x
elif has_version ">=x11-base/xorg-server-1.12" ; then
newins vboxvideo_drv_112.so vboxvideo_drv.so
# xorg-server-1.11.x
elif has_version ">=x11-base/xorg-server-1.11" ; then
newins vboxvideo_drv_111.so vboxvideo_drv.so
# xorg-server-1.10.x
elif has_version ">=x11-base/xorg-server-1.10" ; then
newins vboxvideo_drv_110.so vboxvideo_drv.so
# xorg-server-1.9.x
else
newins vboxvideo_drv_19.so vboxvideo_drv.so
fi
# Guest OpenGL driver
insinto /usr/$(get_libdir)
doins -r VBoxOGL*
if use dri ; then
dosym /usr/$(get_libdir)/VBoxOGL.so /usr/$(get_libdir)/dri/vboxvideo_dri.so
fi
}
pkg_postinst() {
elog "You need to edit the file /etc/X11/xorg.conf and set:"
elog ""
elog " Driver \"vboxvideo\""
elog ""
elog "in the Graphics device section (Section \"Device\")"
elog ""
if use dri; then
elog "To use the kernel drm video driver, please add:"
elog "\"vboxvideo\" to:"
if has_version sys-apps/openrc ; then
elog "/etc/conf.d/modules"
else
elog "/etc/modules.autoload.d/kernel-${KV_MAJOR}.${KV_MINOR}"
fi
elog ""
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-09-08 12:38 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-09-08 12:38 [gentoo-commits] gentoo-x86 commit in x11-drivers/xf86-video-virtualbox: xf86-video-virtualbox-4.2.18.ebuild ChangeLog xf86-video-virtualbox-4.2.14.ebuild Lars Wendler (polynomial-c)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox