[gentoo-commits] gentoo-x86 commit in dev-python/shiboken: shiboken-1.2.0.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-python/shiboken: shiboken-1.2.0.ebuild ChangeLog

[Davide Pesavento (pesa)]

pesa        13/08/15 09:45:01

  Modified:             ChangeLog
  Added:                shiboken-1.2.0.ebuild
  Log:
  Version bump (bug 477844).
  
  (Portage version: 2.2.0/cvs/Linux x86_64, signed Manifest commit with key 17A85C72)

Revision  Changes    Path
1.45                 dev-python/shiboken/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/shiboken/ChangeLog?rev=1.45&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/shiboken/ChangeLog?rev=1.45&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/shiboken/ChangeLog?r1=1.44&r2=1.45

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/shiboken/ChangeLog,v
retrieving revision 1.44
retrieving revision 1.45
diff -u -r1.44 -r1.45
--- ChangeLog	21 Mar 2013 10:48:36 -0000	1.44
+++ ChangeLog	15 Aug 2013 09:45:01 -0000	1.45
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/shiboken
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/shiboken/ChangeLog,v 1.44 2013/03/21 10:48:36 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/shiboken/ChangeLog,v 1.45 2013/08/15 09:45:01 pesa Exp $
+
+*shiboken-1.2.0 (15 Aug 2013)
+
+  15 Aug 2013; Davide Pesavento <pesa@gentoo.org> +shiboken-1.2.0.ebuild:
+  Version bump (bug 477844).
 
   21 Mar 2013; Justin Lecher <jlec@gentoo.org> shiboken-1.1.2-r1.ebuild,
   metadata.xml:



1.1                  dev-python/shiboken/shiboken-1.2.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/shiboken/shiboken-1.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/shiboken/shiboken-1.2.0.ebuild?rev=1.1&content-type=text/plain

Index: shiboken-1.2.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/shiboken/shiboken-1.2.0.ebuild,v 1.1 2013/08/15 09:45:01 pesa Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7,3_2} )

inherit multilib cmake-utils python-r1

DESCRIPTION="A tool for creating Python bindings for C++ libraries"
HOMEPAGE="http://qt-project.org/wiki/PySide"
SRC_URI="http://download.qt-project.org/official_releases/pyside/${P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
IUSE="test"

RDEPEND="
	>=dev-libs/libxml2-2.6.32
	>=dev-libs/libxslt-1.1.19
	>=dev-qt/qtcore-4.7.0:4
	>=dev-qt/qtxmlpatterns-4.7.0:4
	!dev-python/apiextractor
	!dev-python/generatorrunner
"
DEPEND="${RDEPEND}
	test? (
		dev-python/numpy[${PYTHON_USEDEP}]
		>=dev-qt/qtgui-4.7.0:4
		>=dev-qt/qttest-4.7.0:4
	)"

DOCS=( AUTHORS ChangeLog )

src_prepare() {
	# Fix inconsistent naming of libshiboken.so and ShibokenConfig.cmake,
	# caused by the usage of a different version suffix with python >= 3.2
	sed -i -e "/get_config_var('SOABI')/d" \
		cmake/Modules/FindPython3InterpWithDebug.cmake || die

	if use prefix; then
		cp "${FILESDIR}"/rpath.cmake .
		sed \
			-i '1iinclude(rpath.cmake)' \
			CMakeLists.txt || die
	fi
}

src_configure() {
	configuration() {
		local mycmakeargs=(
			-DPYTHON_EXECUTABLE="${PYTHON}"
			-DPYTHON_SITE_PACKAGES="$(python_get_sitedir)"
			-DPYTHON_SUFFIX="-${EPYTHON}"
			$(cmake-utils_use_build test TESTS)
		)

		if [[ ${EPYTHON} == python3* ]]; then
			mycmakeargs+=(
				-DUSE_PYTHON3=ON
				-DPYTHON3_INCLUDE_DIR="$(python_get_includedir)"
				-DPYTHON3_LIBRARY="$(python_get_library_path)"
			)
		fi

		cmake-utils_src_configure
	}
	python_foreach_impl configuration
}

src_compile() {
	python_foreach_impl cmake-utils_src_make
}

src_test() {
	python_foreach_impl cmake-utils_src_test
}

src_install() {
	installation() {
		cmake-utils_src_install
		mv "${ED}"usr/$(get_libdir)/pkgconfig/${PN}{,-${EPYTHON}}.pc || die
	}
	python_foreach_impl installation
}