[gentoo-commits] gentoo-x86 commit in xfce-extra/xfce4-whiskermenu-plugin: ChangeLog xfce4-whiskermenu-plugin-1.1.1.ebuild xfce4-whiskermenu-plugin-1.0.3.ebuild

["Julian Ospald (hasufell)" <hasufell@gentoo.org>]

hasufell    13/08/08 19:37:40

  Modified:             ChangeLog
  Added:                xfce4-whiskermenu-plugin-1.1.1.ebuild
  Removed:              xfce4-whiskermenu-plugin-1.0.3.ebuild
  Log:
  version bump, remove old
  
  (Portage version: 2.2.0_alpha195/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.3                  xfce-extra/xfce4-whiskermenu-plugin/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-extra/xfce4-whiskermenu-plugin/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-extra/xfce4-whiskermenu-plugin/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-extra/xfce4-whiskermenu-plugin/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/xfce-extra/xfce4-whiskermenu-plugin/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	28 Jul 2013 08:51:15 -0000	1.2
+++ ChangeLog	8 Aug 2013 19:37:40 -0000	1.3
@@ -1,6 +1,16 @@
 # ChangeLog for xfce-extra/xfce4-whiskermenu-plugin
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-extra/xfce4-whiskermenu-plugin/ChangeLog,v 1.2 2013/07/28 08:51:15 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-extra/xfce4-whiskermenu-plugin/ChangeLog,v 1.3 2013/08/08 19:37:40 hasufell Exp $
+
+*xfce4-whiskermenu-plugin-1.1.1 (08 Aug 2013)
+
+  08 Aug 2013; Julian Ospald <hasufell@gentoo.org>
+  -xfce4-whiskermenu-plugin-1.0.3.ebuild,
+  -files/xfce4-whiskermenu-plugin-1.0.3-Werror.patch,
+  -files/xfce4-whiskermenu-plugin-1.0.3-ldflags.patch,
+  -files/xfce4-whiskermenu-plugin-1.0.3-reorder-flags.patch,
+  +xfce4-whiskermenu-plugin-1.1.1.ebuild:
+  version bump, remove old
 
 *xfce4-whiskermenu-plugin-1.1.0 (28 Jul 2013)
 



1.1                  xfce-extra/xfce4-whiskermenu-plugin/xfce4-whiskermenu-plugin-1.1.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-extra/xfce4-whiskermenu-plugin/xfce4-whiskermenu-plugin-1.1.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-extra/xfce4-whiskermenu-plugin/xfce4-whiskermenu-plugin-1.1.1.ebuild?rev=1.1&content-type=text/plain

Index: xfce4-whiskermenu-plugin-1.1.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/xfce-extra/xfce4-whiskermenu-plugin/xfce4-whiskermenu-plugin-1.1.1.ebuild,v 1.1 2013/08/08 19:37:40 hasufell Exp $

EAPI=5

inherit gnome2-utils cmake-utils

DESCRIPTION="Alternate application launcher for Xfce"
HOMEPAGE="http://gottcode.org/xfce4-whiskermenu-plugin/"
SRC_URI="http://gottcode.org/xfce4-whiskermenu-plugin/${P}-src.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="
	x11-libs/gtk+:2
	xfce-base/exo
	xfce-base/garcon
	xfce-base/libxfce4ui
	xfce-base/libxfce4util
	xfce-base/xfce4-panel
	virtual/libintl"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	sys-devel/gettext"

src_prepare() {
	local i
	if [[ -n "${LINGUAS+x}" ]] ; then
		for i in $(grep add_subdirectory po/CMakeLists.txt | sed 's/add_subdirectory(//;s/)$//') ; do
			has ${i} ${LINGUAS} || { sed -i -e "/add_subdirectory(${i})/d" po/CMakeLists.txt || die ; }
		done
	fi
}

src_configure() {
	local mycmakeargs=(
		-DENABLE_WERROR=OFF
		-DENABLE_AS_NEEDED=OFF
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	dodoc ChangeLog CREDITS NEWS README
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}