[gentoo-commits] gentoo-x86 commit in sys-apps/etckeeper: ChangeLog etckeeper-1.4.ebuild etckeeper-1.3.ebuild

[gentoo-commits] gentoo-x86 commit in sys-apps/etckeeper: ChangeLog etckeeper-1.4.ebuild etckeeper-1.3.ebuild

[Julian Ospald (hasufell)]

hasufell    13/06/17 20:49:46

  Modified:             ChangeLog
  Added:                etckeeper-1.4.ebuild
  Removed:              etckeeper-1.3.ebuild
  Log:
  version bump, remove old
  
  (Portage version: 2.2.0_alpha179/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.18                 sys-apps/etckeeper/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/etckeeper/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	31 May 2013 19:35:02 -0000	1.17
+++ ChangeLog	17 Jun 2013 20:49:46 -0000	1.18
@@ -1,6 +1,13 @@
 # ChangeLog for sys-apps/etckeeper
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/etckeeper/ChangeLog,v 1.17 2013/05/31 19:35:02 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/etckeeper/ChangeLog,v 1.18 2013/06/17 20:49:46 hasufell Exp $
+
+*etckeeper-1.4 (17 Jun 2013)
+
+  17 Jun 2013; Julian Ospald <hasufell@gentoo.org> -etckeeper-1.3.ebuild,
+  -files/etckeeper-1.3-gentoo.patch, +etckeeper-1.4.ebuild,
+  +files/etckeeper-1.4-gentoo.patch:
+  version bump, remove old
 
 *etckeeper-1.3 (31 May 2013)
 



1.1                  sys-apps/etckeeper/etckeeper-1.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/etckeeper-1.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/etckeeper-1.4.ebuild?rev=1.1&content-type=text/plain

Index: etckeeper-1.4.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/etckeeper/etckeeper-1.4.ebuild,v 1.1 2013/06/17 20:49:46 hasufell Exp $

EAPI=5

PYTHON_COMPAT=( python2_6 python2_7 )

inherit eutils bash-completion-r1 prefix python-r1

DESCRIPTION="A collection of tools to let /etc be stored in a repository"
HOMEPAGE="http://kitenet.net/~joey/code/etckeeper/"
SRC_URI="https://github.com/joeyh/etckeeper/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
IUSE="bazaar cron"
KEYWORDS="~amd64 ~x86"
SLOT="0"

VCS_DEPEND="
	dev-vcs/git
	dev-vcs/mercurial
	dev-vcs/darcs"
DEPEND="bazaar? ( dev-vcs/bzr )"
RDEPEND="${DEPEND}
	app-portage/portage-utils
	cron? ( virtual/cron )
	bazaar? ( ${PYTHON_DEPS} )
	!bazaar? ( || ( ${VCS_DEPEND} ) )"

src_prepare(){
	epatch "${FILESDIR}"/${P}-gentoo.patch
}

src_compile() {
	:
}

src_install(){
	emake DESTDIR="${ED}" install

	bzr_install() {
		${PYTHON} ./${PN}-bzr/__init__.py install --root="${ED}" ||
			die "bzr support installation failed!"
	}
	use bazaar && python_foreach_impl bzr_install

	if use prefix; then
		doenvd "${FILESDIR}"/99${PN}
		eprefixify "${ED%/}"/etc/env.d/99${PN}
	fi

	newbashcomp bash_completion ${PN}
	dodoc README TODO
	docinto examples
	dodoc "${FILESDIR}"/bashrc

	if use cron ; then
		exeinto /etc/cron.daily
		newexe debian/cron.daily etckeeper
	fi
}

pkg_postinst(){
	elog "${PN} supports the following VCS: ${VCS_DEPEND}"
	elog "	dev-vcs/bzr"
	elog "This ebuild just ensures at least one is installed!"
	elog "For dev-vcs/bzr you need to enable 'bazaar' useflag."
	elog
	elog "You may want to adjust your /etc/portage/bashrc"
	elog "see the example file in /usr/share/doc/${P}/examples"
	elog
	elog "To initialise your etc-dir as a repository run:"
	elog "${PN} init -d /etc"
}