[gentoo-commits] gentoo-x86 commit in media-gfx/argyllcms: argyllcms-1.5.1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in media-gfx/argyllcms: argyllcms-1.5.1.ebuild ChangeLog

[Manuel Rueger (mrueg)]

mrueg       13/08/13 02:18:33

  Modified:             ChangeLog
  Added:                argyllcms-1.5.1.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.0/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.34                 media-gfx/argyllcms/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/argyllcms/ChangeLog?rev=1.34&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/argyllcms/ChangeLog?rev=1.34&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/argyllcms/ChangeLog?r1=1.33&r2=1.34

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/argyllcms/ChangeLog,v
retrieving revision 1.33
retrieving revision 1.34
diff -u -r1.33 -r1.34
--- ChangeLog	29 Dec 2012 16:15:03 -0000	1.33
+++ ChangeLog	13 Aug 2013 02:18:32 -0000	1.34
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/argyllcms
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/argyllcms/ChangeLog,v 1.33 2012/12/29 16:15:03 floppym Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/argyllcms/ChangeLog,v 1.34 2013/08/13 02:18:32 mrueg Exp $
+
+*argyllcms-1.5.1 (13 Aug 2013)
+
+  13 Aug 2013; Manuel Rüger <mrueg@gentoo.org> +argyllcms-1.5.1.ebuild:
+  Version bump
 
   29 Dec 2012; Mike Gilbert <floppym@gentoo.org> argyllcms-1.4.0-r2.ebuild:
   Use makeopts_jobs for more robust MAKEOPTS parsing. Bug 449106 by jannis.



1.1                  media-gfx/argyllcms/argyllcms-1.5.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/argyllcms/argyllcms-1.5.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/argyllcms/argyllcms-1.5.1.ebuild?rev=1.1&content-type=text/plain

Index: argyllcms-1.5.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/argyllcms/argyllcms-1.5.1.ebuild,v 1.1 2013/08/13 02:18:32 mrueg Exp $

EAPI=5

inherit base flag-o-matic multiprocessing toolchain-funcs udev

MY_P="Argyll_V${PV}"

DESCRIPTION="Open source, ICC compatible color management system"
HOMEPAGE="http://www.argyllcms.com/"
SRC_URI="http://www.argyllcms.com/${MY_P}_src.zip"

LICENSE="AGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc"

RDEPEND="
	media-libs/tiff
	sys-libs/zlib
	virtual/jpeg
	x11-libs/libX11
	x11-libs/libXau
	x11-libs/libXdmcp
	x11-libs/libXext
	x11-libs/libXinerama
	x11-libs/libXrandr
	x11-libs/libXxf86vm
	x11-libs/libXScrnSaver"
DEPEND="${RDEPEND}
	app-arch/unzip
	dev-util/ftjam
	virtual/pkgconfig"

S="${WORKDIR}/${MY_P}"

PATCHES=(
	"${FILESDIR}/${PN}-1.4.0-CVE-2012-4405.patch"
	)

src_compile() {
	# Make it respect LDFLAGS
	echo "LINKFLAGS += ${LDFLAGS} ;" >> Jamtop

	# Evil hack to get --as-needed working. The build system unfortunately lists all
	# the shared libraries by default on the command line _before_ the object to be built...
	echo "STDLIBS += -ldl -lrt -lX11 -lXext -lXxf86vm -lXinerama -lXrandr -lXau -lXdmcp -lXss -ltiff -ljpeg ;" >> Jamtop

	append-cflags -DUNIX -D_THREAD_SAFE

	sed \
		-e 's:CCFLAGS:CFLAGS:g' \
		-e "s:ar rusc:$(tc-getAR) rusc:g" \
		-i Jambase || die

	tc-export CC RANLIB

	jam -dx -fJambase "-j$(makeopts_jobs)" || die
}

src_install() {
	jam -dx -fJambase install || die

	rm bin/License.txt || die

	pushd bin > /dev/null
	local binname
	for binname in * ; do
		newbin ${binname} argyll-${binname}
	done
	popd > /dev/null

	use doc && dohtml -r doc/*

	dodoc log.txt Readme.txt ttbd.txt notes.txt

	insinto /usr/share/${PN}
	doins -r ref

	udev_dorules usb/55-Argyll.rules
}

pkg_postinst() {
	elog "If you have a Spyder2 you need to extract the firmware"
	elog "from the CVSpyder.dll of the windows driver package"
	elog "and store it as /usr/share/color/spyd2PLD.bin"
	echo
	elog "For further info on setting up instrument access read"
	elog "http://www.argyllcms.com/doc/Installing_Linux.html"
	echo
}