[gentoo-commits] gentoo-x86 commit in dev-qt/qtdemo: metadata.xml qtdemo-4.8.5-r1.ebuild ChangeLog qtdemo-4.8.5.ebuild

[gentoo-commits] gentoo-x86 commit in dev-qt/qtdemo: metadata.xml qtdemo-4.8.5-r1.ebuild ChangeLog qtdemo-4.8.5.ebuild

[Davide Pesavento (pesa)]

pesa        13/07/25 09:07:41

  Modified:             metadata.xml ChangeLog
  Added:                qtdemo-4.8.5-r1.ebuild
  Removed:              qtdemo-4.8.5.ebuild
  Log:
  Fix bugs #477652 and #477862.
  
  (Portage version: 2.2.0_alpha188/cvs/Linux x86_64, signed Manifest commit with key 17A85C72)

Revision  Changes    Path
1.2                  dev-qt/qtdemo/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qtdemo/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qtdemo/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qtdemo/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-qt/qtdemo/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	2 Mar 2013 15:27:09 -0000	1.1
+++ metadata.xml	25 Jul 2013 09:07:41 -0000	1.2
@@ -11,6 +11,7 @@
 		<flag name="multimedia">Build QtMultimedia examples and demos</flag>
 		<flag name="opengl">Build QtOpenGL examples and demos</flag>
 		<flag name="openvg">Build QtOpenVG examples and demos</flag>
+		<flag name="phonon">Build Phonon examples and demos</flag>
 		<flag name="qt3support">Build Qt3Support examples and demos</flag>
 		<flag name="webkit">Build QtWebKit examples and demos</flag>
 		<flag name="xmlpatterns">Build QtXmlPatterns examples and demos</flag>



1.5                  dev-qt/qtdemo/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qtdemo/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qtdemo/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qtdemo/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-qt/qtdemo/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	9 Jul 2013 10:47:30 -0000	1.4
+++ ChangeLog	25 Jul 2013 09:07:41 -0000	1.5
@@ -1,6 +1,12 @@
 # ChangeLog for dev-qt/qtdemo
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-qt/qtdemo/ChangeLog,v 1.4 2013/07/09 10:47:30 pesa Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-qt/qtdemo/ChangeLog,v 1.5 2013/07/25 09:07:41 pesa Exp $
+
+*qtdemo-4.8.5-r1 (25 Jul 2013)
+
+  25 Jul 2013; Davide Pesavento <pesa@gentoo.org> +qtdemo-4.8.5-r1.ebuild,
+  -qtdemo-4.8.5.ebuild, metadata.xml:
+  Fix bugs #477652 and #477862.
 
 *qtdemo-4.8.5 (09 Jul 2013)
 



1.1                  dev-qt/qtdemo/qtdemo-4.8.5-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qtdemo/qtdemo-4.8.5-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qtdemo/qtdemo-4.8.5-r1.ebuild?rev=1.1&content-type=text/plain

Index: qtdemo-4.8.5-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-qt/qtdemo/qtdemo-4.8.5-r1.ebuild,v 1.1 2013/07/25 09:07:41 pesa Exp $

EAPI=4

inherit qt4-build

DESCRIPTION="Demonstration module and examples for the Qt toolkit"
SLOT="4"
if [[ ${QT4_BUILD_TYPE} == live ]]; then
	KEYWORDS=""
else
	KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x64-macos"
fi
IUSE="dbus declarative kde multimedia opengl openvg phonon qt3support webkit xmlpatterns"

DEPEND="
	~dev-qt/designer-${PV}[aqua=,debug=]
	~dev-qt/qtcore-${PV}[aqua=,debug=,qt3support?]
	~dev-qt/qtgui-${PV}[aqua=,debug=,qt3support?]
	~dev-qt/qthelp-${PV}[aqua=,debug=]
	~dev-qt/qtscript-${PV}[aqua=,debug=]
	~dev-qt/qtsql-${PV}[aqua=,debug=,qt3support?]
	~dev-qt/qtsvg-${PV}[aqua=,debug=]
	~dev-qt/qttest-${PV}[aqua=,debug=]
	dbus? ( ~dev-qt/qtdbus-${PV}[aqua=,debug=] )
	declarative? ( ~dev-qt/qtdeclarative-${PV}[aqua=,debug=,webkit?] )
	multimedia? ( ~dev-qt/qtmultimedia-${PV}[aqua=,debug=] )
	opengl? ( ~dev-qt/qtopengl-${PV}[aqua=,debug=,qt3support?] )
	openvg? ( ~dev-qt/qtopenvg-${PV}[aqua=,debug=,qt3support?] )
	phonon? (
		kde? ( media-libs/phonon[aqua=] )
		!kde? ( || ( ~dev-qt/qtphonon-${PV}[aqua=,debug=] media-libs/phonon[aqua=] ) )
	)
	qt3support? ( ~dev-qt/qt3support-${PV}[aqua=,debug=] )
	webkit? ( ~dev-qt/qtwebkit-${PV}[aqua=,debug=] )
	xmlpatterns? ( ~dev-qt/qtxmlpatterns-${PV}[aqua=,debug=] )
"
RDEPEND="${DEPEND}"

PATCHES=(
	"${FILESDIR}/${PN}-4.6-plugandpaint.patch"
)

pkg_setup() {
	QT4_TARGET_DIRECTORIES="
		demos
		examples"
	QT4_EXTRACT_DIRECTORIES="${QT4_TARGET_DIRECTORIES}
		doc/src/images
		include
		src
		tools"

	qt4-build_pkg_setup
}

src_prepare() {
	qt4-build_src_prepare

	# Array mapping USE flags to subdirs
	local flags_subdirs_map=(
		'dbus'
		'declarative:declarative'
		'multimedia:spectrum'
		'opengl:boxes|glhypnotizer'
		'openvg'
		'phonon:mediaplayer'
		'webkit:browser'
		'xmlpatterns'
	)

	# Disable unwanted examples/demos
	for flag in "${flags_subdirs_map[@]}"; do
		if ! use ${flag%:*}; then
			einfo "Disabling ${flag%:*} examples"
			sed -i -e "/SUBDIRS += ${flag%:*}/d" \
				examples/examples.pro || die

			if [[ ${flag} == *:* ]]; then
				einfo "Disabling ${flag%:*} demos"
				sed -i -re "/SUBDIRS \+= demos_(${flag#*:})/d" \
					demos/demos.pro || die
			fi
		fi
	done

	if ! use qt3support; then
		einfo "Disabling qt3support examples"
		sed -i -e '/QT_CONFIG, qt3support/d' \
			examples/graphicsview/graphicsview.pro || die
	fi
}

src_configure() {
	myconf+="
		$(qt_use dbus)
		$(qt_use declarative)
		$(qt_use multimedia)
		$(qt_use opengl)
		$(qt_use openvg)
		$(qt_use phonon)
		$(qt_use qt3support)
		$(qt_use webkit)
		$(qt_use xmlpatterns)"

	qt4-build_src_configure
}

src_install() {
	insinto "${QTDOCDIR#${EPREFIX}}"/src
	doins -r doc/src/images

	qt4-build_src_install
}