[gentoo-commits] gentoo-x86 commit in www-plugins/chrome-binary-plugins: chrome-binary-plugins-29.0.1547.65_p220622.ebuild ChangeLog chrome-binary-plugins-29.0.1547.62_p219432.ebuild

[gentoo-commits] gentoo-x86 commit in www-plugins/chrome-binary-plugins: chrome-binary-plugins-29.0.1547.65_p220622.ebuild ChangeLog chrome-binary-plugins-29.0.1547.62_p219432.ebuild

[Mike Gilbert (floppym)]

floppym     13/09/04 00:27:31

  Modified:             ChangeLog
  Added:                chrome-binary-plugins-29.0.1547.65_p220622.ebuild
  Removed:              chrome-binary-plugins-29.0.1547.62_p219432.ebuild
  Log:
  Automated update.
  
  (Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

Revision  Changes    Path
1.52                 www-plugins/chrome-binary-plugins/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/chrome-binary-plugins/ChangeLog?rev=1.52&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/chrome-binary-plugins/ChangeLog?rev=1.52&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/chrome-binary-plugins/ChangeLog?r1=1.51&r2=1.52

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-plugins/chrome-binary-plugins/ChangeLog,v
retrieving revision 1.51
retrieving revision 1.52
diff -u -r1.51 -r1.52
--- ChangeLog	28 Aug 2013 17:40:24 -0000	1.51
+++ ChangeLog	4 Sep 2013 00:27:31 -0000	1.52
@@ -1,6 +1,13 @@
 # ChangeLog for www-plugins/chrome-binary-plugins
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-plugins/chrome-binary-plugins/ChangeLog,v 1.51 2013/08/28 17:40:24 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-plugins/chrome-binary-plugins/ChangeLog,v 1.52 2013/09/04 00:27:31 floppym Exp $
+
+*chrome-binary-plugins-29.0.1547.65_p220622 (04 Sep 2013)
+
+  04 Sep 2013; Mike Gilbert <floppym@gentoo.org>
+  +chrome-binary-plugins-29.0.1547.65_p220622.ebuild,
+  -chrome-binary-plugins-29.0.1547.62_p219432.ebuild:
+  Automated update.
 
 *chrome-binary-plugins-29.0.1547.62_p219432 (28 Aug 2013)
 *chrome-binary-plugins-30.0.1599.22_beta1 (28 Aug 2013)



1.1                  www-plugins/chrome-binary-plugins/chrome-binary-plugins-29.0.1547.65_p220622.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/chrome-binary-plugins/chrome-binary-plugins-29.0.1547.65_p220622.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/chrome-binary-plugins/chrome-binary-plugins-29.0.1547.65_p220622.ebuild?rev=1.1&content-type=text/plain

Index: chrome-binary-plugins-29.0.1547.65_p220622.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-plugins/chrome-binary-plugins/chrome-binary-plugins-29.0.1547.65_p220622.ebuild,v 1.1 2013/09/04 00:27:31 floppym Exp $

EAPI=4

inherit multilib unpacker

DESCRIPTION="Binary plugins -- native API Flash and PDF -- from Google Chrome for use in Chromium."
HOMEPAGE="http://www.google.com/chrome"

case ${PV} in
	*_alpha*)
		SLOT="unstable"
		MY_PV=${PV/_alpha/-r}
		;;
	*_beta*)
		SLOT="beta"
		MY_PV=${PV/_beta/-r}
		;;
	*_p*)
		SLOT="stable"
		MY_PV=${PV/_p/-r}
		;;
	*)
		die "Invalid value for \${PV}: ${PV}"
		;;
esac

MY_PN="google-chrome-${SLOT}"
MY_P="${MY_PN}_${MY_PV}"

SRC_URI="
	amd64? (
		http://dl.google.com/linux/chrome/deb/pool/main/g/${MY_PN}/${MY_P}_amd64.deb
	)
	x86? (
		http://dl.google.com/linux/chrome/deb/pool/main/g/${MY_PN}/${MY_P}_i386.deb
	)
"

LICENSE="google-chrome"
KEYWORDS="~amd64 ~x86"
IUSE="+flash +pdf"
RESTRICT="bindist mirror strip"

RDEPEND="www-client/chromium"

for x in 0 beta stable unstable; do
	if [[ ${SLOT} != ${x} ]]; then
		RDEPEND+=" !${CATEGORY}/${PN}:${x}"
	fi
done

S="${WORKDIR}/opt/google/chrome"
QA_PREBUILT="*"

src_install() {
	local version flapper

	insinto /usr/$(get_libdir)/chromium-browser/

	use pdf && doins libpdf.so

	if use flash; then
		doins -r PepperFlash

		# Since this is a live ebuild, we're forced to, unfortuantely,
		# dynamically construct the command line args for Chromium.
		version=$(sed -n 's/.*"version": "\(.*\)",.*/\1/p' PepperFlash/manifest.json)
		flapper="${ROOT}usr/$(get_libdir)/chromium-browser/PepperFlash/libpepflashplayer.so"
		echo -n "CHROMIUM_FLAGS=\"\${CHROMIUM_FLAGS} " > pepper-flash
		echo -n "--ppapi-flash-path=$flapper " >> pepper-flash
		echo "--ppapi-flash-version=$version\"" >> pepper-flash

		insinto /etc/chromium/
		doins pepper-flash
	fi
}

pkg_postinst() {
	use flash || return

	einfo
	einfo "To enable Flash for Chromium, source	${ROOT}etc/chromium/pepper-flash"
	einfo "inside ${ROOT}etc/chromium/default. You may run this as root:"
	einfo
	einfo "  # echo . ${ROOT}etc/chromium/pepper-flash >> ${ROOT}etc/chromium/default"
	einfo
}