[gentoo-commits] gentoo-x86 commit in sci-visualization/kst: kst-2.0.7.ebuild ChangeLog kst-2.0.5.ebuild

[gentoo-commits] gentoo-x86 commit in sci-visualization/kst: kst-2.0.7.ebuild ChangeLog kst-2.0.5.ebuild

[Michael Palimaka (kensington)]

kensington    13/08/01 18:28:16

  Modified:             ChangeLog
  Added:                kst-2.0.7.ebuild
  Removed:              kst-2.0.5.ebuild
  Log:
  Version bump. Remove old.
  
  (Portage version: 2.1.13.2/cvs/Linux x86_64, signed Manifest commit with key 675D0D2C)

Revision  Changes    Path
1.13                 sci-visualization/kst/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/kst/ChangeLog?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/kst/ChangeLog?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/kst/ChangeLog?r1=1.12&r2=1.13

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-visualization/kst/ChangeLog,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- ChangeLog	23 Jul 2013 14:19:51 -0000	1.12
+++ ChangeLog	1 Aug 2013 18:28:16 -0000	1.13
@@ -1,6 +1,12 @@
 # ChangeLog for sci-visualization/kst
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-visualization/kst/ChangeLog,v 1.12 2013/07/23 14:19:51 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-visualization/kst/ChangeLog,v 1.13 2013/08/01 18:28:16 kensington Exp $
+
+*kst-2.0.7 (01 Aug 2013)
+
+  01 Aug 2013; Michael Palimaka <kensington@gentoo.org>
+  +files/kst-2.0.7-cfitsio-includes.patch, +kst-2.0.7.ebuild, -kst-2.0.5.ebuild:
+  Version bump. Remove old.
 
   23 Jul 2013; Michael Palimaka <kensington@gentoo.org> kst-2.0.5.ebuild,
   kst-2.0.6.ebuild:



1.1                  sci-visualization/kst/kst-2.0.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/kst/kst-2.0.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/kst/kst-2.0.7.ebuild?rev=1.1&content-type=text/plain

Index: kst-2.0.7.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-visualization/kst/kst-2.0.7.ebuild,v 1.1 2013/08/01 18:28:16 kensington Exp $

EAPI=4

CMAKE_USE_DIR=${S}/cmake
MY_PN="Kst"
inherit cmake-utils multilib

DESCRIPTION="Fast real-time large-dataset viewing and plotting tool for KDE4"
HOMEPAGE="http://kst.kde.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_PN}-${PV}.tar.gz"

LICENSE="GPL-2 LGPL-2 FDL-1.2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug +qt4 qt5 test"

REQUIRED_USE="^^ ( qt4 qt5 )"

RESTRICT="test"

RDEPEND="
	qt4? (
		dev-qt/qtcore:4
		|| ( ( >=dev-qt/qtgui-4.8.5:4 dev-qt/designer:4 ) <dev-qt/qtgui-4.8.5:4 )
		dev-qt/qtopengl:4
		dev-qt/qtsvg:4
	)
	qt5? (
		dev-qt/qtconcurrent:5
		dev-qt/qtcore:5
		dev-qt/designer:5
		dev-qt/qtgui:5
		dev-qt/qtnetwork:5
		dev-qt/qtopengl:5
		dev-qt/qtprintsupport:5
		dev-qt/qtwidgets:5
		dev-qt/qtxml:5
	)
	sci-libs/cfitsio
	sci-libs/getdata
	sci-libs/gsl
	sci-libs/netcdf[cxx]
"
DEPEND="${RDEPEND}
	test? ( dev-qt/qttest:4 )
"

DOCS=( AUTHORS ChangeLog )
PATCHES=( "${FILESDIR}/${PN}-2.0.7-cfitsio-includes.patch" )

src_configure() {
	local mycmakeargs=(
		-Dkst_install_libdir=$(get_libdir)
		-Dkst_pch=OFF
		-Dkst_release=$(usex debug OFF ON)
		-Dkst_rpath=OFF
		-Dkst_svnversion=OFF
		$(cmake-utils_use test kst_test)
		$(cmake-utils_use qt5 kst_qt5)
	)
	cmake-utils_src_configure
}