* [gentoo-commits] gentoo-x86 commit in www-servers/varnish: varnish-3.0.4-r1.ebuild ChangeLog
@ 2013-07-08 22:11 Anthony G. Basile (blueness)
0 siblings, 0 replies; only message in thread
From: Anthony G. Basile (blueness) @ 2013-07-08 22:11 UTC (permalink / raw
To: gentoo-commits
blueness 13/07/08 22:11:35
Modified: ChangeLog
Added: varnish-3.0.4-r1.ebuild
Log:
Add sanity test and reload functionality to init.d script, bug #475600
(Portage version: 2.1.12.2/cvs/Linux x86_64, signed Manifest commit with key 0xF52D4BBA)
Revision Changes Path
1.63 www-servers/varnish/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-servers/varnish/ChangeLog?rev=1.63&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-servers/varnish/ChangeLog?rev=1.63&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-servers/varnish/ChangeLog?r1=1.62&r2=1.63
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-servers/varnish/ChangeLog,v
retrieving revision 1.62
retrieving revision 1.63
diff -u -r1.62 -r1.63
--- ChangeLog 21 Jun 2013 12:51:35 -0000 1.62
+++ ChangeLog 8 Jul 2013 22:11:35 -0000 1.63
@@ -1,6 +1,12 @@
# ChangeLog for www-servers/varnish
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-servers/varnish/ChangeLog,v 1.62 2013/06/21 12:51:35 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-servers/varnish/ChangeLog,v 1.63 2013/07/08 22:11:35 blueness Exp $
+
+*varnish-3.0.4-r1 (08 Jul 2013)
+
+ 08 Jul 2013; Anthony G. Basile <blueness@gentoo.org> +files/varnishd.confd-r1,
+ +files/varnishd.initd-r1, +varnish-3.0.4-r1.ebuild:
+ Add sanity test and reload functionality to init.d script, bug #475600
21 Jun 2013; Anthony G. Basile <blueness@gentoo.org>
+files/varnish-3.0.4-fix-automake-1.13.patch, varnish-3.0.4.ebuild:
1.1 www-servers/varnish/varnish-3.0.4-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-servers/varnish/varnish-3.0.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-servers/varnish/varnish-3.0.4-r1.ebuild?rev=1.1&content-type=text/plain
Index: varnish-3.0.4-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-servers/varnish/varnish-3.0.4-r1.ebuild,v 1.1 2013/07/08 22:11:35 blueness Exp $
EAPI="5"
inherit autotools-utils eutils
DESCRIPTION="Varnish is a state-of-the-art, high-performance HTTP accelerator"
HOMEPAGE="http://www.varnish-cache.org/"
SRC_URI="http://repo.varnish-cache.org/source/${P}.tar.gz"
LICENSE="BSD-2 GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~mips ~x86"
IUSE="doc jemalloc jit static-libs +tools"
CDEPEND="
|| ( dev-libs/libedit sys-libs/readline )
dev-libs/libpcre[jit?]
jemalloc? ( dev-libs/jemalloc )
tools? ( sys-libs/ncurses )"
#varnish compiles stuff at run time
RDEPEND="
${CDEPEND}
sys-devel/gcc"
DEPEND="
${CDEPEND}
virtual/pkgconfig"
RESTRICT="test" #315725
DOCS=( README doc/changes.rst )
PATCHES=(
"${FILESDIR}"/${PN}-3.0.4-fix-automake-1.13.patch
"${FILESDIR}"/${PN}-3.0.4-automagic.patch
"${FILESDIR}"/${PN}-3.0.3-pthread-uclibc.patch
)
AUTOTOOLS_AUTORECONF="yes"
src_prepare() {
# Remove bundled libjemalloc. We also fix
# automagic dep in our patches, bug #461638
rm -rf lib/libjemalloc
autotools-utils_src_prepare
}
src_configure() {
local myeconfargs=(
$(use_enable static-libs static)
$(use_enable jit pcre-jit )
$(use_with jemalloc)
$(use_with tools)
--without-rst2man
--without-rst2html
)
autotools-utils_src_configure
}
src_install() {
autotools-utils_src_install
newinitd "${FILESDIR}"/varnishd.initd-r1 varnishd
newconfd "${FILESDIR}"/varnishd.confd-r1 varnishd
insinto /etc/logrotate.d
newins "${FILESDIR}/varnishd.logrotate" varnishd
dodir /var/log/varnish
use doc && dohtml -r "doc/sphinx/=build/html/"
}
pkg_postinst () {
elog "No demo-/sample-configfile is included in the distribution. Please"
elog "read the man-page for more info. A sample configuration proxying"
elog "localhost:8080 for localhost:80 is given in /etc/conf.d/varnishd."
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-07-09 22:58 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-07-08 22:11 [gentoo-commits] gentoo-x86 commit in www-servers/varnish: varnish-3.0.4-r1.ebuild ChangeLog Anthony G. Basile (blueness)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox