[gentoo-commits] gentoo-x86 commit in dev-vcs/tortoisehg: tortoisehg-2.9.ebuild ChangeLog tortoisehg-2.8.1.ebuild

[gentoo-commits] gentoo-x86 commit in dev-vcs/tortoisehg: tortoisehg-2.9.ebuild ChangeLog tortoisehg-2.8.1.ebuild

[Lars Wendler (polynomial-c)]

polynomial-c    13/08/11 21:35:32

  Modified:             ChangeLog
  Added:                tortoisehg-2.9.ebuild
  Removed:              tortoisehg-2.8.1.ebuild
  Log:
  Version bump. Removed old
  
  (Portage version: 2.2.0_alpha196/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

Revision  Changes    Path
1.43                 dev-vcs/tortoisehg/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/tortoisehg/ChangeLog?rev=1.43&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/tortoisehg/ChangeLog?rev=1.43&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/tortoisehg/ChangeLog?r1=1.42&r2=1.43

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-vcs/tortoisehg/ChangeLog,v
retrieving revision 1.42
retrieving revision 1.43
diff -u -r1.42 -r1.43
--- ChangeLog	15 Jul 2013 06:54:09 -0000	1.42
+++ ChangeLog	11 Aug 2013 21:35:32 -0000	1.43
@@ -1,6 +1,12 @@
 # ChangeLog for dev-vcs/tortoisehg
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/tortoisehg/ChangeLog,v 1.42 2013/07/15 06:54:09 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/tortoisehg/ChangeLog,v 1.43 2013/08/11 21:35:32 polynomial-c Exp $
+
+*tortoisehg-2.9 (11 Aug 2013)
+
+  11 Aug 2013; Lars Wendler <polynomial-c@gentoo.org> -tortoisehg-2.8.1.ebuild,
+  +tortoisehg-2.9.ebuild:
+  Version bump. Removed old.
 
 *tortoisehg-2.8.2 (15 Jul 2013)
 



1.1                  dev-vcs/tortoisehg/tortoisehg-2.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/tortoisehg/tortoisehg-2.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/tortoisehg/tortoisehg-2.9.ebuild?rev=1.1&content-type=text/plain

Index: tortoisehg-2.9.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/tortoisehg/tortoisehg-2.9.ebuild,v 1.1 2013/08/11 21:35:32 polynomial-c Exp $

EAPI=5
PYTHON_COMPAT=( python{2_5,2_6,2_7} )

inherit distutils-r1 eutils

if [[ ${PV} != *9999* ]]; then
	KEYWORDS="~amd64 ~x86"
	SRC_URI="mirror://bitbucket/${PN}/targz/downloads/${P}.tar.gz"
	HG_DEPEND=">=dev-vcs/mercurial-2.5 <dev-vcs/mercurial-2.8"
else
	inherit mercurial
	EHG_REPO_URI="https://bitbucket.org/tortoisehg/thg"
	EHG_REVISION="stable"
	KEYWORDS=""
	SRC_URI=""
	HG_DEPEND="dev-vcs/mercurial"
fi

DESCRIPTION="Set of graphical tools for Mercurial"
HOMEPAGE="http://tortoisehg.bitbucket.org"

LICENSE="GPL-2"
SLOT="0"
IUSE="doc"

RDEPEND="${HG_DEPEND}
	dev-python/iniparse[${PYTHON_USEDEP}]
	dev-python/pygments[${PYTHON_USEDEP}]
	dev-python/PyQt4[svg,${PYTHON_USEDEP}]
	dev-python/qscintilla-python[${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}
	doc? ( >=dev-python/sphinx-1.0.3 )"

# Workaround race condition in build_qt
DISTUTILS_IN_SOURCE_BUILD=1

python_prepare_all() {
	if [[ ${LINGUAS+set} ]]; then
		cd i18n/tortoisehg || die
		local x y keep
		for x in *.po; do
			keep=false
			for y in ${LINGUAS}; do
				if [[ ${y} == ${x%.po}* ]]; then
					keep=true
					break
				fi
			done
			${keep} || rm "${x}" || die
		done
		cd "${S}" || die
	fi
	distutils-r1_python_prepare_all
}

python_compile_all() {
	use doc && emake -C doc html
}

python_install_all() {
	distutils-r1_python_install_all
	dodoc doc/ReadMe*.txt doc/TODO contrib/mergetools.rc
	if use doc ; then
		dohtml -r doc/build/html/
	fi
	newicon -s scalable icons/scalable/apps/thg-logo.svg thg_logo.svg
	domenu contrib/${PN}.desktop
}

pkg_postinst() {
	elog "When startup of ${PN} fails with an API version mismatch error"
	elog "between dev-python/sip and dev-python/PyQt4 please rebuild"
	elog "dev-python/qscintilla-python."
}