[gentoo-commits] gentoo-x86 commit in dev-db/pgpool2: pgpool2-3.2.5.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-db/pgpool2: pgpool2-3.2.5.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     13/08/26 05:28:36

  Modified:             ChangeLog
  Added:                pgpool2-3.2.5.ebuild
  Log:
  Bump
  
  (Portage version: 2.2.1/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.20                 dev-db/pgpool2/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/pgpool2/ChangeLog?rev=1.20&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/pgpool2/ChangeLog?rev=1.20&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/pgpool2/ChangeLog?r1=1.19&r2=1.20

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-db/pgpool2/ChangeLog,v
retrieving revision 1.19
retrieving revision 1.20
diff -u -r1.19 -r1.20
--- ChangeLog	10 May 2013 08:21:43 -0000	1.19
+++ ChangeLog	26 Aug 2013 05:28:36 -0000	1.20
@@ -1,6 +1,11 @@
 # ChangeLog for dev-db/pgpool2
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/pgpool2/ChangeLog,v 1.19 2013/05/10 08:21:43 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/pgpool2/ChangeLog,v 1.20 2013/08/26 05:28:36 patrick Exp $
+
+*pgpool2-3.2.5 (26 Aug 2013)
+
+  26 Aug 2013; Patrick Lauer <patrick@gentoo.org> +pgpool2-3.2.5.ebuild:
+  Bump
 
   10 May 2013; Patrick Lauer <patrick@gentoo.org> pgpool2-3.2.3.ebuild,
   pgpool2-3.2.4.ebuild, pgpool2-9999.ebuild:



1.1                  dev-db/pgpool2/pgpool2-3.2.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/pgpool2/pgpool2-3.2.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/pgpool2/pgpool2-3.2.5.ebuild?rev=1.1&content-type=text/plain

Index: pgpool2-3.2.5.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/pgpool2/pgpool2-3.2.5.ebuild,v 1.1 2013/08/26 05:28:36 patrick Exp $

EAPI=4

MY_P="${PN/2/-II}-${PV}"

inherit base user

DESCRIPTION="Connection pool server for PostgreSQL"
HOMEPAGE="http://www.pgpool.net/"
SRC_URI="http://www.pgpool.net/download.php?f=${MY_P}.tar.gz -> ${MY_P}.tar.gz"
LICENSE="BSD"
SLOT="0"

KEYWORDS="~amd64 ~x86"

IUSE="memcached pam ssl static-libs"

RDEPEND="
	dev-db/postgresql-base
	memcached? ( dev-libs/libmemcached )
	pam? ( sys-auth/pambase )
	ssl? ( dev-libs/openssl )
"
DEPEND="${RDEPEND}
	sys-devel/bison
	!!dev-db/pgpool
"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	enewgroup postgres 70
	enewuser pgpool -1 -1 -1 postgres

	# We need the postgres user as well so we can set the proper
	# permissions on the sockets without getting into fights with
	# PostgreSQL's initialization scripts.
	enewuser postgres 70 /bin/bash /var/lib/postgresql postgres
}

src_prepare() {
	epatch "${FILESDIR}/pgpool_run_paths.patch"

	local pg_config_manual="$(pg_config --includedir)/pg_config_manual.h"
	local pgsql_socket_dir=$(grep DEFAULT_PGSOCKET_DIR "${pg_config_manual}" | \
		sed 's|.*\"\(.*\)\"|\1|g')
	local pgpool_socket_dir="$(dirname $pgsql_socket_dir)/pgpool"

	sed "s|@PGSQL_SOCKETDIR@|${pgsql_socket_dir}|g" \
		-i *.conf.sample* pool.h || die

	sed "s|@PGPOOL_SOCKETDIR@|${pgpool_socket_dir}|g" \
		-i *.conf.sample* pool.h || die
}

src_configure() {
	local myconf
	use memcached && \
		myconf="--with-memcached=\"${EROOT%/}/usr/include/libmemcached\""
	use pam && myconf+=' --with-pam'

	econf \
		--disable-rpath \
		--sysconfdir="${EROOT%/}/etc/${PN}" \
		$(use_with ssl openssl) \
		$(use_enable static-libs static) \
		${myconf}
}

src_compile() {
	emake

	emake -C sql
}

src_install() {
	emake DESTDIR="${D}" install

	emake DESTDIR="${D}" -C sql install
	cd "${S}"

	# `contrib' moved to `extension' with PostgreSQL 9.1
	local pgslot=$(postgresql-config show)
	if [[ ${pgslot//.} > 90 ]] ; then
		cd "${ED%/}$(pg_config --sharedir)"
		mv contrib extension || die
		cd "${S}"
	fi

	newinitd "${FILESDIR}/${PN}.initd" ${PN}
	newconfd "${FILESDIR}/${PN}.confd" ${PN}

	# Documentation
	dodoc NEWS TODO doc/where_to_send_queries.{pdf,odg}
	dohtml -r doc

	# Examples and extras
	insinto "/usr/share/${PN}"
	doins doc/{pgpool_remote_start,basebackup.sh,recovery.conf.sample}
	mv "${ED%/}/usr/share/${PN/2/-II}" "${ED%/}/usr/share/${PN}" || die

	# One more thing: Evil la files!
	find "${ED}" -name '*.la' -exec rm -f {} +
}