[gentoo-commits] gentoo-x86 commit in kde-base/plasma-workspace: plasma-workspace-4.10.5-r1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in kde-base/plasma-workspace: plasma-workspace-4.10.5-r1.ebuild ChangeLog

[Michael Palimaka (kensington)]

kensington    13/07/03 07:42:27

  Modified:             ChangeLog
  Added:                plasma-workspace-4.10.5-r1.ebuild
  Log:
  Backport patch from upstream to solve a memory leak issue, wrt bug #447862.
  
  (Portage version: 2.1.12.11/cvs/Linux x86_64, signed Manifest commit with key 675D0D2C)

Revision  Changes    Path
1.230                kde-base/plasma-workspace/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/ChangeLog?rev=1.230&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/ChangeLog?rev=1.230&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/ChangeLog?r1=1.229&r2=1.230

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/plasma-workspace/ChangeLog,v
retrieving revision 1.229
retrieving revision 1.230
diff -u -r1.229 -r1.230
--- ChangeLog	2 Jul 2013 16:48:04 -0000	1.229
+++ ChangeLog	3 Jul 2013 07:42:27 -0000	1.230
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/plasma-workspace
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/plasma-workspace/ChangeLog,v 1.229 2013/07/02 16:48:04 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/plasma-workspace/ChangeLog,v 1.230 2013/07/03 07:42:27 kensington Exp $
+
+*plasma-workspace-4.10.5-r1 (03 Jul 2013)
+
+  03 Jul 2013; Michael Palimaka <kensington@gentoo.org>
+  +files/plasma-workspace-4.10.5-leak.patch, +plasma-workspace-4.10.5-r1.ebuild:
+  Backport patch from upstream to solve a memory leak issue, wrt bug #447862.
 
 *plasma-workspace-4.10.5 (02 Jul 2013)
 



1.1                  kde-base/plasma-workspace/plasma-workspace-4.10.5-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/plasma-workspace-4.10.5-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/plasma-workspace-4.10.5-r1.ebuild?rev=1.1&content-type=text/plain

Index: plasma-workspace-4.10.5-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/plasma-workspace/plasma-workspace-4.10.5-r1.ebuild,v 1.1 2013/07/03 07:42:27 kensington Exp $

EAPI=5

DECLARATIVE_REQUIRED="always"
KDE_HANDBOOK="optional"
KMNAME="kde-workspace"
KMMODULE="plasma"
PYTHON_DEPEND="python? 2"
OPENGL_REQUIRED="always"
inherit python kde4-meta

DESCRIPTION="Plasma: KDE desktop framework"
KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="debug gps json python qalculate +rss semantic-desktop"

COMMONDEPEND="
	dev-libs/libdbusmenu-qt
	>=dev-qt/qtcore-4.8.4-r3:4
	!kde-misc/ktouchpadenabler
	$(add_kdebase_dep kactivities)
	$(add_kdebase_dep kdelibs 'semantic-desktop(+)?')
	$(add_kdebase_dep kephal)
	$(add_kdebase_dep ksysguard)
	$(add_kdebase_dep libkworkspace)
	$(add_kdebase_dep libplasmagenericshell)
	$(add_kdebase_dep libtaskmanager)
	$(add_kdebase_dep solid)
	x11-libs/libX11
	x11-libs/libXcomposite
	x11-libs/libXdamage
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libXi
	x11-libs/libXrender
	gps? ( >=sci-geosciences/gpsd-2.37 )
	json? ( dev-libs/qjson )
	python? (
		>=dev-python/PyQt4-4.4.0[X]
		$(add_kdebase_dep pykde4)
	)
	qalculate? ( sci-libs/libqalculate )
	rss? (
		$(add_kdebase_dep kdepimlibs 'semantic-desktop(+)?')
		$(add_kdebase_dep libplasmaclock 'holidays(+)')
	)
	!rss? ( $(add_kdebase_dep libplasmaclock '-holidays(+)') )
	semantic-desktop? (
		dev-libs/soprano
		$(add_kdebase_dep nepomuk-core)
	)
"
DEPEND="${COMMONDEPEND}
	rss? ( dev-libs/boost )
	x11-proto/compositeproto
	x11-proto/damageproto
	x11-proto/fixesproto
	x11-proto/renderproto
"
RDEPEND="${COMMONDEPEND}
	$(add_kdebase_dep plasma-runtime)
"

KMEXTRA="
	appmenu/
	ktouchpadenabler/
	statusnotifierwatcher/
"
KMEXTRACTONLY="
	kcheckpass/
	krunner/dbus/org.freedesktop.ScreenSaver.xml
	krunner/dbus/org.kde.krunner.App.xml
	ksmserver/org.kde.KSMServerInterface.xml
	ksmserver/screenlocker/
	libs/kephal/
	libs/kworkspace/
	libs/taskmanager/
	libs/plasmagenericshell/
	libs/ksysguard/
	libs/kdm/kgreeterplugin.h
	ksysguard/
"

KMLOADLIBS="libkworkspace libplasmaclock libplasmagenericshell libtaskmanager"

PATCHES=(
	"${FILESDIR}/${PN}-4.10.1-noplasmalock.patch"
	"${FILESDIR}/${PN}-4.10.5-leak.patch"
)

pkg_setup() {
	if use python ; then
		python_set_active_version 2
		python_pkg_setup
	fi
	kde4-meta_pkg_setup
}

src_unpack() {
	if use handbook; then
		KMEXTRA+=" doc/plasma-desktop"
	fi

	kde4-meta_src_unpack
}

src_configure() {
	mycmakeargs=(
		$(cmake-utils_use_with gps libgps)
		$(cmake-utils_use_with json QJSON)
		$(cmake-utils_use_with python PythonLibrary)
		$(cmake-utils_use_with qalculate)
		$(cmake-utils_use_with rss KdepimLibs)
		$(cmake-utils_use_with semantic-desktop Akonadi)
		$(cmake-utils_use_with semantic-desktop NepomukCore)
		$(cmake-utils_use_with semantic-desktop Soprano)
		-DWITH_Googlegadgets=OFF
		-DWITH_Xmms=OFF
	)

	kde4-meta_src_configure
}

pkg_postinst() {
	kde4-meta_pkg_postinst

	if use python; then
		python_mod_optimize \
			PyKDE4/plasmascript.py \
			/usr/share/apps/plasma_scriptengine_python
	fi
}

pkg_postrm() {
	kde4-meta_pkg_postrm

	if use python; then
		python_mod_cleanup \
			PyKDE4/plasmascript.py \
			/usr/share/apps/plasma_scriptengine_python
	fi
}