[gentoo-commits] gentoo-x86 commit in sys-apps/openrc: openrc-0.12.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in sys-apps/openrc: openrc-0.12.ebuild ChangeLog

[William Hubbs (williamh)]

williamh    13/08/14 06:35:47

  Modified:             ChangeLog
  Added:                openrc-0.12.ebuild
  Log:
  OpenRC-0.12, bug #439098 tracks changes
  
  (Portage version: 2.2.0/cvs/Linux i686, signed Manifest commit with key 0x30C46538)

Revision  Changes    Path
1.273                sys-apps/openrc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/ChangeLog?rev=1.273&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/ChangeLog?rev=1.273&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/ChangeLog?r1=1.272&r2=1.273

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/openrc/ChangeLog,v
retrieving revision 1.272
retrieving revision 1.273
diff -u -r1.272 -r1.273
--- ChangeLog	14 Aug 2013 03:56:38 -0000	1.272
+++ ChangeLog	14 Aug 2013 06:35:47 -0000	1.273
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/openrc
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/openrc/ChangeLog,v 1.272 2013/08/14 03:56:38 williamh Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/openrc/ChangeLog,v 1.273 2013/08/14 06:35:47 williamh Exp $
+
+*openrc-0.12 (14 Aug 2013)
+
+  14 Aug 2013; William Hubbs <williamh@gentoo.org> +openrc-0.12.ebuild:
+  OpenRC-0.12, bug #439098 tracks changes
 
   14 Aug 2013; William Hubbs <williamh@gentoo.org> metadata.xml,
   openrc-9999.ebuild:



1.1                  sys-apps/openrc/openrc-0.12.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild?rev=1.1&content-type=text/plain

Index: openrc-0.12.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild,v 1.1 2013/08/14 06:35:47 williamh Exp $

EAPI=5

inherit eutils flag-o-matic multilib pam toolchain-funcs

DESCRIPTION="OpenRC manages the services, startup and shutdown of a host"
HOMEPAGE="http://www.gentoo.org/proj/en/base/openrc/"

if [[ ${PV} == "9999" ]]; then
	EGIT_REPO_URI="git://github.com/OpenRC/${PN}.git"
	inherit git-2
else
	SRC_URI="http://dev.gentoo.org/~williamh/dist/${P}.tar.bz2"
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
fi

LICENSE="BSD-2"
SLOT="0"
IUSE="debug elibc_glibc ncurses pam newnet prefix +netifrc selinux static-libs
	tools unicode kernel_linux kernel_FreeBSD"

COMMON_DEPEND=">=sys-apps/baselayout-2.1-r1
	kernel_FreeBSD? ( || ( >=sys-freebsd/freebsd-ubin-9.0_rc sys-process/fuser-bsd ) )
	elibc_glibc? ( >=sys-libs/glibc-2.5 )
	ncurses? ( sys-libs/ncurses )
	pam? ( sys-auth/pambase )
	tools? ( dev-lang/perl )
	kernel_linux? (
		sys-process/psmisc
	)
	selinux? ( sec-policy/selinux-openrc )
	!<sys-fs/udev-init-scripts-17
	!<sys-fs/udev-133"
DEPEND="${COMMON_DEPEND}
	virtual/os-headers
	ncurses? ( virtual/pkgconfig )"
RDEPEND="${COMMON_DEPEND}
	!prefix? (
		kernel_linux? ( || ( >=sys-apps/sysvinit-2.86-r6 sys-process/runit ) )
		kernel_FreeBSD? ( sys-freebsd/freebsd-sbin )
	)"

PDEPEND="netifrc? ( net-misc/netifrc )"

src_prepare() {
	sed -i 's:0444:0644:' mk/sys.mk || die

	if [[ ${PV} == "9999" ]] ; then
		local ver="git-${EGIT_VERSION:0:6}"
		sed -i "/^GITVER[[:space:]]*=/s:=.*:=${ver}:" mk/git.mk || die
	fi

	# Allow user patches to be applied without modifying the ebuild
	epatch_user
}

