[gentoo-commits] gentoo-x86 commit in x11-wm/xpra: xpra-0.10.2.ebuild ChangeLog xpra-0.10.0.ebuild

[gentoo-commits] gentoo-x86 commit in x11-wm/xpra: xpra-0.10.2.ebuild ChangeLog xpra-0.10.0.ebuild

[Michael Weber (xmw)]

xmw         13/09/04 07:27:43

  Modified:             ChangeLog
  Added:                xpra-0.10.2.ebuild
  Removed:              xpra-0.10.0.ebuild
  Log:
  Version bump, drop old.
  
  (Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key 62EEF090)

Revision  Changes    Path
1.81                 x11-wm/xpra/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/xpra/ChangeLog?rev=1.81&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/xpra/ChangeLog?rev=1.81&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/xpra/ChangeLog?r1=1.80&r2=1.81

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/xpra/ChangeLog,v
retrieving revision 1.80
retrieving revision 1.81
diff -u -r1.80 -r1.81
--- ChangeLog	30 Aug 2013 08:36:50 -0000	1.80
+++ ChangeLog	4 Sep 2013 07:27:43 -0000	1.81
@@ -1,6 +1,12 @@
 # ChangeLog for x11-wm/xpra
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/xpra/ChangeLog,v 1.80 2013/08/30 08:36:50 heroxbd Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/xpra/ChangeLog,v 1.81 2013/09/04 07:27:43 xmw Exp $
+
+*xpra-0.10.2 (04 Sep 2013)
+
+  04 Sep 2013; Michael Weber <xmw@gentoo.org> +xpra-0.10.2.ebuild,
+  -xpra-0.10.0.ebuild:
+  Version bump, drop old.
 
   30 Aug 2013; Benda Xu <heroxbd@gentoo.org> +files/xpra-0.10.1-prefix.patch,
   xpra-0.10.1.ebuild:



1.1                  x11-wm/xpra/xpra-0.10.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/xpra/xpra-0.10.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/xpra/xpra-0.10.2.ebuild?rev=1.1&content-type=text/plain

Index: xpra-0.10.2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/xpra/xpra-0.10.2.ebuild,v 1.1 2013/09/04 07:27:43 xmw Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7} )
inherit distutils-r1 eutils

DESCRIPTION="X Persistent Remote Apps (xpra) and Partitioning WM (parti) based on wimpiggy"
HOMEPAGE="http://xpra.org/ http://xpra.org/src/"
SRC_URI="http://xpra.org/src/${P}.tar.bz2"

LICENSE="GPL-2 BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="+client +clipboard csc dec_av opengl pulseaudio +rencode server sound vpx webp x264"

REQUIRED_USE="${PYTHON_REQUIRED_USE}
	clipboard? ( || ( server client ) )
	opengl? ( client )
	|| ( client server )"

# x264/old-libav.path situation see bug 459218
COMMON_DEPEND=""${PYTHON_DEPS}"
	dev-python/pygobject:2[${PYTHON_USEDEP}]
	dev-python/pygtk:2[${PYTHON_USEDEP}]
	x11-libs/gtk+:2
	x11-libs/libX11
	x11-libs/libXcomposite
	x11-libs/libXdamage
	x11-libs/libXfixes
	x11-libs/libXrandr
	x11-libs/libXtst
	csc? ( || ( >=media-video/ffmpeg-1.2.2 media-video/libav ) )
	dec_av? ( || ( >=media-video/ffmpeg-1.2.2 media-video/libav ) )
	opengl? ( dev-python/pygtkglext )
	pulseaudio? ( media-sound/pulseaudio )
	sound? ( media-libs/gstreamer
		media-libs/gst-plugins-base
		dev-python/gst-python )
	vpx? ( media-libs/libvpx virtual/ffmpeg )
	webp? ( media-libs/libwebp )
	x264? ( media-libs/x264
		|| ( >=media-video/ffmpeg-1.0.4:0 media-video/libav ) )"

RDEPEND="${COMMON_DEPEND}
	dev-python/dbus-python[${PYTHON_USEDEP}]
	dev-python/ipython[${PYTHON_USEDEP}]
	dev-python/numpy[${PYTHON_USEDEP}]
	virtual/python-imaging[${PYTHON_USEDEP}]
	virtual/ssh
	x11-apps/setxkbmap
	x11-apps/xmodmap
	server? ( x11-base/xorg-server[-minimal,xvfb]
		x11-drivers/xf86-input-void
		x11-drivers/xf86-video-dummy
	)"
DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig
	>=dev-python/cython-0.16[${PYTHON_USEDEP}]"

python_prepare_all() {
	epatch \
		"${FILESDIR}"/${PN}-0.7.1-ignore-gentoo-no-compile.patch \
		"${FILESDIR}"/${PN}-0.10.1-prefix.patch

	#assuming ffmpeg and libav mutual exclusive installs
	if has_version "media-video/libav" ; then
		if ! has_version ">=media-video/libav-9" ; then
			epatch patches/old-libav.patch
		fi
	fi
}

python_configure_all() {
	mydistutilsargs=(
		$(use_with client)
		$(use_with clipboard)
		$(use_with csc csc_swscale)
		$(use_with dec_av dec_avcodec)
		$(use_with opengl)
		$(use_with rencode)
		$(use_with server cymaths)
		$(use_with server shadow)
		$(use_with server)
		$(use_with sound)
		$(use_with vpx)
		$(use_with webp)
		$(use_with x264 enc_x264)
		--with-Xdummy
		--with-argb
		--without-csc_nvcuda
		--with-cyxor
		--with-gtk2
		--without-gtk3
		--without-qt4
		--with-nvenc
		--with-strict
		--with-warn
		--with-x11
		--without-PIC
		--without-debug )
}