[gentoo-commits] gentoo-x86 commit in media-video/vcdimager: vcdimager-0.7.24.ebuild ChangeLog

["Alexis Ballier (aballier)" <aballier@gentoo.org>]

aballier    13/08/14 19:48:27

  Modified:             ChangeLog
  Added:                vcdimager-0.7.24.ebuild
  Log:
  Version bump (released in 2011!), avoid building test programs in src_compile, bug #226249 and convert to multilib.
  
  (Portage version: 2.2.0/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

Revision  Changes    Path
1.69                 media-video/vcdimager/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/vcdimager/ChangeLog?rev=1.69&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/vcdimager/ChangeLog?rev=1.69&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/vcdimager/ChangeLog?r1=1.68&r2=1.69

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/vcdimager/ChangeLog,v
retrieving revision 1.68
retrieving revision 1.69
diff -u -r1.68 -r1.69
--- ChangeLog	1 Jan 2013 19:03:46 -0000	1.68
+++ ChangeLog	14 Aug 2013 19:48:27 -0000	1.69
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/vcdimager
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/vcdimager/ChangeLog,v 1.68 2013/01/01 19:03:46 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/vcdimager/ChangeLog,v 1.69 2013/08/14 19:48:27 aballier Exp $
+
+*vcdimager-0.7.24 (14 Aug 2013)
+
+  14 Aug 2013; Alexis Ballier <aballier@gentoo.org> +vcdimager-0.7.24.ebuild:
+  Version bump (released in 2011!), avoid building test programs in
+  src_compile, bug #226249 and convert to multilib.
 
   01 Jan 2013; Raúl Porcel <armin76@gentoo.org> vcdimager-0.7.23-r1.ebuild:
   sh stable wrt #443582



1.1                  media-video/vcdimager/vcdimager-0.7.24.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/vcdimager/vcdimager-0.7.24.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/vcdimager/vcdimager-0.7.24.ebuild?rev=1.1&content-type=text/plain

Index: vcdimager-0.7.24.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/vcdimager/vcdimager-0.7.24.ebuild,v 1.1 2013/08/14 19:48:27 aballier Exp $

EAPI=5
inherit eutils multilib-minimal

DESCRIPTION="GNU VCDimager"
HOMEPAGE="http://www.vcdimager.org/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
IUSE="+xml static-libs"

RDEPEND=">=dev-libs/libcdio-0.76[-minimal,${MULTILIB_USEDEP}]
	dev-libs/popt
	xml? ( dev-libs/libxml2 )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

DOCS="AUTHORS BUGS ChangeLog FAQ HACKING NEWS README THANKS TODO"

src_prepare() {
	# Avoid building useless programs. Bug #226249
	sed -i \
		-e 's/check_PROGRAMS =/check_PROGRAMS +=/' \
		-e 's/noinst_PROGRAMS =/check_PROGRAMS =/' \
		test/Makefile.in || die
	sed -i \
		-e 's/noinst_PROGRAMS =/check_PROGRAMS =/' \
		example/Makefile.in || die
}

multilib_src_configure() {
	# We disable the xmltest because the configure script includes differently
	# than the actual XML-frontend C files.
	local myconf
	if use xml && multilib_is_native_abi ; then
		myconf="--with-xml-prefix=${EPREFIX}/usr --disable-xmltest"
	else
		myconf="--without-xml-frontend"
	fi
	multilib_is_native_abi || myconf="${myconf} --without-cli-frontend"
	ECONF_SOURCE="${S}" \
		econf $(use_enable static-libs static) ${myconf}
}

multilib_src_install_all() {
	prune_libtool_files
}