[gentoo-commits] gentoo-x86 commit in dev-python/pip: pip-1.4.ebuild ChangeLog

["Dirkjan Ochtman (djc)" <djc@gentoo.org>]

djc         13/07/24 07:38:52

  Modified:             ChangeLog
  Added:                pip-1.4.ebuild
  Log:
  Version bump pip to 1.4.
  
  (Portage version: 2.1.12.13/cvs/Linux x86_64, signed Manifest commit with key 6B065BFB)

Revision  Changes    Path
1.19                 dev-python/pip/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pip/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pip/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pip/ChangeLog?r1=1.18&r2=1.19

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/pip/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog	3 May 2013 19:35:02 -0000	1.18
+++ ChangeLog	24 Jul 2013 07:38:52 -0000	1.19
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/pip
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pip/ChangeLog,v 1.18 2013/05/03 19:35:02 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pip/ChangeLog,v 1.19 2013/07/24 07:38:52 djc Exp $
+
+*pip-1.4 (24 Jul 2013)
+
+  24 Jul 2013; Dirkjan Ochtman <djc@gentoo.org> +pip-1.4.ebuild:
+  Version bump pip to 1.4.
 
   03 May 2013; Robin H. Johnson <robbat2@gentoo.org> pip-1.2.1.ebuild,
   pip-1.3.1.ebuild:



1.1                  dev-python/pip/pip-1.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pip/pip-1.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pip/pip-1.4.ebuild?rev=1.1&content-type=text/plain

Index: pip-1.4.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pip/pip-1.4.ebuild,v 1.1 2013/07/24 07:38:52 djc Exp $

EAPI=5
PYTHON_COMPAT=( python{2_5,2_6,2_7,3_1,3_2,3_3} )

inherit bash-completion-r1 distutils-r1 eutils

DESCRIPTION="Installs python packages -- replacement for easy_install"
HOMEPAGE="http://www.pip-installer.org/ http://pypi.python.org/pypi/pip/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="MIT"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
SLOT="0"
IUSE="zsh-completion"

RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
		!<=app-misc/pip-1.2"
DEPEND="${RDEPEND}"

# required test data isn't bundled with the tarball
RESTRICT="test"

python_prepare_all() {
	epatch "${FILESDIR}"/${PN}-1.3.1-unversioned.patch
	distutils-r1_python_prepare_all
}

python_install_all() {
	local DOCS=( AUTHORS.txt docs/*.txt )
	distutils-r1_python_install_all

	COMPLETION="${T}"/completion.tmp

	${EPYTHON} pip/runner.py completion --bash > "${COMPLETION}" || die
	newbashcomp "${COMPLETION}" ${PN}

	if use zsh-completion ; then
		${EPYTHON} pip/runner.py completion --zsh > "${COMPLETION}" || die
		insinto /usr/share/zsh/site-functions
		newins "${COMPLETION}" _pip
	fi
}