[gentoo-commits] gentoo-x86 commit in net-libs/gupnp: ChangeLog gupnp-0.20.5.ebuild

[gentoo-commits] gentoo-x86 commit in net-libs/gupnp: ChangeLog gupnp-0.20.5.ebuild

[Gilles Dartiguelongue (eva)]

eva         13/08/25 21:53:31

  Modified:             ChangeLog
  Added:                gupnp-0.20.5.ebuild
  Log:
  Version bump. Add python-*-r1 support for gupnp-binding-tool.
  
  (Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key C6085806)

Revision  Changes    Path
1.68                 net-libs/gupnp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp/ChangeLog?rev=1.68&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp/ChangeLog?rev=1.68&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp/ChangeLog?r1=1.67&r2=1.68

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/gupnp/ChangeLog,v
retrieving revision 1.67
retrieving revision 1.68
diff -u -r1.67 -r1.68
--- ChangeLog	1 Aug 2013 18:49:36 -0000	1.67
+++ ChangeLog	25 Aug 2013 21:53:31 -0000	1.68
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/gupnp
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp/ChangeLog,v 1.67 2013/08/01 18:49:36 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp/ChangeLog,v 1.68 2013/08/25 21:53:31 eva Exp $
+
+*gupnp-0.20.5 (25 Aug 2013)
+
+  25 Aug 2013; Gilles Dartiguelongue <eva@gentoo.org> +gupnp-0.20.5.ebuild:
+  Version bump. Add python-*-r1 support for gupnp-binding-tool.
 
 *gupnp-0.20.4 (01 Aug 2013)
 



1.1                  net-libs/gupnp/gupnp-0.20.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp/gupnp-0.20.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp/gupnp-0.20.5.ebuild?rev=1.1&content-type=text/plain

Index: gupnp-0.20.5.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp/gupnp-0.20.5.ebuild,v 1.1 2013/08/25 21:53:31 eva Exp $

EAPI="5"
GCONF_DEBUG="no"
VALA_MIN_API_VERSION="0.14"
VALA_USE_DEPEND="vapigen"
# FIXME: Claims to works with python3 but appears to be wishful thinking
PYTHON_COMPAT=( python{2_6,2_7} )
PYTHON_REQ_USE="xml"

inherit gnome2 python-any-r1 vala

DESCRIPTION="An object-oriented framework for creating UPnP devs and control points"
HOMEPAGE="http://gupnp.org/"

LICENSE="LGPL-2"
SLOT="0/4"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="connman +introspection kernel_linux networkmanager"

RDEPEND="
	>=net-libs/gssdp-0.13.0:0=[introspection?]
	>=net-libs/libsoup-2.28.2:2.4[introspection?]
	>=dev-libs/glib-2.24:2
	dev-libs/libxml2
	|| (
		>=sys-apps/util-linux-2.16
		<sys-libs/e2fsprogs-libs-1.41.8 )
	introspection? (
			>=dev-libs/gobject-introspection-0.6.4
			$(vala_depend) )
	connman? (
		>=dev-libs/glib-2.28:2
		>=net-misc/connman-0.80 )
	networkmanager? ( >=dev-libs/glib-2.26:2 )
	!net-libs/gupnp-vala
"
DEPEND="${RDEPEND}
	${PYTHON_DEPS}
	>=dev-util/gtk-doc-am-1
	sys-devel/gettext
	virtual/pkgconfig
"

pkg_setup() {
	python-any-r1_pkg_setup
}

src_prepare() {
	use introspection && vala_src_prepare
	gnome2_src_prepare
}

src_configure() {
	local backend=unix
	use kernel_linux && backend=linux
	use connman && backend=connman
	use networkmanager && backend=network-manager

	gnome2_src_configure \
		$(use_enable introspection) \
		--disable-static \
		--with-context-manager=${backend}
}

src_install() {
	gnome2_src_install
	python_doscript tools/gupnp-binding-tool
}