[gentoo-commits] gentoo-x86 commit in net-im/gajim: ChangeLog gajim-0.16_alpha2.ebuild

[gentoo-commits] gentoo-x86 commit in net-im/gajim: ChangeLog gajim-0.16_alpha2.ebuild

[Justin Lecher (jlec)]

jlec        13/07/28 12:03:36

  Modified:             ChangeLog
  Added:                gajim-0.16_alpha2.ebuild
  Log:
  net-im/gajim: Bump to second alpha
  
  (Portage version: 2.2.0_alpha190/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

Revision  Changes    Path
1.187                net-im/gajim/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/ChangeLog?rev=1.187&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/ChangeLog?rev=1.187&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/ChangeLog?r1=1.186&r2=1.187

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/gajim/ChangeLog,v
retrieving revision 1.186
retrieving revision 1.187
diff -u -r1.186 -r1.187
--- ChangeLog	28 Jul 2013 09:16:02 -0000	1.186
+++ ChangeLog	28 Jul 2013 12:03:35 -0000	1.187
@@ -1,6 +1,11 @@
 # ChangeLog for net-im/gajim
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/gajim/ChangeLog,v 1.186 2013/07/28 09:16:02 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/gajim/ChangeLog,v 1.187 2013/07/28 12:03:35 jlec Exp $
+
+*gajim-0.16_alpha2 (28 Jul 2013)
+
+  28 Jul 2013; Justin Lecher <jlec@gentoo.org> +gajim-0.16_alpha2.ebuild:
+  Bump to second alpha
 
 *gajim-0.16_alpha1 (28 Jul 2013)
 



1.1                  net-im/gajim/gajim-0.16_alpha2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/gajim-0.16_alpha2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/gajim-0.16_alpha2.ebuild?rev=1.1&content-type=text/plain

Index: gajim-0.16_alpha2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/gajim/gajim-0.16_alpha2.ebuild,v 1.1 2013/07/28 12:03:35 jlec Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7} )
PYTHON_REQ_USE="sqlite,xml"

AUTOTOOLS_AUTORECONF=true

inherit autotools-utils python-r1 versionator

MY_PV=${PV/_/-}
MY_P="${PN}-${MY_PV}"

DESCRIPTION="Jabber client written in PyGTK"
HOMEPAGE="http://www.gajim.org/"
SRC_URI="
	http://www.gajim.org/downloads/$(get_version_component_range 1-2)/${MY_P}.tar.bz2"
#	test? ( http://dev.gentoo.org/~jlec/distfiles/${PN}-tests-${PV}.tar.xz )"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="avahi crypt dbus gnome gnome-keyring kde idle jingle libnotify networkmanager nls spell +srv test X xhtml"

REQUIRED_USE="
	${PYTHON_REQUIRED_USE}
	libnotify? ( dbus )
	avahi? ( dbus )
	gnome? ( gnome-keyring )"

COMMON_DEPEND="
	${PYTHON_DEPS}
	dev-python/pygtk:2[${PYTHON_USEDEP}]
	x11-libs/gtk+:2"
DEPEND="${COMMON_DEPEND}
	>=dev-util/intltool-0.40.1
	virtual/pkgconfig
	>=sys-devel/gettext-0.17-r1"
RDEPEND="${COMMON_DEPEND}
	dev-python/pyasn1[${PYTHON_USEDEP}]
	dev-python/pyopenssl[${PYTHON_USEDEP}]
	dev-python/python-nbxmpp[${PYTHON_USEDEP}]
	crypt? (
		app-crypt/gnupg
		dev-python/pycrypto[${PYTHON_USEDEP}]
		)
	dbus? (
		dev-python/dbus-python[${PYTHON_USEDEP}]
		dev-libs/dbus-glib
		libnotify? ( dev-python/notify-python[${PYTHON_USEDEP}] )
		avahi? ( net-dns/avahi[dbus,gtk,python,${PYTHON_USEDEP}] )
		)
	gnome? (
		dev-python/libgnome-python
		dev-python/egg-python
		)
	gnome-keyring? ( dev-python/gnome-keyring-python )
	idle? ( x11-libs/libXScrnSaver )
	jingle? ( net-libs/farstream:0.1[python] )
	kde? ( kde-base/kwallet )
	networkmanager? (
			dev-python/dbus-python[${PYTHON_USEDEP}]
			net-misc/networkmanager
		)
	spell? ( app-text/gtkspell:2 )
	srv? (
		|| (
			dev-python/libasyncns-python
			net-dns/bind-tools )
		)
	xhtml? ( dev-python/docutils[${PYTHON_USEDEP}] )"

RESTRICT="test"

S="${WORKDIR}"/${MY_P}

src_prepare() {
	autotools-utils_src_prepare
	python_copy_sources
}

src_configure() {
	configuration() {
		local myeconfargs=(
			$(use_enable nls)
			$(use_with X x)
			--docdir="/usr/share/doc/${PF}"
			--libdir="$(python_get_sitedir)"
			--enable-site-packages
		)
		run_in_build_dir autotools-utils_src_configure
	}
	python_foreach_impl configuration
}

src_compile() {
	compilation() {
		run_in_build_dir autotools-utils_src_compile
	}
	python_foreach_impl compilation
}

src_test() {
	testing() {
		run_in_build_dir ${PYTHON} test/runtests.py --verbose 3 || die
	}
	python_foreach_impl testing
}

src_install() {
	installation() {
		run_in_build_dir autotools-utils_src_install
		python_optimize "${ED}"/$(python_get_sitedir)
	}
	python_foreach_impl installation

	rm "${D}/usr/share/doc/${PF}/README.html" || die
	dohtml README.html
}