[gentoo-commits] gentoo-x86 commit in sys-auth/fingerprint-gui: fingerprint-gui-1.05.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in sys-auth/fingerprint-gui: fingerprint-gui-1.05.ebuild ChangeLog

[Maxim Koltsov (maksbotan)]

maksbotan    13/07/07 09:36:10

  Modified:             ChangeLog
  Added:                fingerprint-gui-1.05.ebuild
  Log:
  Bump to 1.05, Upek 147e:2020 device now supported.
  
  Improvements to ebuild:
      - use new SRC_URI, old one returns html with tarball in frame
      - unistd patch is no longer needed
      - libbaspi.so now has multiple versions
      - correct sed command for desktop, '=' was left out
      - correct install path for uinput udev rules using get_udevdir
  
  (Portage version: 2.1.12.10/cvs/Linux x86_64, signed Manifest commit with key F8DBDADE)

Revision  Changes    Path
1.7                  sys-auth/fingerprint-gui/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/fingerprint-gui/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/fingerprint-gui/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/fingerprint-gui/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-auth/fingerprint-gui/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	2 Mar 2013 23:33:19 -0000	1.6
+++ ChangeLog	7 Jul 2013 09:36:09 -0000	1.7
@@ -1,6 +1,16 @@
 # ChangeLog for sys-auth/fingerprint-gui
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/fingerprint-gui/ChangeLog,v 1.6 2013/03/02 23:33:19 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/fingerprint-gui/ChangeLog,v 1.7 2013/07/07 09:36:09 maksbotan Exp $
+
+*fingerprint-gui-1.05 (07 Jul 2013)
+
+  07 Jul 2013; Maxim Koltsov <maksbotan@gentoo.org>
+  +fingerprint-gui-1.05.ebuild:
+  Bump to 1.05, Upek 147e:2020 device now supported.  Improvements to ebuild:
+  - use new SRC_URI, old one returns html with tarball in frame     - unistd
+  patch is no longer needed     - libbaspi.so now has multiple versions     -
+  correct sed command for desktop, '=' was left out     - correct install path
+  for uinput udev rules using get_udevdir
 
   02 Mar 2013; Markos Chandras <hwoarang@gentoo.org>
   fingerprint-gui-1.04.ebuild:



1.1                  sys-auth/fingerprint-gui/fingerprint-gui-1.05.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/fingerprint-gui/fingerprint-gui-1.05.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/fingerprint-gui/fingerprint-gui-1.05.ebuild?rev=1.1&content-type=text/plain

Index: fingerprint-gui-1.05.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-auth/fingerprint-gui/fingerprint-gui-1.05.ebuild,v 1.1 2013/07/07 09:36:09 maksbotan Exp $

EAPI=4

inherit eutils multilib qt4-r2 udev

DESCRIPTION="Use Fingerprint Devices with Linux"
HOMEPAGE="http://www.n-view.net/Appliance/fingerprint/"
SRC_URI="http://ullrich-online.cc/nview/Appliance/${PN%-gui}/download/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+upekbsapi"

RDEPEND="app-crypt/qca
	app-crypt/qca-ossl
	sys-auth/libfprint
	sys-auth/polkit-qt
	sys-libs/pam
	x11-libs/libfakekey
	dev-qt/qtcore:4
	!sys-auth/thinkfinger"
DEPEND="${RDEPEND}"

QA_SONAME="/usr/lib/libbsapi.so.* /usr/lib64/libbsapi.so.*"
QA_PRESTRIPPED="/usr/lib/libbsapi.so.* /usr/lib64/libbsapi.so.*"
QA_FLAGS_IGNORED="/usr/lib/libbsapi.so.* /usr/lib64/libbsapi.so.*"

src_prepare() {
	sed -e '/Icon=/s:=.*:=Fingerprint:' \
		-i bin/${PN}/${PN}.desktop || die
	sed -e "s:/etc/udev/rules.d:\"$(get_udevdir)\"/rules.d:g" \
		-i bin/${PN%-gui}-helper/${PN%-gui}-helper.pro || die
}

src_configure() {
	eqmake4 \
		PREFIX="${EROOT}"usr \
		LIB="$(get_libdir)" \
		LIBEXEC=libexec \
		LIBPOLKIT_QT=LIBPOLKIT_QT_1_1
}

src_install() {
	emake INSTALL_ROOT="${D}" install
	rm -r "${ED}"/usr/share/doc/${PN} || die
	if use upekbsapi ; then
		use amd64 && dolib.so upek/lib64/libbsapi.so*
		use x86 && dolib.so upek/lib/libbsapi.so*
		udev_dorules upek/91-fingerprint-gui-upek.rules
		insinto /etc
		doins upek/upek.cfg
		#dodir /var/upek_data
		#fowners root:plugdev /var/upek_data
		#fperms 0775 /var/upek_data
	fi
	doicon src/res/Fingerprint.png

	dodoc CHANGELOG README
	dohtml doc/*
}

pkg_postinst() {
	elog "Please take a thorough look a the Install-step-by-step.html"
	elog "in /usr/share/doc/${PF} for integration with pam/polkit/..."
	elog "Hint: You may want"
	elog "   auth        sufficient  pam_fingerprint-gui.so"
	elog "in /etc/pam.d/system-auth"
	einfo
	elog "There are udev rules to enforce group plugdev on the reader device"
	elog "Please put yourself in that group and re-trigger the udev rules."
}