[gentoo-commits] gentoo-x86 commit in dev-libs/elfutils: elfutils-0.156.ebuild ChangeLog

["Mike Frysinger (vapier)" <vapier@gentoo.org>]

vapier      13/08/25 22:48:11

  Modified:             ChangeLog
  Added:                elfutils-0.156.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)

Revision  Changes    Path
1.168                dev-libs/elfutils/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/elfutils/ChangeLog?rev=1.168&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/elfutils/ChangeLog?rev=1.168&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/elfutils/ChangeLog?r1=1.167&r2=1.168

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/elfutils/ChangeLog,v
retrieving revision 1.167
retrieving revision 1.168
diff -u -r1.167 -r1.168
--- ChangeLog	16 Aug 2013 12:36:03 -0000	1.167
+++ ChangeLog	25 Aug 2013 22:48:11 -0000	1.168
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/elfutils
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/elfutils/ChangeLog,v 1.167 2013/08/16 12:36:03 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/elfutils/ChangeLog,v 1.168 2013/08/25 22:48:11 vapier Exp $
+
+*elfutils-0.156 (25 Aug 2013)
+
+  25 Aug 2013; Mike Frysinger <vapier@gentoo.org> +elfutils-0.156.ebuild:
+  Version bump.
 
 *elfutils-0.155-r1 (16 Aug 2013)
 



1.1                  dev-libs/elfutils/elfutils-0.156.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/elfutils/elfutils-0.156.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/elfutils/elfutils-0.156.ebuild?rev=1.1&content-type=text/plain

Index: elfutils-0.156.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/elfutils/elfutils-0.156.ebuild,v 1.1 2013/08/25 22:48:11 vapier Exp $

EAPI="4"

inherit eutils flag-o-matic multilib-minimal

DESCRIPTION="Libraries/utilities to handle ELF objects (drop in replacement for libelf)"
HOMEPAGE="https://fedorahosted.org/elfutils/"
SRC_URI="https://fedorahosted.org/releases/e/l/${PN}/${PV}/${P}.tar.bz2
	https://fedorahosted.org/releases/e/l/${PN}/${PV}/${PN}-portability.patch -> ${P}-portability.patch
	https://fedorahosted.org/releases/e/l/${PN}/${PV}/${PN}-robustify.patch -> ${P}-robustify.patch"

LICENSE="GPL-2-with-exceptions"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~arm-linux ~x86-linux"
IUSE="bzip2 lzma nls static-libs test +threads +utils zlib"

# This pkg does not actually seem to compile currently in a uClibc
# environment (xrealloc errs), but we need to ensure that glibc never
# gets pulled in as a dep since this package does not respect virtual/libc
RDEPEND="zlib? ( >=sys-libs/zlib-1.2.2.3[${MULTILIB_USEDEP}] )
	bzip2? ( app-arch/bzip2[${MULTILIB_USEDEP}] )
	lzma? ( app-arch/xz-utils[${MULTILIB_USEDEP}] )
	!dev-libs/libelf
	abi_x86_32? (
		!<=app-emulation/emul-linux-x86-baselibs-20130224-r11
		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
	)"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	>=sys-devel/flex-2.5.4a
	sys-devel/m4"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-0.118-PaX-support.patch
	epatch "${DISTDIR}"/${P}-{portability,robustify}.patch
	sed -i -e 's:-Werror::g' $(find -name Makefile.in) || die
	use test || sed -i -e 's: tests::' Makefile.in #226349
	use static-libs || sed -i -e '/^lib_LIBRARIES/s:=.*:=:' -e '/^%.os/s:%.o$::' lib{asm,dw,elf}/Makefile.in
	# some patches touch both configure and configure.ac
	find -type f -exec touch -r configure {} +
}

src_configure() {
	use test && append-flags -g #407135
	multilib-minimal_src_configure
}

multilib_src_configure() {
	ECONF_SOURCE="${S}" econf \
		--disable-werror \
		$(use_enable nls) \
		$(use_enable threads thread-safety) \
		--program-prefix="eu-" \
		$(use_with zlib) \
		$(use_with bzip2 bzlib) \
		$(use_with lzma)
}

multilib_src_test() {
	env	LD_LIBRARY_PATH="${BUILD_DIR}/libelf:${BUILD_DIR}/libebl:${BUILD_DIR}/libdw:${BUILD_DIR}/libasm" \
		LC_ALL="C" \
		emake check || die
}

multilib_src_install_all() {
	dodoc NOTES
	# These build quick, and are needed for most tests, so don't
	# disable their building when the USE flag is disabled.
	use utils || rm -rf "${ED}"/usr/bin
}