[gentoo-commits] gentoo-x86 commit in app-admin/system-config-printer-common: ChangeLog system-config-printer-common-1.4.1.ebuild

[gentoo-commits] gentoo-x86 commit in app-admin/system-config-printer-common: ChangeLog system-config-printer-common-1.4.1.ebuild

[Gilles Dartiguelongue (eva)]

eva         13/08/11 20:02:07

  Modified:             ChangeLog
  Added:                system-config-printer-common-1.4.1.ebuild
  Log:
  464958 478656 Version bump, bug #464958. Move to python-single-r1 and EAPI=5. Always install systemd unit files and fix path to udev helpers with an updated 'split' patch, bug #478656.
  
  (Portage version: 2.2.0_alpha196/cvs/Linux x86_64, RepoMan options: --force, signed Manifest commit with key C6085806)

Revision  Changes    Path
1.97                 app-admin/system-config-printer-common/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/ChangeLog?rev=1.97&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/ChangeLog?rev=1.97&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/ChangeLog?r1=1.96&r2=1.97

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/system-config-printer-common/ChangeLog,v
retrieving revision 1.96
retrieving revision 1.97
diff -u -r1.96 -r1.97
--- ChangeLog	9 Apr 2013 16:40:46 -0000	1.96
+++ ChangeLog	11 Aug 2013 20:02:07 -0000	1.97
@@ -1,6 +1,15 @@
 # ChangeLog for app-admin/system-config-printer-common
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/system-config-printer-common/ChangeLog,v 1.96 2013/04/09 16:40:46 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/system-config-printer-common/ChangeLog,v 1.97 2013/08/11 20:02:07 eva Exp $
+
+*system-config-printer-common-1.4.1 (11 Aug 2013)
+
+  11 Aug 2013; Gilles Dartiguelongue <eva@gentoo.org>
+  +system-config-printer-common-1.4.1.ebuild,
+  +files/system-config-printer-common-1.4.1-split.patch:
+  464958 478656 Version bump, bug #464958. Move to python-single-r1 and EAPI=5.
+  Always install systemd unit files and fix path to udev helpers with an
+  updated 'split' patch, bug #478656.
 
   09 Apr 2013; Agostino Sarubbo <ago@gentoo.org>
   system-config-printer-common-1.3.12.ebuild:



1.1                  app-admin/system-config-printer-common/system-config-printer-common-1.4.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/system-config-printer-common-1.4.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/system-config-printer-common-1.4.1.ebuild?rev=1.1&content-type=text/plain

Index: system-config-printer-common-1.4.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/system-config-printer-common/system-config-printer-common-1.4.1.ebuild,v 1.1 2013/08/11 20:02:07 eva Exp $

EAPI="5"
PYTHON_COMPAT=( python2_{6,7} )
PYTHON_REQ_USE="xml"

inherit autotools eutils python-single-r1 systemd

MY_P=${PN%-common}-${PV}

DESCRIPTION="Common modules of Red Hat's printer administration tool"
HOMEPAGE="http://cyberelk.net/tim/software/system-config-printer/"
SRC_URI="http://cyberelk.net/tim/data/${PN/-common}/${PV%.*}/${MY_P}.tar.xz"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
SLOT="0"
IUSE="doc policykit"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

# Needs cups running, bug 284005
RESTRICT="test"

# system-config-printer split since 1.1.3
#
# Additional unhandled dependencies:
# net-firewall/firewalld[${PYTHON_USEDEP}]
# gnome-extra/gnome-packagekit[${PYTHON_USEDEP}] with pygobject:2 ?
COMMON_DEPEND="
	${PYTHON_DEPS}
	>=dev-libs/glib-2
	dev-libs/libxml2[python,${PYTHON_USEDEP}]
	dev-python/dbus-python[${PYTHON_USEDEP}]
	>=dev-python/pycups-1.9.60[${PYTHON_USEDEP}]
	dev-python/pycurl[${PYTHON_USEDEP}]
	dev-python/pygobject:3[${PYTHON_USEDEP}]
	net-print/cups[dbus]
	virtual/libusb:1
	>=virtual/udev-172
"
DEPEND="${COMMON_DEPEND}
	dev-util/intltool
	virtual/pkgconfig
	doc? ( dev-python/epydoc[${PYTHON_USEDEP}] )
"
RDEPEND="${COMMON_DEPEND}
	!<app-admin/system-config-printer-gnome-${PV}
	policykit? ( >=sys-auth/polkit-0.104-r1 )
"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	python-single-r1_pkg_setup
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.4.1-split.patch
	eautoreconf
}

src_configure() {
	econf \
		--disable-nls \
		--with-udev-rules \
		$(systemd_with_unitdir)
}

src_compile() {
	emake
	use doc && emake html
}

src_install() {
	emake DESTDIR="${D}" install

	dodoc AUTHORS ChangeLog README
	use doc && dohtml -r html/

	python_fix_shebang "${ED}"
}