[gentoo-commits] gentoo-x86 commit in net-im/mu-conference: mu-conference-0.8-r1.ebuild ChangeLog mu-conference-0.8.ebuild

[gentoo-commits] gentoo-x86 commit in net-im/mu-conference: mu-conference-0.8-r1.ebuild ChangeLog mu-conference-0.8.ebuild

[Manuel Rueger (mrueg)]

mrueg       13/08/13 08:01:33

  Modified:             ChangeLog
  Added:                mu-conference-0.8-r1.ebuild
  Removed:              mu-conference-0.8.ebuild
  Log:
  Style fixes, thanks to Julian Ospald
  
  (Portage version: 2.2.0/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.29                 net-im/mu-conference/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/mu-conference/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/mu-conference/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/mu-conference/ChangeLog?r1=1.28&r2=1.29

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/mu-conference/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog	12 Aug 2013 23:27:45 -0000	1.28
+++ ChangeLog	13 Aug 2013 08:01:33 -0000	1.29
@@ -1,6 +1,12 @@
 # ChangeLog for net-im/mu-conference
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/mu-conference/ChangeLog,v 1.28 2013/08/12 23:27:45 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/mu-conference/ChangeLog,v 1.29 2013/08/13 08:01:33 mrueg Exp $
+
+*mu-conference-0.8-r1 (13 Aug 2013)
+
+  13 Aug 2013; Manuel Rüger <mrueg@gentoo.org> +mu-conference-0.8-r1.ebuild,
+  -mu-conference-0.8.ebuild:
+  Style fixes, thanks to Julian Ospald
 
 *mu-conference-0.8 (12 Aug 2013)
 



1.1                  net-im/mu-conference/mu-conference-0.8-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/mu-conference/mu-conference-0.8-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/mu-conference/mu-conference-0.8-r1.ebuild?rev=1.1&content-type=text/plain

Index: mu-conference-0.8-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/mu-conference/mu-conference-0.8-r1.ebuild,v 1.1 2013/08/13 08:01:33 mrueg Exp $

EAPI=5

inherit toolchain-funcs

DESCRIPTION="Multi-User Chat for jabberd"
HOMEPAGE="https://gna.org/projects/mu-conference/"
SRC_URI="http://download.gna.org/mu-conference/${PN}_${PV}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
SLOT="0"
IUSE="mysql"

RDEPEND="dev-libs/expat
	>=dev-libs/glib-2
	net-dns/libidn
	net-im/jabberd2
	mysql? ( virtual/mysql )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

S=${WORKDIR}/${PN}_${PV}

src_prepare() {
	# Fix missing header in src/conference_user.c in order to
	# make emerge happy and avoid QA notice.
	sed -i -e "/conference.h/ i #define _XOPEN_SOURCE" src/conference_user.c || die

	if use mysql; then
		sed -i -e '/^CFLAGS/ a CFLAGS:=$(CFLAGS) -DHAVE_MYSQL' \
			-e '/^LIBS/ a LIBS:=$(LIBS) `mysql_config --libs`' src/Makefile || die
	fi
		sed -i -e 's/^CC:=/CC?=/' -e 's/$(MCFLAGS)/$(MCFLAGS) $(LDFLAGS)/'\
			-e 's/LDFLAGS:=-L./LDFLAGS:=$(LDFLAGS) -L./'\
			-e 's/$(LDFLAGS) $(LIBS)/$(LIBS)/' src/Makefile || die
		sed -i -e 's/-O2//' src/{,jabberd,jcomp}/Makefile || die
		sed -i -e 's/CC=/CC?=/' src/{jabberd,jcomp}/Makefile || die
		sed -i -e 's/ar/$(AR)/' -e 's/ranlib/$(RANLIB)/' src/jabberd/Makefile || die
		sed -i -e 's/gcc -g/$(CC) -g/' src/jcomp/Makefile || die
	tc-export CC AR RANLIB
}

src_install() {
	exeinto /usr/bin
	doexe src/mu-conference
	fowners jabber:jabber /usr/bin/mu-conference
	fperms 750 /usr/bin/mu-conference

	newinitd "${FILESDIR}/${P}".init mu-conference

	dodoc ChangeLog FAQ mu-conference.sql README README.sql
	docinto scripts
	dodoc scripts/*

	local i
	for i in log spool; do
		dodir /var/${i}/jabber/mu-conference
		keepdir /var/${i}/jabber/mu-conference
		fowners jabber:jabber /var/${i}/jabber/mu-conference
		fperms 770 /var/${i}/jabber/mu-conference
	done

	insinto /etc/jabber
	newins muc-default.xml mu-conference.xml
	doins style.css

	sed -i \
		-e 's,./spool/chat.localhost,/var/spool/jabber/mu-conference,g' \
		-e 's,./syslogs,/var/log/jabber,g' \
		-e 's,./logs,/var/log/jabber/mu-conference,g' \
		-e 's,./mu-conference.pid,/var/run/jabber/mu-conference.pid,g' \
		-e "s,../style.css,/etc/jabber/style.css,g" \
		-e "s,7009,5347,g" \
		"${D}"/etc/jabber/mu-conference.xml || die "sed failed"
}

pkg_postinst() {
	elog
	elog "For jabberd-2 connection:"
	elog "1. Make sure that the ip and port in /etc/jabber/mu-conference.xml"
	elog "   match the address of your jabberd router."
	elog "2. Set a common secret in mu-conference.xml and router.xml"
	elog
}