[gentoo-commits] gentoo-x86 commit in sci-biology/mafft: ChangeLog mafft-7.047.ebuild

[gentoo-commits] gentoo-x86 commit in sci-biology/mafft: ChangeLog mafft-7.047.ebuild

[Justin Lecher (jlec)]

jlec        13/06/24 09:53:38

  Modified:             ChangeLog
  Added:                mafft-7.047.ebuild
  Log:
  sci-biology/mafft: Version Bump
  
  (Portage version: 2.2.0_alpha184/cvs/Linux x86_64, signed Manifest commit with key 8009D6F070EB7916)

Revision  Changes    Path
1.18                 sci-biology/mafft/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-biology/mafft/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-biology/mafft/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-biology/mafft/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-biology/mafft/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	12 Jun 2013 13:42:20 -0000	1.17
+++ ChangeLog	24 Jun 2013 09:53:38 -0000	1.18
@@ -1,6 +1,11 @@
 # ChangeLog for sci-biology/mafft
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-biology/mafft/ChangeLog,v 1.17 2013/06/12 13:42:20 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-biology/mafft/ChangeLog,v 1.18 2013/06/24 09:53:38 jlec Exp $
+
+*mafft-7.047 (24 Jun 2013)
+
+  24 Jun 2013; Justin Lecher <jlec@gentoo.org> +mafft-7.047.ebuild:
+  Version Bump
 
 *mafft-7.046 (12 Jun 2013)
 



1.1                  sci-biology/mafft/mafft-7.047.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-biology/mafft/mafft-7.047.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-biology/mafft/mafft-7.047.ebuild?rev=1.1&content-type=text/plain

Index: mafft-7.047.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-biology/mafft/mafft-7.047.ebuild,v 1.1 2013/06/24 09:53:38 jlec Exp $

EAPI=5

inherit eutils flag-o-matic multilib toolchain-funcs

EXTENSIONS="-without-extensions"

DESCRIPTION="Multiple sequence alignments using a variety of algorithms"
HOMEPAGE="http://mafft.cbrc.jp/alignment/software/index.html"
SRC_URI="http://mafft.cbrc.jp/alignment/software/${P}${EXTENSIONS}-src.tgz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x64-macos ~x86-macos"
IUSE="threads"

S="${WORKDIR}"/${P}${EXTENSIONS}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-7.037-respect.patch
	use threads && append-cppflags -Denablemultithread
	sed "s:GENTOOLIBDIR:$(get_libdir):g" -i core/Makefile || die
	sed -i -e "s/(PREFIX)\/man/(PREFIX)\/share\/man/" "${S}"/core/Makefile || die "sed failed"
}

src_compile() {
	pushd core > /dev/null || die
	emake \
		$(usex threads ENABLE_MULTITHREAD="-Denablemultithread" ENABLE_MULTITHREAD="") \
		PREFIX="${EPREFIX}"/usr \
		CC="$(tc-getCC)" \
		CFLAGS="${CFLAGS}"
	popd > /dev/null || die
}

src_test() {
	export MAFFT_BINARIES="${S}"/core
	cd test || die
	bash ../core/mafft sample > test.fftns2 || die
	bash ../core/mafft --maxiterate 100  sample > test.fftnsi || die
	bash ../core/mafft --globalpair sample > test.gins1 || die
	bash ../core/mafft --globalpair --maxiterate 100  sample > test.ginsi || die
	bash ../core/mafft --localpair sample > test.lins1 || die
	bash ../core/mafft --localpair --maxiterate 100  sample > test.linsi || die

	diff test.fftns2 sample.fftns2 || die
	diff test.fftnsi sample.fftnsi || die
	diff test.gins1 sample.gins1 || die
	diff test.ginsi sample.ginsi || die
	diff test.lins1 sample.lins1 || die
}

src_install() {
	pushd core
	emake PREFIX="${ED}usr" install
	popd
	dodoc readme
}