[gentoo-commits] gentoo-x86 commit in x11-wm/openbox: openbox-9999.ebuild openbox-3.5.2.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in x11-wm/openbox: openbox-9999.ebuild openbox-3.5.2.ebuild ChangeLog

[Markos Chandras (hwoarang)]

hwoarang    13/08/14 18:05:31

  Modified:             openbox-9999.ebuild ChangeLog
  Added:                openbox-3.5.2.ebuild
  Log:
  Version bump. Bug #480818
  
  (Portage version: 2.1.13.7/cvs/Linux x86_64, signed Manifest commit with key C2BA7F3C!)

Revision  Changes    Path
1.23                 x11-wm/openbox/openbox-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/openbox/openbox-9999.ebuild?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/openbox/openbox-9999.ebuild?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/openbox/openbox-9999.ebuild?r1=1.22&r2=1.23

Index: openbox-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/openbox/openbox-9999.ebuild,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- openbox-9999.ebuild	2 Dec 2012 11:14:49 -0000	1.22
+++ openbox-9999.ebuild	14 Aug 2013 18:05:31 -0000	1.23
@@ -1,6 +1,6 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/openbox/openbox-9999.ebuild,v 1.22 2012/12/02 11:14:49 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/openbox/openbox-9999.ebuild,v 1.23 2013/08/14 18:05:31 hwoarang Exp $
 
 EAPI="2"
 inherit multilib autotools eutils python git-2
@@ -37,7 +37,7 @@
 
 src_prepare() {
 	use python && python_convert_shebangs -r 2 .
-	epatch "${FILESDIR}"/${PN}-gnome-session-3.4.9.patch
+	epatch "${FILESDIR}"/${P}-gnome-session.patch
 	# Lets try to replace docbook-to-man with docbook2man.pl since
 	# Gentoo does not provide (why?) a docbook-to-man package
 	sed -i -e "s:docbook-to-man:docbook2man.pl:" "${S}"/Makefile.am



1.276                x11-wm/openbox/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/openbox/ChangeLog?rev=1.276&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/openbox/ChangeLog?rev=1.276&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/openbox/ChangeLog?r1=1.275&r2=1.276

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/openbox/ChangeLog,v
retrieving revision 1.275
retrieving revision 1.276
diff -u -r1.275 -r1.276
--- ChangeLog	3 Aug 2013 06:53:43 -0000	1.275
+++ ChangeLog	14 Aug 2013 18:05:31 -0000	1.276
@@ -1,6 +1,13 @@
 # ChangeLog for x11-wm/openbox
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/openbox/ChangeLog,v 1.275 2013/08/03 06:53:43 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/openbox/ChangeLog,v 1.276 2013/08/14 18:05:31 hwoarang Exp $
+
+*openbox-3.5.2 (14 Aug 2013)
+
+  14 Aug 2013; Markos Chandras <hwoarang@gentoo.org>
+  +files/openbox-3.5.2-gnome-session.patch, +openbox-3.5.2.ebuild,
+  openbox-9999.ebuild:
+  Version bump. Bug #480818
 
   03 Aug 2013; Agostino Sarubbo <ago@gentoo.org> openbox-3.5.0_p20130215.ebuild:
   Stable for sparc, wrt bug #477744



1.1                  x11-wm/openbox/openbox-3.5.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/openbox/openbox-3.5.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/openbox/openbox-3.5.2.ebuild?rev=1.1&content-type=text/plain

Index: openbox-3.5.2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/openbox/openbox-3.5.2.ebuild,v 1.1 2013/08/14 18:05:31 hwoarang Exp $

EAPI="5"
inherit multilib autotools python eutils

DESCRIPTION="A standards compliant, fast, light-weight, extensible window manager"
HOMEPAGE="http://openbox.org/"
SRC_URI="http://openbox.org/dist/openbox/${P}.tar.gz
branding? ( http://dev.gentoo.org/~hwoarang/distfiles/surreal-gentoo.tar.gz )"

LICENSE="GPL-2"
SLOT="3"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~arm-linux ~x86-linux"
IUSE="branding debug imlib nls python session startup-notification static-libs"

RDEPEND="dev-libs/glib:2
	>=dev-libs/libxml2-2.0
	python? ( dev-python/pyxdg )
	>=media-libs/fontconfig-2
	x11-libs/libXft
	x11-libs/libXrandr
	x11-libs/libXt
	>=x11-libs/pango-1.8[X]
	imlib? ( media-libs/imlib2 )
	startup-notification? ( >=x11-libs/startup-notification-0.8 )
	x11-libs/libXinerama"
DEPEND="${RDEPEND}
	sys-devel/gettext
	virtual/pkgconfig
	x11-proto/xextproto
	x11-proto/xf86vidmodeproto
	x11-proto/xineramaproto"

src_prepare() {
	use python && python_convert_shebangs -r 2 .
	epatch "${FILESDIR}"/${P}-gnome-session.patch
	sed -i \
		-e "s:-O0 -ggdb ::" \
		-e 's/-fno-strict-aliasing//' \
		"${S}"/m4/openbox.m4 || die
	epatch_user
	eautoreconf
}

src_configure() {
	econf \
		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
		--disable-silent-rules \
		$(use_enable debug) \
		$(use_enable imlib imlib2) \
		$(use_enable nls) \
		$(use_enable startup-notification) \
		$(use_enable session session-management) \
		$(use_enable static-libs static) \
		--with-x
}

src_install() {
	dodir /etc/X11/Sessions
	echo "/usr/bin/openbox-session" > "${ED}/etc/X11/Sessions/${PN}"
	fperms a+x /etc/X11/Sessions/${PN}
	emake DESTDIR="${D}" install
	if use branding; then
		insinto /usr/share/themes
		doins -r "${WORKDIR}"/Surreal_Gentoo
		# make it the default theme
		sed -i \
			"/<theme>/{n; s@<name>.*</name>@<name>Surreal_Gentoo</name>@}" \
			"${D}"/etc/xdg/openbox/rc.xml \
			|| die "failed to set Surreal Gentoo as the default theme"
	fi
	! use static-libs && rm "${ED}"/usr/$(get_libdir)/lib{obt,obrender}.la
	! use python && rm "${ED}"/usr/libexec/openbox-xdg-autostart
}