src_compile() {
	unset LIBDIR #266688

	MAKE_ARGS="${MAKE_ARGS}
		LIBNAME=$(get_libdir)
		LIBEXECDIR=${EPREFIX}/$(get_libdir)/rc
		MKSELINUX=$(usex selinux)
		MKSTATICLIBS=$(usex static-libs)
	MKTOOLS=$(usex tools)"

	local brand="Unknown"
	if use kernel_linux ; then
		MAKE_ARGS="${MAKE_ARGS} OS=Linux"
		brand="Linux"
	elif use kernel_FreeBSD ; then
		MAKE_ARGS="${MAKE_ARGS} OS=FreeBSD"
		brand="FreeBSD"
	fi
	export BRANDING="Gentoo ${brand}"
	use newnet || MAKE_ARGS="${MAKE_ARGS} MKNET=oldnet"
	use prefix && MAKE_ARGS="${MAKE_ARGS} MKPREFIX=yes PREFIX=${EPREFIX}"
	export DEBUG=$(usev debug)
	export MKPAM=$(usev pam)
	export MKTERMCAP=$(usev ncurses)

	tc-export CC AR RANLIB
	emake ${MAKE_ARGS}
}

# set_config <file> <option name> <yes value> <no value> test
# a value of "#" will just comment out the option
set_config() {
	local file="${ED}/$1" var=$2 val com
	eval "${@:5}" && val=$3 || val=$4
	[[ ${val} == "#" ]] && com="#" && val='\2'
	sed -i -r -e "/^#?${var}=/{s:=([\"'])?([^ ]*)\1?:=\1${val}\1:;s:^#?:${com}:}" "${file}"
}

set_config_yes_no() {
	set_config "$1" "$2" YES NO "${@:3}"
}

src_install() {
	emake ${MAKE_ARGS} DESTDIR="${D}" install

	# move the shared libs back to /usr so ldscript can install
	# more of a minimal set of files
	# disabled for now due to #270646
	#mv "${ED}"/$(get_libdir)/lib{einfo,rc}* "${ED}"/usr/$(get_libdir)/ || die
	#gen_usr_ldscript -a einfo rc
	gen_usr_ldscript libeinfo.so
	gen_usr_ldscript librc.so

	if ! use kernel_linux; then
		keepdir /$(get_libdir)/rc/init.d
	fi
	keepdir /$(get_libdir)/rc/tmp

	# Backup our default runlevels
	dodir /usr/share/"${PN}"
	cp -PR "${ED}"/etc/runlevels "${ED}"/usr/share/${PN} || die
	rm -rf "${ED}"/etc/runlevels

	# Setup unicode defaults for silly unicode users
	set_config_yes_no /etc/rc.conf unicode use unicode

	# Cater to the norm
	set_config_yes_no /etc/conf.d/keymaps windowkeys '(' use x86 '||' use amd64 ')'

	# On HPPA, do not run consolefont by default (bug #222889)
	if use hppa; then
		rm -f "${ED}"/usr/share/openrc/runlevels/boot/consolefont
	fi

	# Support for logfile rotation
	insinto /etc/logrotate.d
	newins "${FILESDIR}"/openrc.logrotate openrc

	# install the gentoo pam.d file
	newpamd "${FILESDIR}"/start-stop-daemon.pam start-stop-daemon

	# install documentation
dodoc README.busybox
	if use newnet; then
		dodoc README.net
	fi
}

