[gentoo-commits] gentoo-x86 commit in media-sound/umurmur: umurmur-0.2.13.ebuild ChangeLog metadata.xml

[gentoo-commits] gentoo-x86 commit in media-sound/umurmur: umurmur-0.2.13.ebuild ChangeLog metadata.xml

[Lars Wendler (polynomial-c)]

polynomial-c    13/06/20 09:10:30

  Added:                umurmur-0.2.13.ebuild ChangeLog metadata.xml
  Log:
  Initial commit (bug #371773)
  
  (Portage version: 2.2.0_alpha182/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

Revision  Changes    Path
1.1                  media-sound/umurmur/umurmur-0.2.13.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/umurmur/umurmur-0.2.13.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/umurmur/umurmur-0.2.13.ebuild?rev=1.1&content-type=text/plain

Index: umurmur-0.2.13.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/umurmur/umurmur-0.2.13.ebuild,v 1.1 2013/06/20 09:10:29 polynomial-c Exp $

EAPI=5

inherit eutils user

DESCRIPTION="Minimalistic Murmur (Mumble server)"
HOMEPAGE="http://code.google.com/p/umurmur/"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="polarssl"

DEPEND=">=dev-libs/protobuf-c-0.14
	dev-libs/libconfig
	polarssl? ( >=net-libs/polarssl-1.0.0 )
	!polarssl? ( dev-libs/openssl )"

RDEPEND="${DEPEND}"

pkg_setup() {
	enewgroup murmur
	enewuser murmur "" "" "" murmur
}

src_configure() {
	local myconf

	# build uses polarssl by default, but instead, make it use openssl
	# unless polarssl is desired.
	use !polarssl && myconf="${myconf} --with-ssl=openssl"

	econf ${myconf}
}

src_install() {
	emake DESTDIR="${D}" install

	newinitd "${FILESDIR}"/umurmurd.initd umurmurd
	newconfd "${FILESDIR}"/umurmurd.confd umurmurd

	dodoc AUTHORS ChangeLog
	newdoc README.md README

	# Some permissions are adjusted as the config may contain a server
	# password, and /etc/umurmur will typically contain the cert and the
	# key used to sign it, which are read after priveleges are dropped.
	local confdir="/etc/umurmur"
	dodir ${confdir}
	fperms 0750 ${confdir}
	fowners root:murmur ${confdir}

	insinto ${confdir}
	doins "${FILESDIR}"/umurmur.conf
	fperms 0640 ${confdir}/umurmur.conf
}

pkg_postinst() {
	elog "A configuration file has been installed at /etc/umurmur.conf - you may "
	elog "want to review it. See also"
	elog "   http://code.google.com/p/umurmur/wiki/Configuring02x"

	if use polarssl ; then
		elog
		elog "Because you have enabled PolarSSL support, umurmurd will use a"
		elog "predefined test-certificate and key if none are configured, which"
		elog "is insecure. See http://code.google.com/p/umurmur/wiki/Installing02x#Installing_uMurmur_with_PolarSSL_support"
		elog "for more information on how to create your certificate and key"
	fi
}



1.1                  media-sound/umurmur/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/umurmur/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/umurmur/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for media-sound/umurmur
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/umurmur/ChangeLog,v 1.1 2013/06/20 09:10:29 polynomial-c Exp $

*umurmur-0.2.13 (20 Jun 2013)

  20 Jun 2013; Lars Wendler <polynomial-c@gentoo.org> +umurmur-0.2.13.ebuild,
  +files/umurmur.conf, +files/umurmurd.confd, +files/umurmurd.initd,
  +metadata.xml:
  Initial commit. This fixes bug #371773 reported by Hans Nieser who also
  contributed various files to the bug.




1.1                  media-sound/umurmur/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/umurmur/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/umurmur/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>voip</herd>
  <maintainer>
    <email>polynomial-c@gentoo.org</email>
    <name>Lars Wendler</name>
  </maintainer>
  <longdescription lang="en">
    uMumble is a minimalistic Mumble server primarily targeted to run on routers with an open OS like OpenWRT. The server part of Mumble is called Murmur, hence the name uMurmur.
  </longdescription>
  <use>
    <flag name='polarssl'>Use <pkg>net-libs/polarssl</pkg> instead of <pkg>dev-libs/openssl</pkg></flag>
  </use>
</pkgmetadata>