public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
* [gentoo-commits] gentoo-x86 commit in app-i18n/mozc: mozc-1.10.1390.102.ebuild ChangeLog
@ 2013-05-04  3:20 Naohiro Aota (naota)
  0 siblings, 0 replies; 3+ messages in thread
From: Naohiro Aota (naota) @ 2013-05-04  3:20 UTC (permalink / raw
  To: gentoo-commits

naota       13/05/04 03:20:57

  Modified:             ChangeLog
  Added:                mozc-1.10.1390.102.ebuild
  Log:
  Version bump wrt #465204
  
  (Portage version: 2.2.0_alpha171/cvs/Linux x86_64, signed Manifest commit with key F8551514)

Revision  Changes    Path
1.5                  app-i18n/mozc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/mozc/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/mozc/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/mozc/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-i18n/mozc/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	2 Mar 2013 19:28:02 -0000	1.4
+++ ChangeLog	4 May 2013 03:20:57 -0000	1.5
@@ -1,6 +1,12 @@
 # ChangeLog for app-i18n/mozc
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/mozc/ChangeLog,v 1.4 2013/03/02 19:28:02 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/mozc/ChangeLog,v 1.5 2013/05/04 03:20:57 naota Exp $
+
+*mozc-1.10.1390.102 (04 May 2013)
+
+  04 May 2013; Naohiro Aota <naota@gentoo.org>
+  +files/mozc-1.10.1390.102-drop-Werror.patch, +mozc-1.10.1390.102.ebuild:
+  Version bump wrt #465204
 
   02 Mar 2013; Markos Chandras <hwoarang@gentoo.org> mozc-1.3.975.102.ebuild,
   mozc-1.5.1090.102.ebuild, mozc-1.6.1187.102.ebuild:



1.1                  app-i18n/mozc/mozc-1.10.1390.102.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/mozc/mozc-1.10.1390.102.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/mozc/mozc-1.10.1390.102.ebuild?rev=1.1&content-type=text/plain

Index: mozc-1.10.1390.102.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-i18n/mozc/mozc-1.10.1390.102.ebuild,v 1.1 2013/05/04 03:20:57 naota Exp $

EAPI="5"
PYTHON_COMPAT=( python{2_6,2_7} )
inherit elisp-common eutils multilib multiprocessing python-single-r1 toolchain-funcs

DESCRIPTION="The Mozc engine for IBus Framework"
HOMEPAGE="http://code.google.com/p/mozc/"

PROTOBUF_VER="2.5.0"
GMOCK_VER="1.6.0"
GTEST_VER="1.6.0"
JSONCPP_VER="0.6.0-rc2"
MOZC_URL="http://mozc.googlecode.com/files/${P}.tar.bz2"
PROTOBUF_URL="http://protobuf.googlecode.com/files/protobuf-${PROTOBUF_VER}.tar.bz2"
GMOCK_URL="https://googlemock.googlecode.com/files/gmock-${GMOCK_VER}.zip"
GTEST_URL="https://googletest.googlecode.com/files/gtest-${GTEST_VER}.zip"
JSONCPP_URL="mirror://sourceforge/jsoncpp/jsoncpp-src-${JSONCPP_VER}.tar.gz"
SRC_URI="${MOZC_URL} ${PROTOBUF_URL}
	test? ( ${GMOCK_URL} ${GTEST_URL} ${JSONCPP_URL} )"

LICENSE="Apache-2.0 BSD Boost-1.0 ipadic public-domain unicode"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="emacs +ibus +qt4 renderer test"

RDEPEND="dev-libs/glib:2
	dev-libs/openssl
	x11-libs/libxcb
	emacs? ( virtual/emacs )
	ibus? ( >=app-i18n/ibus-1.4.1 )
	renderer? ( x11-libs/gtk+:2 )
	qt4? (
		dev-qt/qtgui:4
		app-i18n/zinnia
	)
	${PYTHON_DEPS}"
DEPEND="${RDEPEND}
	~dev-libs/protobuf-2.4.1
	virtual/pkgconfig"

BUILDTYPE="${BUILDTYPE:-Release}"

RESTRICT="test"

SITEFILE=50${PN}-gentoo.el

src_unpack() {
	unpack $(basename ${MOZC_URL})

	cd "${S}"/protobuf
	unpack $(basename ${PROTOBUF_URL})
	mv protobuf-${PROTOBUF_VER} files || die

	if use test; then
		cd "${S}"/third_party
		unpack $(basename ${GMOCK_URL}) $(basename ${GTEST_URL}) \
			$(basename ${JSONCPP_URL})
		mv gmock-${GMOCK_VER} gmock || die
		mv gtest-${GTEST_VER} gtest || die
		mv jsoncpp-src-${JSONCPP_VER} jsoncpp || die
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-drop-Werror.patch
}

src_configure() {
	local myconf="--server_dir=/usr/$(get_libdir)/mozc"

	if ! use qt4 ; then
		myconf+=" --noqt"
		export GYP_DEFINES="use_libzinnia=0"
	fi

	if ! use renderer ; then
		export GYP_DEFINES="${GYP_DEFINES} enable_gtk_renderer=0"
	fi

	# export GYP_DEFINES="${GYP_DEFINES} use_libprotobuf=1"

	"${PYTHON}" build_mozc.py gyp ${myconf} || die "gyp failed"
}

src_compile() {
	tc-export CC CXX AR AS RANLIB LD

	local my_makeopts=$(makeopts_jobs)
	# This is for a safety. -j without a number, makeopts_jobs returns 999.
	local myjobs=-j${my_makeopts/999/1}

	local mytarget="server/server.gyp:mozc_server"
	use emacs && mytarget="${mytarget} unix/emacs/emacs.gyp:mozc_emacs_helper"
	use ibus && mytarget="${mytarget} unix/ibus/ibus.gyp:ibus_mozc"
	use renderer && mytarget="${mytarget} renderer/renderer.gyp:mozc_renderer"
	if use qt4 ; then
		export QTDIR="${EPREFIX}/usr"
		mytarget="${mytarget} gui/gui.gyp:mozc_tool"
	fi

	V=1 "${PYTHON}" build_mozc.py build_tools -c "${BUILDTYPE}" ${myjobs} || die
	V=1 "${PYTHON}" build_mozc.py build -c "${BUILDTYPE}" ${mytarget} ${myjobs} || die

	if use emacs ; then
		elisp-compile unix/emacs/*.el || die
	fi
}

src_test() {
	tc-export CC CXX AR AS RANLIB LD
	V=1 "${PYTHON}" build_mozc.py runtests -c "${BUILDTYPE}" || die
}

src_install() {
	if use emacs ; then
		dobin "out_linux/${BUILDTYPE}/mozc_emacs_helper" || die
		elisp-install ${PN} unix/emacs/*.{el,elc} || die
		elisp-site-file-install "${FILESDIR}/${SITEFILE}" ${PN} || die
	fi

	if use ibus ; then
		exeinto /usr/libexec || die
		newexe "out_linux/${BUILDTYPE}/ibus_mozc" ibus-engine-mozc || die
		insinto /usr/share/ibus/component || die
		doins "out_linux/${BUILDTYPE}/obj/gen/unix/ibus/mozc.xml" || die
		insinto /usr/share/ibus-mozc || die
		(
			cd data/images/unix
			newins ime_product_icon_opensource-32.png product_icon.png || die
			for f in ui-*
			do
				newins ${f} ${f/ui-} || die
			done
		)

	fi

	exeinto "/usr/$(get_libdir)/mozc" || die
	doexe "out_linux/${BUILDTYPE}/mozc_server" || die

	if use qt4 ; then
		exeinto "/usr/$(get_libdir)/mozc" || die
		doexe "out_linux/${BUILDTYPE}/mozc_tool" || die
	fi

	if use renderer ; then
		exeinto "/usr/$(get_libdir)/mozc" || die
		doexe "out_linux/${BUILDTYPE}/mozc_renderer" || die
	fi
}

pkg_postinst() {
	if use emacs ; then
		elisp-site-regen
		elog "You can use mozc-mode via LEIM (Library of Emacs Input Method)."
		elog "Write the following settings into your init file (~/.emacs.d/init.el"
		elog "or ~/.emacs) in order to use mozc-mode by default, or you can call"
		elog "\`set-input-method' and set \"japanese-mozc\" anytime you have loaded"
		elog "mozc.el"
		elog
		elog "  (require 'mozc)"
		elog "  (set-language-environment \"Japanese\")"
		elog "  (setq default-input-method \"japanese-mozc\")"
		elog
		elog "Having the above settings, just type C-\\ which is bound to"
		elog "\`toggle-input-method' by default."
	fi
}

pkg_postrm() {
	use emacs && elisp-site-regen
}





^ permalink raw reply	[flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-i18n/mozc: mozc-1.10.1390.102.ebuild ChangeLog
@ 2013-05-10  5:27 Naohiro Aota (naota)
  0 siblings, 0 replies; 3+ messages in thread
From: Naohiro Aota (naota) @ 2013-05-10  5:27 UTC (permalink / raw
  To: gentoo-commits

naota       13/05/10 05:27:20

  Modified:             mozc-1.10.1390.102.ebuild ChangeLog
  Log:
  Call epatch_user
  
  (Portage version: 2.1.11.62/cvs/Linux x86_64, signed Manifest commit with key F8551514)

Revision  Changes    Path
1.2                  app-i18n/mozc/mozc-1.10.1390.102.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/mozc/mozc-1.10.1390.102.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/mozc/mozc-1.10.1390.102.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/mozc/mozc-1.10.1390.102.ebuild?r1=1.1&r2=1.2

Index: mozc-1.10.1390.102.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-i18n/mozc/mozc-1.10.1390.102.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- mozc-1.10.1390.102.ebuild	4 May 2013 03:20:57 -0000	1.1
+++ mozc-1.10.1390.102.ebuild	10 May 2013 05:27:20 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/mozc/mozc-1.10.1390.102.ebuild,v 1.1 2013/05/04 03:20:57 naota Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/mozc/mozc-1.10.1390.102.ebuild,v 1.2 2013/05/10 05:27:20 naota Exp $
 
 EAPI="5"
 PYTHON_COMPAT=( python{2_6,2_7} )
@@ -66,6 +66,7 @@
 
 src_prepare() {
 	epatch "${FILESDIR}"/${P}-drop-Werror.patch
+	epatch_user
 }
 
 src_configure() {



1.6                  app-i18n/mozc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/mozc/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/mozc/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/mozc/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-i18n/mozc/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	4 May 2013 03:20:57 -0000	1.5
+++ ChangeLog	10 May 2013 05:27:20 -0000	1.6
@@ -1,6 +1,9 @@
 # ChangeLog for app-i18n/mozc
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/mozc/ChangeLog,v 1.5 2013/05/04 03:20:57 naota Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/mozc/ChangeLog,v 1.6 2013/05/10 05:27:20 naota Exp $
+
+  10 May 2013; Naohiro Aota <naota@gentoo.org> mozc-1.10.1390.102.ebuild:
+  Call epatch_user
 
 *mozc-1.10.1390.102 (04 May 2013)
 





^ permalink raw reply	[flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-i18n/mozc: mozc-1.10.1390.102.ebuild ChangeLog
@ 2013-07-28  9:42 Naohiro Aota (naota)
  0 siblings, 0 replies; 3+ messages in thread
From: Naohiro Aota (naota) @ 2013-07-28  9:42 UTC (permalink / raw
  To: gentoo-commits

naota       13/07/28 09:42:56

  Modified:             mozc-1.10.1390.102.ebuild ChangeLog
  Log:
  Drop miss-added dep to dev-libs/protobuf. #478094
  
  (Portage version: 2.2.0_alpha188/cvs/Linux x86_64, signed Manifest commit with key F8551514)

Revision  Changes    Path
1.4                  app-i18n/mozc/mozc-1.10.1390.102.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/mozc/mozc-1.10.1390.102.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/mozc/mozc-1.10.1390.102.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/mozc/mozc-1.10.1390.102.ebuild?r1=1.3&r2=1.4

Index: mozc-1.10.1390.102.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-i18n/mozc/mozc-1.10.1390.102.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- mozc-1.10.1390.102.ebuild	20 Jul 2013 07:15:49 -0000	1.3
+++ mozc-1.10.1390.102.ebuild	28 Jul 2013 09:42:56 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/mozc/mozc-1.10.1390.102.ebuild,v 1.3 2013/07/20 07:15:49 naota Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/mozc/mozc-1.10.1390.102.ebuild,v 1.4 2013/07/28 09:42:56 naota Exp $
 
 EAPI="5"
 PYTHON_COMPAT=( python{2_6,2_7} )
@@ -38,7 +38,6 @@
 	)
 	${PYTHON_DEPS}"
 DEPEND="${RDEPEND}
-	~dev-libs/protobuf-2.4.1
 	virtual/pkgconfig"
 
 BUILDTYPE="${BUILDTYPE:-Release}"



1.8                  app-i18n/mozc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/mozc/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/mozc/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/mozc/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-i18n/mozc/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	20 Jul 2013 07:15:49 -0000	1.7
+++ ChangeLog	28 Jul 2013 09:42:56 -0000	1.8
@@ -1,6 +1,9 @@
 # ChangeLog for app-i18n/mozc
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/mozc/ChangeLog,v 1.7 2013/07/20 07:15:49 naota Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/mozc/ChangeLog,v 1.8 2013/07/28 09:42:56 naota Exp $
+
+  28 Jul 2013; Naohiro Aota <naota@gentoo.org> mozc-1.10.1390.102.ebuild:
+  Drop miss-added dep to dev-libs/protobuf. #478094
 
   20 Jul 2013; Naohiro Aota <naota@gentoo.org> mozc-1.10.1390.102.ebuild,
   mozc-1.6.1187.102.ebuild:





^ permalink raw reply	[flat|nested] 3+ messages in thread
end of thread, other threads:[~2013-07-28  9:42 UTC | newest]

Thread overview: 3+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-07-28  9:42 [gentoo-commits] gentoo-x86 commit in app-i18n/mozc: mozc-1.10.1390.102.ebuild ChangeLog Naohiro Aota (naota)
  -- strict thread matches above, loose matches on Subject: below --
2013-05-10  5:27 Naohiro Aota (naota)
2013-05-04  3:20 Naohiro Aota (naota)

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox