[gentoo-commits] gentoo-x86 commit in net-proxy/privoxy: privoxy-3.0.21-r1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-proxy/privoxy: privoxy-3.0.21-r1.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       13/09/03 20:17:02

  Modified:             ChangeLog
  Added:                privoxy-3.0.21-r1.ebuild
  Log:
  Add unit file (#483370 by Andrius Štikonas)
  
  (Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.84                 net-proxy/privoxy/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/privoxy/ChangeLog?rev=1.84&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/privoxy/ChangeLog?rev=1.84&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/privoxy/ChangeLog?r1=1.83&r2=1.84

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-proxy/privoxy/ChangeLog,v
retrieving revision 1.83
retrieving revision 1.84
diff -u -r1.83 -r1.84
--- ChangeLog	17 Mar 2013 19:22:02 -0000	1.83
+++ ChangeLog	3 Sep 2013 20:17:02 -0000	1.84
@@ -1,6 +1,12 @@
 # ChangeLog for net-proxy/privoxy
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/privoxy/ChangeLog,v 1.83 2013/03/17 19:22:02 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/privoxy/ChangeLog,v 1.84 2013/09/03 20:17:02 pacho Exp $
+
+*privoxy-3.0.21-r1 (03 Sep 2013)
+
+  03 Sep 2013; Pacho Ramos <pacho@gentoo.org> +files/privoxy.service,
+  +privoxy-3.0.21-r1.ebuild:
+  Add unit file (#483370 by Andrius Štikonas)
 
   17 Mar 2013; Agostino Sarubbo <ago@gentoo.org> -privoxy-3.0.12.ebuild,
   -privoxy-3.0.13_beta.ebuild, -privoxy-3.0.14_beta.ebuild,



1.1                  net-proxy/privoxy/privoxy-3.0.21-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/privoxy/privoxy-3.0.21-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/privoxy/privoxy-3.0.21-r1.ebuild?rev=1.1&content-type=text/plain

Index: privoxy-3.0.21-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-proxy/privoxy/privoxy-3.0.21-r1.ebuild,v 1.1 2013/09/03 20:17:02 pacho Exp $

EAPI="4"

inherit eutils toolchain-funcs autotools systemd user

[ "${PV##*_}" = "beta" ] &&
	PRIVOXY_STATUS="beta" ||
	PRIVOXY_STATUS="stable"

HOMEPAGE="http://www.privoxy.org http://sourceforge.net/projects/ijbswa/"
DESCRIPTION="A web proxy with advanced filtering capabilities for protecting privacy against Internet junk"
SRC_URI="mirror://sourceforge/ijbswa/${P%_*}-${PRIVOXY_STATUS}-src.tar.gz"

IUSE="selinux threads zlib"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
LICENSE="GPL-2"

DEPEND="dev-libs/libpcre
	zlib? ( sys-libs/zlib )"
RDEPEND="${DEPEND}
	selinux? ( sec-policy/selinux-privoxy )"

S="${WORKDIR}/${P%_*}-${PRIVOXY_STATUS}"

pkg_setup() {
	enewgroup privoxy
	enewuser privoxy -1 -1 /etc/privoxy privoxy
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-3.0.19-gentoo.patch
	# autoreconf needs to be called even if we don't modify any autotools source files
	# See main makefile
	eautoreconf
}

src_configure() {
	econf \
		$(use_enable zlib) \
		$(use_enable threads pthread) \
		--enable-dynamic-pcre \
		--with-user=privoxy \
		--with-group=privoxy \
		--sysconfdir=/etc/privoxy \
		--docdir=/usr/share/doc/${PF}
}

src_install () {
	default

	newinitd "${FILESDIR}/privoxy.initd" privoxy
	systemd_dounit "${FILESDIR}"/${PN}.service

	insinto /etc/logrotate.d
	newins "${FILESDIR}/privoxy.logrotate" privoxy

	diropts -m 0750 -g privoxy -o privoxy
	keepdir /var/log/privoxy
}