[gentoo-commits] gentoo-x86 commit in sys-cluster/pacemaker: ChangeLog pacemaker-1.1.10.ebuild pacemaker-1.1.10_rc1.ebuild

[gentoo-commits] gentoo-x86 commit in sys-cluster/pacemaker: ChangeLog pacemaker-1.1.10.ebuild pacemaker-1.1.10_rc1.ebuild

[Alexys Jacob (ultrabug)]

ultrabug    13/08/29 10:32:25

  Modified:             ChangeLog
  Added:                pacemaker-1.1.10.ebuild
  Removed:              pacemaker-1.1.10_rc1.ebuild
  Log:
  version bump, drop old
  
  (Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key B658FA13)

Revision  Changes    Path
1.34                 sys-cluster/pacemaker/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/pacemaker/ChangeLog?rev=1.34&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/pacemaker/ChangeLog?rev=1.34&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/pacemaker/ChangeLog?r1=1.33&r2=1.34

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/pacemaker/ChangeLog,v
retrieving revision 1.33
retrieving revision 1.34
diff -u -r1.33 -r1.34
--- ChangeLog	23 Apr 2013 08:04:02 -0000	1.33
+++ ChangeLog	29 Aug 2013 10:32:25 -0000	1.34
@@ -1,6 +1,12 @@
 # ChangeLog for sys-cluster/pacemaker
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/pacemaker/ChangeLog,v 1.33 2013/04/23 08:04:02 ultrabug Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/pacemaker/ChangeLog,v 1.34 2013/08/29 10:32:25 ultrabug Exp $
+
+*pacemaker-1.1.10 (29 Aug 2013)
+
+  29 Aug 2013; Ultrabug <ultrabug@gentoo.org> -pacemaker-1.1.10_rc1.ebuild,
+  +pacemaker-1.1.10.ebuild:
+  version bump, drop old
 
 *pacemaker-1.1.8-r2 (23 Apr 2013)
 



1.1                  sys-cluster/pacemaker/pacemaker-1.1.10.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/pacemaker/pacemaker-1.1.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/pacemaker/pacemaker-1.1.10.ebuild?rev=1.1&content-type=text/plain

Index: pacemaker-1.1.10.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/pacemaker/pacemaker-1.1.10.ebuild,v 1.1 2013/08/29 10:32:25 ultrabug Exp $

EAPI="5"
PYTHON_DEPEND="2"
WANT_AUTOMAKE="1.12"

inherit autotools base python

MY_PN="Pacemaker"
MY_P=${MY_PN}-${PV/_/-}

DESCRIPTION="Pacemaker CRM"
HOMEPAGE="http://www.linux-ha.org/wiki/Pacemaker"
SRC_URI="https://github.com/ClusterLabs/${PN}/archive/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~x86"
REQUIRED_USE="cman? ( !heartbeat )"
IUSE="acl cman heartbeat smtp snmp static-libs"

DEPEND="
	app-text/docbook-xsl-stylesheets
	dev-libs/libxslt
	sys-cluster/cluster-glue
	>=sys-cluster/libqb-0.14.0
	sys-cluster/resource-agents
	cman? ( sys-cluster/cman )
	heartbeat? ( >=sys-cluster/heartbeat-3.0.0 )
	!heartbeat? ( sys-cluster/corosync )
	smtp? ( net-libs/libesmtp )
	snmp? ( net-analyzer/net-snmp )
"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${PN}-${MY_P}"

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	base_src_prepare
	sed -i -e "/ggdb3/d" configure.ac || die
	sed -i -e "s/ -ggdb//g" configure.ac || die
	sed -i -e "s/uid2username(uid)/uid2username(uid_client)/g" lib/common/ipc.c || die
	sed -i -e "s:<glib/ghash.h>:<glib.h>:" lib/ais/plugin.c || die
	eautoreconf
	python_convert_shebangs -r 2 .
}

src_configure() {
	local myopts=""
	if use heartbeat ; then
		myopts="--without-corosync"
	else
		myopts="--with-ais"
	fi
	# appends lib to localstatedir automatically
	econf \
		--libdir=/usr/$(get_libdir) \
		--localstatedir=/var \
		--disable-dependency-tracking \
		--disable-fatal-warnings \
		$(use_with acl) \
		$(use_with cman cs-quorum) \
		$(use_with cman cman) \
		$(use_with heartbeat) \
		$(use_with smtp esmtp) \
		$(use_with snmp) \
		$(use_enable static-libs static) \
		${myopts}
}

src_install() {
	base_src_install
	rm -rf "${D}"/var/run "${D}"/etc/init.d
	newinitd "${FILESDIR}/${PN}.initd" ${PN} || die
	if has_version "<sys-cluster/corosync-2.0"; then
		insinto /etc/corosync/service.d
		newins "${FILESDIR}/${PN}.service" ${PN} || die
	fi
}

pkg_postinst() {
	elog " "
	elog "Looking for the crm CLI ? emerge sys-cluster/crmsh !"
	elog " "
}