add_boot_init() {
	local initd=$1
	local runlevel=${2:-boot}
	# if the initscript is not going to be installed and is not
	# currently installed, return
	[[ -e "${ED}"/etc/init.d/${initd} || -e "${EROOT}"etc/init.d/${initd} ]] \
		|| return
	[[ -e "${EROOT}"etc/runlevels/${runlevel}/${initd} ]] && return

	# if runlevels dont exist just yet, then create it but still flag
	# to pkg_postinst that it needs real setup #277323
	if [[ ! -d "${EROOT}"etc/runlevels/${runlevel} ]] ; then
		mkdir -p "${EROOT}"etc/runlevels/${runlevel}
		touch "${EROOT}"etc/runlevels/.add_boot_init.created
	fi

	elog "Auto-adding '${initd}' service to your ${runlevel} runlevel"
	ln -snf /etc/init.d/${initd} "${EROOT}"etc/runlevels/${runlevel}/${initd}
}
add_boot_init_mit_config() {
	local config=$1 initd=$2
	if [[ -e ${EROOT}${config} ]] ; then
		if [[ -n $(sed -e 's:#.*::' -e '/^[[:space:]]*$/d' "${EROOT}"${config}) ]] ; then
			add_boot_init ${initd}
		fi
	fi
}

pkg_preinst() {
	local f LIBDIR=$(get_libdir)

	# avoid default thrashing in conf.d files when possible #295406
	if [[ -e "${EROOT}"etc/conf.d/hostname ]] ; then
		(
		unset hostname HOSTNAME
		source "${EROOT}"etc/conf.d/hostname
		: ${hostname:=${HOSTNAME}}
		[[ -n ${hostname} ]] && set_config /etc/conf.d/hostname hostname "${hostname}"
		)
	fi

	# set default interactive shell to sulogin if it exists
	set_config /etc/rc.conf rc_shell /sbin/sulogin "#" test -e /sbin/sulogin

	# termencoding was added in 0.2.1 and needed in boot
	has_version ">=sys-apps/openrc-0.2.1" || add_boot_init termencoding

	# swapfiles was added in 0.9.9 and needed in boot (february 2012)
	has_version ">=sys-apps/openrc-0.9.9" || add_boot_init swapfiles

	if ! has_version ">=sys-apps/openrc-0.11"; then
		add_boot_init sysfs sysinit
	fi

	if ! has_version ">=sys-apps/openrc-0.11.3" ; then
		migrate_udev_mount_script
		add_boot_init tmpfiles.setup boot
	fi

	# these were added in 0.12.
	if ! has_version ">=sys-apps/openrc-0.12"; then
		add_boot_init loopback
		add_boot_init tmpfiles.dev sysinit
	fi
}

# >=OpenRC-0.11.3 requires udev-mount to be in the sysinit runlevel with udev.
migrate_udev_mount_script() {
	if [ -e "${EROOT}"etc/runlevels/sysinit/udev -a \
		! -e "${EROOT}"etc/runlevels/sysinit/udev-mount ]; then
		add_boot_init udev-mount sysinit
	fi
	return 0
}

