[gentoo-commits] gentoo-x86 commit in sys-fs/s3ql: s3ql-2.3.ebuild ChangeLog

["Tim Harder (radhermit)" <radhermit@gentoo.org>]

radhermit    13/07/20 01:41:22

  Modified:             ChangeLog
  Added:                s3ql-2.3.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha188/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.22                 sys-fs/s3ql/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/s3ql/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/s3ql/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/s3ql/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/s3ql/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	14 Jul 2013 01:20:46 -0000	1.21
+++ ChangeLog	20 Jul 2013 01:41:22 -0000	1.22
@@ -1,6 +1,11 @@
 # ChangeLog for sys-fs/s3ql
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/s3ql/ChangeLog,v 1.21 2013/07/14 01:20:46 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/s3ql/ChangeLog,v 1.22 2013/07/20 01:41:22 radhermit Exp $
+
+*s3ql-2.3 (20 Jul 2013)
+
+  20 Jul 2013; Tim Harder <radhermit@gentoo.org> +s3ql-2.3.ebuild:
+  Version bump.
 
 *s3ql-2.2 (14 Jul 2013)
 



1.1                  sys-fs/s3ql/s3ql-2.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/s3ql/s3ql-2.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/s3ql/s3ql-2.3.ebuild?rev=1.1&content-type=text/plain

Index: s3ql-2.3.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/s3ql/s3ql-2.3.ebuild,v 1.1 2013/07/20 01:41:22 radhermit Exp $

EAPI=5
PYTHON_COMPAT=( python3_3 )

inherit distutils-r1

DESCRIPTION="A full-featured file system for online data storage"
HOMEPAGE="http://code.google.com/p/s3ql/"
SRC_URI="http://s3ql.googlecode.com/files/${P/_/-}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="contrib doc test"

RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
	>=dev-python/apsw-3.7.0[${PYTHON_USEDEP}]
	>=dev-python/llfuse-0.39[${PYTHON_USEDEP}]
	dev-python/pycrypto[${PYTHON_USEDEP}]
	sys-fs/fuse"
DEPEND="${RDEPEND}
	test? (
		dev-python/pytest[${PYTHON_USEDEP}]
		net-misc/rsync[xattr]
	)"

python_test() {
	if [[ ${EUID} -ne 0 ]] ; then
		ewarn "Skipping tests: root privileges are required so userpriv must be disabled"
	else
		addwrite /dev/fuse
		esetup.py test
	fi
}

python_install_all() {
	distutils-r1_python_install_all

	if use contrib ; then
		exeinto /usr/share/doc/${PF}/contrib
		docompress -x /usr/share/doc/${PF}/contrib
		doexe contrib/*.{py,sh}
		doman contrib/*.1
	fi

	if use doc ; then
		dodoc doc/manual.pdf
		dohtml -r doc/html/*
	fi
}