[gentoo-commits] gentoo-x86 commit in net-misc/htbinit: htbinit-0.8.5-r6.ebuild ChangeLog

["Pacho Ramos (pacho)" <pacho@gentoo.org>]

pacho       13/06/25 17:07:11

  Modified:             ChangeLog
  Added:                htbinit-0.8.5-r6.ebuild
  Log:
  Fix 'ip' path (#474700 by Lorand Kelemen)
  
  (Portage version: 2.1.12.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.23                 net-misc/htbinit/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/htbinit/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/htbinit/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/htbinit/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/htbinit/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	4 May 2013 13:40:21 -0000	1.22
+++ ChangeLog	25 Jun 2013 17:07:11 -0000	1.23
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/htbinit
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/htbinit/ChangeLog,v 1.22 2013/05/04 13:40:21 tomwij Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/htbinit/ChangeLog,v 1.23 2013/06/25 17:07:11 pacho Exp $
+
+*htbinit-0.8.5-r6 (25 Jun 2013)
+
+  25 Jun 2013; Pacho Ramos <pacho@gentoo.org> +htbinit-0.8.5-r6.ebuild:
+  Fix 'ip' path (#474700 by Lorand Kelemen)
 
   04 May 2013; Tom Wijsman <TomWij@gentoo.org> htbinit-0.8.5-r5.ebuild,
   metadata.xml:



1.1                  net-misc/htbinit/htbinit-0.8.5-r6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/htbinit/htbinit-0.8.5-r6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/htbinit/htbinit-0.8.5-r6.ebuild?rev=1.1&content-type=text/plain

Index: htbinit-0.8.5-r6.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/htbinit/htbinit-0.8.5-r6.ebuild,v 1.1 2013/06/25 17:07:11 pacho Exp $

EAPI=5
inherit eutils linux-info

DESCRIPTION="Sets up Hierachical Token Bucket based traffic control (QoS) with iproute2"
HOMEPAGE="http://www.sourceforge.net/projects/htbinit"
SRC_URI="mirror://sourceforge/htbinit/htb.init-v${PV}"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="ipv6 esfq"

DEPEND="sys-apps/iproute2"
RDEPEND="${DEPEND}"

S=${WORKDIR}

pkg_setup() {
	for i in NET_SCH_HTB NET_SCH_SFQ NET_CLS_FW NET_CLS_U32 NET_CLS_ROUTE ; do
		CONFIG_CHECK="${CONFIG_CHECK} ~${i}"
	done
	use esfq && CONFIG_CHECK="${CONFIG_CHECK} ~NET_SCH_ESFQ"
	linux-info_pkg_setup
}

src_unpack() {
	cp "${DISTDIR}"/htb.init-v${PV} "${S}"/htb.init || die
}

src_prepare() {
	sed -i 's|/etc/sysconfig/htb|/etc/htb|g' "${S}"/htb.init
	epatch "${FILESDIR}"/htb.init-v0.8.5_tos.patch
	use ipv6 && epatch "${FILESDIR}"/htb_0.8.5_ipv6.diff
	use esfq && epatch "${FILESDIR}"/htb_0.8.5_esfq.diff
	epatch "${FILESDIR}"/prio_rule.patch
	epatch "${FILESDIR}"/timecheck_fix.patch
	epatch "${FILESDIR}"/htb.init_find_fix.patch
	sed -i -e 's:/sbin/ip:/bin/ip:g' "${S}"/htb.init # bug #474700
}

src_compile() {
	:
}

src_install() {
	dosbin htb.init
	newinitd "${FILESDIR}"/htbinit.rc htbinit
	keepdir /etc/htb
}

pkg_postinst() {
	if [[ -z ${REPLACING_VERSIONS} ]] ; then
		elog 'Run "rc-update add htbinit default" to run htb.init at startup.'
		elog 'Please, read carefully the htb.init documentation.'
		elog 'New directory to store configuration is /etc/htb.'
	fi
}