pkg_postinst() {
	local LIBDIR=$(get_libdir)

	# Make our runlevels if they don't exist
	if [[ ! -e "${EROOT}"etc/runlevels ]] || [[ -e "${EROOT}"etc/runlevels/.add_boot_init.created ]] ; then
		einfo "Copying across default runlevels"
		cp -RPp "${EROOT}"usr/share/${PN}/runlevels "${EROOT}"etc
		rm -f "${EROOT}"etc/runlevels/.add_boot_init.created
	else
		if [[ ! -e "${EROOT}"etc/runlevels/sysinit/devfs ]] ; then
			mkdir -p "${EROOT}"etc/runlevels/sysinit
			cp -RPp "${EROOT}"usr/share/${PN}/runlevels/sysinit/* \
				"${EROOT}"etc/runlevels/sysinit
		fi
		if [[ ! -e "${EROOT}"etc/runlevels/shutdown/mount-ro ]] ; then
			mkdir -p "${EROOT}"etc/runlevels/shutdown
			cp -RPp "${EROOT}"usr/share/${PN}/runlevels/shutdown/* \
				"${EROOT}"etc/runlevels/shutdown
		fi
	fi

	if use hppa; then
		elog "Setting the console font does not work on all HPPA consoles."
		elog "You can still enable it by running:"
		elog "# rc-update add consolefont boot"
	fi

	# Handle the conf.d/local.{start,stop} -> local.d transition
	if path_exists -o "${EROOT}"etc/conf.d/local.{start,stop} ; then
		elog "Moving your ${EROOT}etc/conf.d/local.{start,stop}"
		elog "files to ${EROOT}etc/local.d"
		mv "${EROOT}"etc/conf.d/local.start "${EROOT}"etc/local.d/baselayout1.start
		mv "${EROOT}"etc/conf.d/local.stop "${EROOT}"etc/local.d/baselayout1.stop
		chmod +x "${EROOT}"etc/local.d/*{start,stop}
	fi

	if use kernel_linux && [[ "${EROOT}" = "/" ]]; then
		if ! /$(get_libdir)/rc/sh/migrate-to-run.sh; then
			ewarn "The dependency data could not be migrated to /run/openrc."
			ewarn "This means you need to reboot your system."
		fi
	fi

	# update the dependency tree after touching all files #224171
	[[ "${EROOT}" = "/" ]] && "${EROOT}/${LIBDIR}"/rc/bin/rc-depend -u

	if ! use newnet && ! use netifrc; then
		ewarn "You have emerged OpenRc without network support. This"
		ewarn "means you need to SET UP a network manager such as"
	ewarn "	net-misc/netifrc, net-misc/dhcpcd, net-misc/wicd,"
	ewarn "net-misc/NetworkManager, or net-misc/badvpn."
	ewarn "Or, you have the option of emerging openrc with the newnet"
	ewarn "use flag and configuring /etc/conf.d/network and"
	ewarn "/etc/conf.d/staticroute if you only use static interfaces."
	fi

	if use newnet && [ ! -e "${EROOT}"etc/runlevels/boot/network ]; then
		ewarn "Please add the network service to your boot runlevel"
		ewarn "as soon as possible. Not doing so could leave you with a system"
		ewarn "without networking."
	fi

	ewarn "In this version of OpenRC, the loopback interface no longer"
	ewarn "satisfies the net virtual."
	ewarn "If you have services now which do not start because of this,"
	ewarn "They can be fixed by adding rc_need=\"!net\""
	ewarn "to the ${EROOT}etc/conf.d/<servicename> file."
	ewarn "You should also file a bug against the service asking that"
	ewarn "need net be dropped from the dependencies."
	ewarn "The bug you file should block the following tracker:"
	ewarn "https://bugs.gentoo.org/show_bug.cgi?id=439092"

	ewarn "This version of OpenRC doesn't enable nfs mounts automatically any"
	ewarn "longer. In order to mount nfs file systems, you must use the"
	ewarn "nfsmount service from the nfs-utils package."
	ewarn "See bug https://bugs.gentoo.org/show_bug.cgi?id=427996 for"
	ewarn "more information on this."

	elog "You should now update all files in /etc, using etc-update"
	elog "or equivalent before restarting any services or this host."
}

[gentoo-commits] gentoo-x86 commit in sys-apps/openrc: openrc-0.12.ebuild ChangeLog

[Ian Stakenvicius (axs)]

axs         13/08/14 18:41:38

  Modified:             openrc-0.12.ebuild ChangeLog
  Log:
  fixed dodoc README.net to README.newnet to match distfile, bug 481078
  
  (Portage version: 2.1.12.2/cvs/Linux x86_64, signed Manifest commit with key 2B6559ED)

Revision  Changes    Path
1.2                  sys-apps/openrc/openrc-0.12.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild?r1=1.1&r2=1.2

Index: openrc-0.12.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- openrc-0.12.ebuild	14 Aug 2013 06:35:47 -0000	1.1
+++ openrc-0.12.ebuild	14 Aug 2013 18:41:38 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild,v 1.1 2013/08/14 06:35:47 williamh Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild,v 1.2 2013/08/14 18:41:38 axs Exp $
 
 EAPI=5
 
@@ -139,9 +139,9 @@
 	newpamd "${FILESDIR}"/start-stop-daemon.pam start-stop-daemon
 
 	# install documentation
-dodoc README.busybox
+	dodoc README.busybox
 	if use newnet; then
-		dodoc README.net
+		dodoc README.newnet
 	fi
 }
 



1.274                sys-apps/openrc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/ChangeLog?rev=1.274&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/ChangeLog?rev=1.274&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/ChangeLog?r1=1.273&r2=1.274

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/openrc/ChangeLog,v
retrieving revision 1.273
retrieving revision 1.274
diff -u -r1.273 -r1.274
--- ChangeLog	14 Aug 2013 06:35:47 -0000	1.273
+++ ChangeLog	14 Aug 2013 18:41:38 -0000	1.274
@@ -1,6 +1,9 @@
 # ChangeLog for sys-apps/openrc
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/openrc/ChangeLog,v 1.273 2013/08/14 06:35:47 williamh Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/openrc/ChangeLog,v 1.274 2013/08/14 18:41:38 axs Exp $
+
+  14 Aug 2013; Ian Stakenvicius <axs@gentoo.org> openrc-0.12.ebuild:
+  fixed dodoc README.net to README.newnet to match distfile, bug 481078
 
 *openrc-0.12 (14 Aug 2013)
 

[gentoo-commits] gentoo-x86 commit in sys-apps/openrc: openrc-0.12.ebuild ChangeLog

[Ian Stakenvicius (axs)]

axs         13/08/16 16:13:14

  Modified:             openrc-0.12.ebuild ChangeLog
  Log:
  stop the removal of /etc/conf.d/net when upgrading from 0.11.8 and previous, bug 481336
  
  (Portage version: 2.1.12.2/cvs/Linux x86_64, RepoMan options: --force, signed Manifest commit with key 2B6559ED)

Revision  Changes    Path
1.3                  sys-apps/openrc/openrc-0.12.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild?r1=1.2&r2=1.3

Index: openrc-0.12.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- openrc-0.12.ebuild	14 Aug 2013 18:41:38 -0000	1.2
+++ openrc-0.12.ebuild	16 Aug 2013 16:13:14 -0000	1.3
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild,v 1.2 2013/08/14 18:41:38 axs Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild,v 1.3 2013/08/16 16:13:14 axs Exp $
 
 EAPI=5
 
@@ -208,6 +208,14 @@
 	if ! has_version ">=sys-apps/openrc-0.12"; then
 		add_boot_init loopback
 		add_boot_init tmpfiles.dev sysinit
+
+		# ensure existing /etc/conf.d/net is not removed
+		# undoes the hack to get around CONFIG_PROTECT in openrc-0.11.8 and earlier
+		# this needs to stay in openrc ebuilds for a long time. :(
+		if [[ -f "${EROOT}"etc/conf.d/net ]]; then
+			einfo "Modifying conf.d/net to keep it from being removed"
+			cat "${FILESDIR}"/net.confd.comment >>"${EROOT}"etc/conf.d/net
+		fi
 	fi
 }
 
@@ -269,11 +277,11 @@
 	if ! use newnet && ! use netifrc; then
 		ewarn "You have emerged OpenRc without network support. This"
 		ewarn "means you need to SET UP a network manager such as"
-	ewarn "	net-misc/netifrc, net-misc/dhcpcd, net-misc/wicd,"
-	ewarn "net-misc/NetworkManager, or net-misc/badvpn."
-	ewarn "Or, you have the option of emerging openrc with the newnet"
-	ewarn "use flag and configuring /etc/conf.d/network and"
-	ewarn "/etc/conf.d/staticroute if you only use static interfaces."
+		ewarn "	net-misc/netifrc, net-misc/dhcpcd, net-misc/wicd,"
+		ewarn "net-misc/NetworkManager, or net-misc/badvpn."
+		ewarn "Or, you have the option of emerging openrc with the newnet"
+		ewarn "use flag and configuring /etc/conf.d/network and"
+		ewarn "/etc/conf.d/staticroute if you only use static interfaces."
 	fi
 
 	if use newnet && [ ! -e "${EROOT}"etc/runlevels/boot/network ]; then



1.275                sys-apps/openrc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/ChangeLog?rev=1.275&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/ChangeLog?rev=1.275&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/ChangeLog?r1=1.274&r2=1.275

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/openrc/ChangeLog,v
retrieving revision 1.274
retrieving revision 1.275
diff -u -r1.274 -r1.275
--- ChangeLog	14 Aug 2013 18:41:38 -0000	1.274
+++ ChangeLog	16 Aug 2013 16:13:14 -0000	1.275
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/openrc
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/openrc/ChangeLog,v 1.274 2013/08/14 18:41:38 axs Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/openrc/ChangeLog,v 1.275 2013/08/16 16:13:14 axs Exp $
+
+  16 Aug 2013; Ian Stakenvicius <axs@gentoo.org> +files/net.confd.comment,
+  openrc-0.12.ebuild:
+  stop the removal of /etc/conf.d/net when upgrading from 0.11.8 and previous,
+  bug 481336
 
   14 Aug 2013; Ian Stakenvicius <axs@gentoo.org> openrc-0.12.ebuild:
   fixed dodoc README.net to README.newnet to match distfile, bug 481078

[gentoo-commits] gentoo-x86 commit in sys-apps/openrc: openrc-0.12.ebuild ChangeLog

[William Hubbs (williamh)]

williamh    13/08/16 18:12:50

  Modified:             openrc-0.12.ebuild ChangeLog
  Log:
  move the net comment into a here document.
  
  (Portage version: 2.2.0/cvs/Linux i686, signed Manifest commit with key 0x30C46538)

Revision  Changes    Path
1.4                  sys-apps/openrc/openrc-0.12.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild?r1=1.3&r2=1.4

Index: openrc-0.12.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- openrc-0.12.ebuild	16 Aug 2013 16:13:14 -0000	1.3
+++ openrc-0.12.ebuild	16 Aug 2013 18:12:50 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild,v 1.3 2013/08/16 16:13:14 axs Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/openrc/openrc-0.12.ebuild,v 1.4 2013/08/16 18:12:50 williamh Exp $
 
 EAPI=5
 
@@ -212,9 +212,16 @@
 		# ensure existing /etc/conf.d/net is not removed
 		# undoes the hack to get around CONFIG_PROTECT in openrc-0.11.8 and earlier
 		# this needs to stay in openrc ebuilds for a long time. :(
+		# Added in 0.12.
 		if [[ -f "${EROOT}"etc/conf.d/net ]]; then
 			einfo "Modifying conf.d/net to keep it from being removed"
-			cat "${FILESDIR}"/net.confd.comment >>"${EROOT}"etc/conf.d/net
+			cat <<-EOF >>"${EROOT}"etc/conf.d/net
+
+# The network scripts are now part of net-misc/netifrc
+# In order to avoid sys-apps/${P} from removing this file, this comment was
+# added; you can safely remove this comment.  Please see
+# /usr/share/doc/netifrc*/README* for more information.
+EOF
 		fi
 	fi
 }



1.277                sys-apps/openrc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/ChangeLog?rev=1.277&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/ChangeLog?rev=1.277&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/openrc/ChangeLog?r1=1.276&r2=1.277

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/openrc/ChangeLog,v
retrieving revision 1.276
retrieving revision 1.277
diff -u -r1.276 -r1.277
--- ChangeLog	16 Aug 2013 17:39:21 -0000	1.276
+++ ChangeLog	16 Aug 2013 18:12:50 -0000	1.277
@@ -1,6 +1,10 @@
 # ChangeLog for sys-apps/openrc
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/openrc/ChangeLog,v 1.276 2013/08/16 17:39:21 williamh Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/openrc/ChangeLog,v 1.277 2013/08/16 18:12:50 williamh Exp $
+
+  16 Aug 2013; William Hubbs <williamh@gentoo.org> -files/net.confd.comment,
+  openrc-0.12.ebuild:
+  move the net comment into a here document.
 
   16 Aug 2013; William Hubbs <williamh@gentoo.org> openrc-9999.ebuild:
   partially sync live ebuild