[gentoo-commits] gentoo-x86 commit in dev-tcltk/tdom: ChangeLog tdom-0.8.3-r4.ebuild tdom-0.8.3-r3.ebuild

[gentoo-commits] gentoo-x86 commit in dev-tcltk/tdom: ChangeLog tdom-0.8.3-r4.ebuild tdom-0.8.3-r3.ebuild

[Justin Lecher (jlec)]

jlec        13/06/15 16:12:28

  Modified:             ChangeLog
  Added:                tdom-0.8.3-r4.ebuild
  Removed:              tdom-0.8.3-r3.ebuild
  Log:
  dev-tcltk/tdom: Conditionally use Tcl_GetErrorLine, #473314
  
  (Portage version: 2.2.0_alpha179/cvs/Linux x86_64, RepoMan options: --force, signed Manifest commit with key 8009D6F070EB7916)

Revision  Changes    Path
1.22                 dev-tcltk/tdom/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-tcltk/tdom/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-tcltk/tdom/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-tcltk/tdom/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-tcltk/tdom/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	21 May 2013 06:09:59 -0000	1.21
+++ ChangeLog	15 Jun 2013 16:12:27 -0000	1.22
@@ -1,6 +1,12 @@
 # ChangeLog for dev-tcltk/tdom
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-tcltk/tdom/ChangeLog,v 1.21 2013/05/21 06:09:59 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-tcltk/tdom/ChangeLog,v 1.22 2013/06/15 16:12:27 jlec Exp $
+
+*tdom-0.8.3-r4 (15 Jun 2013)
+
+  15 Jun 2013; Justin Lecher <jlec@gentoo.org> -tdom-0.8.3-r3.ebuild,
+  +tdom-0.8.3-r4.ebuild, files/tdom-0.8.3-tcl8.6.patch:
+  Conditionally use Tcl_GetErrorLine, #473314
 
   21 May 2013; Justin Lecher <jlec@gentoo.org> -tdom-0.8.3-r1.ebuild,
   -tdom-0.8.3-r2.ebuild:



1.1                  dev-tcltk/tdom/tdom-0.8.3-r4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-tcltk/tdom/tdom-0.8.3-r4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-tcltk/tdom/tdom-0.8.3-r4.ebuild?rev=1.1&content-type=text/plain

Index: tdom-0.8.3-r4.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-tcltk/tdom/tdom-0.8.3-r4.ebuild,v 1.1 2013/06/15 16:12:27 jlec Exp $

EAPI=5

inherit autotools eutils flag-o-matic multilib toolchain-funcs

MY_P="tDOM-${PV}"

DESCRIPTION="A XML/DOM/XPath/XSLT Implementation for Tcl"
HOMEPAGE="http://tdom.github.com/"
#SRC_URI="http://cloud.github.com/downloads/tDOM/${PN}/${MY_P}.tgz"
SRC_URI="mirror://github/tDOM/${PN}/${MY_P}.tgz"

LICENSE="MPL-1.1"
SLOT="0"
KEYWORDS="amd64 ~ppc x86 ~amd64-linux ~x86-linux"
IUSE="static-libs threads"

DEPEND="
	dev-lang/tcl:=
	dev-libs/expat"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_P}"

PATCHES=(
	"${FILESDIR}/"${PN}-0.8.2.patch
	"${FILESDIR}/"${P}-soname.patch
	"${FILESDIR}/"${P}-expat.patch
	"${FILESDIR}/"${PN}-0.8.2-tnc.patch
	"${FILESDIR}/"${P}-tcl8.6.patch
	)

src_prepare() {
	tc-export AR
	append-libs -lm
	sed \
		-e 's:-O2::g' \
		-e 's:-pipe::g' \
		-e 's:-fomit-frame-pointer::g' \
		-e '/SHLIB_LD_LIBS/s:\"$: ${TCL_LIB_FLAG}":g' \
		-i {.,extensions/tnc}/configure tclconfig/tcl.m4 || die
	epatch "${PATCHES[@]}"
	eautoreconf
}

src_configure() {
	local myeconfargs=(
		$(use_enable threads)
		--enable-shared
		--disable-tdomalloc
		--with-expat
		--with-tcl="${EPREFIX}"/usr/$(get_libdir)
		)

	cd "${S}"/unix && ECONF_SOURCE=".." econf ${myeconfargs}
	cd "${S}"/extensions/tdomhtml &&	econf ${myeconfargs}
	cd "${S}"/extensions/tnc && econf ${myeconfargs}
}

src_compile() {
	local dir

	for dir in "${S}"/unix "${S}"/extensions/tnc; do
		pushd ${dir} > /dev/null
			emake
		popd > /dev/null
	done
}

src_install() {
	local dir

	dodoc CHANGES ChangeLog README*

	for dir in "${S}"/unix "${S}"/extensions/tdomhtml "${S}"/extensions/tnc; do
		pushd ${dir} > /dev/null
			emake DESTDIR="${D}" install
		popd > /dev/null
	done

	if ! use static-libs; then
		einfo "Removing static libs ..."
		rm -f "${ED}"/usr/$(get_libdir)/*.{a,la} || die
	fi
}