* [gentoo-commits] gentoo-x86 commit in games-emulation/sdlmess: sdlmess-0.149.ebuild ChangeLog
@ 2013-06-26 13:16 Julian Ospald (hasufell)
0 siblings, 0 replies; only message in thread
From: Julian Ospald (hasufell) @ 2013-06-26 13:16 UTC (permalink / raw
To: gentoo-commits
hasufell 13/06/26 13:16:12
Modified: ChangeLog
Added: sdlmess-0.149.ebuild
Log:
version bump
(Portage version: 2.2.0_alpha185/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)
Revision Changes Path
1.4 games-emulation/sdlmess/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/sdlmess/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/sdlmess/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/sdlmess/ChangeLog?r1=1.3&r2=1.4
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-emulation/sdlmess/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog 1 May 2013 10:36:37 -0000 1.3
+++ ChangeLog 26 Jun 2013 13:16:12 -0000 1.4
@@ -1,6 +1,13 @@
# ChangeLog for games-emulation/sdlmess
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-emulation/sdlmess/ChangeLog,v 1.3 2013/05/01 10:36:37 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-emulation/sdlmess/ChangeLog,v 1.4 2013/06/26 13:16:12 hasufell Exp $
+
+*sdlmess-0.149 (26 Jun 2013)
+
+ 26 Jun 2013; Julian Ospald <hasufell@gentoo.org> +sdlmess-0.149.ebuild,
+ +files/sdlmess-0.149-QA.patch, +files/sdlmess-0.149-debugger-linking.patch,
+ +files/sdlmess-0.149-no-opengl.patch, +files/sdlmess-0.149-system-lua.patch:
+ version bump
01 May 2013; Agostino Sarubbo <ago@gentoo.org> sdlmess-0.148_p1.ebuild:
Stable for x86, wrt bug #468054
1.1 games-emulation/sdlmess/sdlmess-0.149.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/sdlmess/sdlmess-0.149.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/sdlmess/sdlmess-0.149.ebuild?rev=1.1&content-type=text/plain
Index: sdlmess-0.149.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-emulation/sdlmess/sdlmess-0.149.ebuild,v 1.1 2013/06/26 13:16:12 hasufell Exp $
EAPI=5
PYTHON_COMPAT=( python2_6 python2_7 )
inherit eutils flag-o-matic python-any-r1 games
MY_PV=${PV/.}
MY_CONF_PN=${PN/sdl}
MY_P=sdlmame${MY_PV}
MY_P=${MY_P%%_p*}
MY_CONF_VER="0.148"
# patches
SRC_URI="$(for PATCH_VER in $(seq 1 ${PV##*_p}) ; do echo "http://dev.gentoo.org/~hasufell/distfiles/${MY_P}u${PATCH_VER}_diff.zip"; done)"
DESCRIPTION="Multi Emulator Super System (SDL)"
HOMEPAGE="http://mamedev.org/"
# Upstream doesn't allow fetching with unknown User-Agent such as wget
SRC_URI="$SRC_URI http://dev.gentoo.org/~hasufell/distfiles/${MY_P/sdl}s.zip"
if [[ ${PN} == "sdlmame" ]] ; then
SRC_URI="$SRC_URI http://www.netswarm.net/misc/sdlmame-ui.bdf.gz"
fi
LICENSE="XMAME"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="X alsa debug opengl"
REQUIRED_USE="debug? ( X )"
RDEPEND=">=dev-lang/lua-5.2
dev-libs/expat
media-libs/fontconfig
media-libs/flac
>=media-libs/libsdl-1.2.10[audio,joystick,opengl?,video]
media-libs/sdl-ttf
sys-libs/zlib
virtual/jpeg
alsa? ( media-libs/alsa-lib )
debug? (
x11-libs/gtk+:2
gnome-base/gconf
)
X? (
x11-libs/libX11
x11-libs/libXinerama
)"
DEPEND="${RDEPEND}
${PYTHON_DEPS}
app-arch/unzip
virtual/pkgconfig
X? ( x11-proto/xineramaproto )"
S=${WORKDIR}
# Function to disable a makefile option
disable_feature() {
sed -i \
-e "/$1.*=/s:^:# :" \
"${S}"/${2:-makefile} \
|| die "sed failed"
}
# Function to enable a makefile option
enable_feature() {
sed -i \
-e "/^#.*$1.*=/s:^#::" \
"${S}"/${2:-makefile} \
|| die "sed failed"
}
pkg_setup() {
games_pkg_setup
python-any-r1_pkg_setup
}
src_unpack() {
default
unpack ./mame.zip
rm -f mame.zip
}
src_prepare() {
if [[ $PV == *_p* ]] ; then
edos2unix $(find $(grep +++ *diff | awk '{ print $2 }' | sort -u) 2>/dev/null) *diff
einfo "Patching release with source updates"
epatch ${MY_PV%%_p*}*.diff
fi
edos2unix makefile src/osd/sdl/{osdsdl.h,sdl.mak}
epatch \
"${FILESDIR}"/${P}-QA.patch \
"${FILESDIR}"/${P}-system-lua.patch \
"${FILESDIR}"/${P}-no-opengl.patch \
"${FILESDIR}"/${P}-debugger-linking.patch
# Don't compile zlib and expat
einfo "Disabling embedded libraries: expat, flac, jpeg, zlib, lua"
disable_feature BUILD_EXPAT
disable_feature BUILD_FLAC
disable_feature BUILD_JPEG
disable_feature BUILD_ZLIB
disable_feature BUILD_LUA
if use amd64; then
einfo "Enabling 64-bit support"
enable_feature PTR64
fi
if use ppc; then
einfo "Enabling PPC support"
enable_feature BIGENDIAN
fi
if use debug; then
einfo "Enabling debug support"
enable_feature DEBUG
enable_feature DEBUG src/osd/sdl/sdl.mak
fi
enable_feature NO_USE_QTDEBUG src/osd/sdl/sdl.mak
if ! use opengl ; then
einfo "Disabling opengl support"
enable_feature NO_OPENGL src/osd/sdl/sdl.mak
fi
if ! use alsa ; then
einfo "Disabling alsa midi support"
enable_feature NO_USE_MIDI src/osd/sdl/sdl.mak
fi
if ! use X ; then
einfo "Disabling X support"
enable_feature NO_X11 src/osd/sdl/sdl.mak
fi
}
src_compile() {
emake \
TARGET="${PN#sdl}" \
NAME="${PN}" \
OPT_FLAGS='-DINI_PATH=\"\$$HOME/.'${PN}'\;'"${GAMES_SYSCONFDIR}/${PN}"'\"' \
NO_DEBUGGER=$(usex debug "0" "1") default
}
src_install() {
newgamesbin ${PN}$(use amd64 && echo 64)$(use debug && echo d) ${PN}
newman src/osd/sdl/man/${PN#sdl}.6 ${PN}.6
insinto "${GAMES_DATADIR}/${PN}"
doins -r src/osd/sdl/keymaps
[[ ${PN} == "sdlmame" ]] && newins sdlmame-ui.bdf ui.bdf
insinto "${GAMES_SYSCONFDIR}/${PN}"
doins "${FILESDIR}"/vector.ini
sed \
-e "s:@GAMES_SYSCONFDIR@:${GAMES_SYSCONFDIR}:" \
-e "s:@GAMES_DATADIR@:${GAMES_DATADIR}:" \
"${FILESDIR}/${MY_CONF_PN}-${MY_CONF_VER}".ini.in > "${D}/${GAMES_SYSCONFDIR}/${PN}/${MY_CONF_PN}".ini \
|| die "sed failed"
dodoc docs/{config,mame,newvideo}.txt
if [[ ${PN} == "sdlmame" ]] ; then
dodoc whatsnew*.txt
else
dodoc messnew*.txt
fi
keepdir \
"${GAMES_DATADIR}/${PN}"/{ctrlr,cheats,roms,samples,artwork,crosshair} \
"${GAMES_SYSCONFDIR}/${PN}"/{ctrlr,cheats}
prepgamesdirs
}
pkg_postinst() {
games_pkg_postinst
elog "optional dependencies:"
elog " games-emulation/sdlmametools (development tools)"
echo
elog "It's strongly recommended that you change either the system-wide"
elog "${MY_CONF_PN}.ini at \"${GAMES_SYSCONFDIR}/${PN}\" or use a per-user setup at \$HOME/.${PN}"
if use opengl; then
echo
elog "You built ${PN} with opengl support and should set"
elog "\"video\" to \"opengl\" in ${MY_CONF_PN}.ini to take advantage of that"
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-06-26 13:16 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-06-26 13:16 [gentoo-commits] gentoo-x86 commit in games-emulation/sdlmess: sdlmess-0.149.ebuild ChangeLog Julian Ospald (hasufell)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox