[gentoo-commits] gentoo-x86 commit in kde-base/systemsettings: systemsettings-4.11.1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in kde-base/systemsettings: systemsettings-4.11.1.ebuild ChangeLog

[Chris Reffett (creffett)]

creffett    13/09/03 19:04:52

  Modified:             ChangeLog
  Added:                systemsettings-4.11.1.ebuild
  Log:
  Bump KDE to 4.1.1
  
  (Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key 42618354)

Revision  Changes    Path
1.221                kde-base/systemsettings/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/systemsettings/ChangeLog?rev=1.221&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/systemsettings/ChangeLog?rev=1.221&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/systemsettings/ChangeLog?r1=1.220&r2=1.221

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/systemsettings/ChangeLog,v
retrieving revision 1.220
retrieving revision 1.221
diff -u -r1.220 -r1.221
--- ChangeLog	21 Aug 2013 19:04:02 -0000	1.220
+++ ChangeLog	3 Sep 2013 19:04:52 -0000	1.221
@@ -1,6 +1,13 @@
 # ChangeLog for kde-base/systemsettings
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/systemsettings/ChangeLog,v 1.220 2013/08/21 19:04:02 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/systemsettings/ChangeLog,v 1.221 2013/09/03 19:04:52 creffett Exp $
+
+*systemsettings-4.11.1 (03 Sep 2013)
+
+  03 Sep 2013; Chris Reffett <creffett@gentoo.org>
+  +files/systemsettings-4.11.1-deps.patch, +systemsettings-4.11.1.ebuild,
+  files/systemsettings-4.10.1-noplasmalock.patch:
+  Bump KDE to 4.1.1
 
   21 Aug 2013; Michael Palimaka <kensington@gentoo.org>
   systemsettings-4.10.5.ebuild, systemsettings-4.11.0.ebuild:



1.1                  kde-base/systemsettings/systemsettings-4.11.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/systemsettings/systemsettings-4.11.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/systemsettings/systemsettings-4.11.1.ebuild?rev=1.1&content-type=text/plain

Index: systemsettings-4.11.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/systemsettings/systemsettings-4.11.1.ebuild,v 1.1 2013/09/03 19:04:52 creffett Exp $

EAPI=5

KDE_HANDBOOK="optional"
KMNAME="kde-workspace"
OPENGL_REQUIRED="optional"
VIRTUALX_REQUIRED="test"
VIRTUALDBUS_TEST="true"
inherit kde4-meta

DESCRIPTION="System settings utility"
HOMEPAGE+=" http://userbase.kde.org/System_Settings"
IUSE="debug gtk +usb"
KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"

COMMONDEPEND="
	app-misc/strigi
	dev-libs/glib:2
	$(add_kdebase_dep kwin)
	$(add_kdebase_dep libkworkspace)
	media-libs/fontconfig
	>=media-libs/freetype-2
	>=x11-libs/libxklavier-3.2
	x11-libs/libX11
	x11-libs/libXcursor
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libXft
	x11-libs/libXi
	x11-libs/libxkbfile
	x11-libs/libXrandr
	x11-libs/libXtst
	opengl? ( virtual/opengl )
	usb? ( virtual/libusb:0 )
"
DEPEND="${COMMONDEPEND}
	x11-proto/kbproto
	x11-proto/xextproto
"
RDEPEND="${COMMONDEPEND}
	$(add_kdebase_dep nepomuk)
	sys-libs/timezone-data
	x11-apps/setxkbmap
	x11-misc/xkeyboard-config
	gtk? ( kde-misc/kde-gtk-config )
"

KMEXTRA="
	kcontrol/
"
KMEXTRACTONLY="
	krunner/dbus/org.kde.krunner.App.xml
	krunner/dbus/org.kde.screensaver.xml
	ksmserver/screenlocker/dbus/org.kde.screensaver.xml
	kwin/
	libs/
	plasma/
"

PATCHES=(
	"${FILESDIR}/${PN}-4.10.1-noplasmalock.patch"
	"${FILESDIR}/${P}-deps.patch"
)

src_unpack() {
	if use handbook; then
		KMEXTRA+="
			doc/kcontrol
			doc/kfontview
		"
	fi

	kde4-meta_src_unpack
}

src_prepare() {
	sed -i -e 's/systemsettingsrc DESTINATION ${SYSCONF_INSTALL_DIR}/systemsettingsrc DESTINATION ${CONFIG_INSTALL_DIR}/' \
		systemsettings/CMakeLists.txt \
		|| die "Failed to fix systemsettingsrc install location"

	kde4-meta_src_prepare
}

# FIXME: is have_openglxvisual found without screensaver
src_configure() {
	# Old keyboard-detection code is unmaintained,
	# so we force the new stuff, using libxklavier.
	mycmakeargs=(
		-DUSE_XKLAVIER=ON -DWITH_LibXKlavier=ON
		-DWITH_GLIB2=ON -DWITH_GObject=ON
		$(cmake-utils_use_with opengl OpenGL)
		$(cmake-utils_use_with usb)
	)

	kde4-meta_src_configure
}